# DJGPP specific configuration file.
# Sed script for additional DJGPP specific editing
# of the configure script generated by autoconf 2.65.






# Additional editing of Makefiles
/^eval sed.*ac_file_inputs.*tmp\/out \\$/ {
:loop
n
/^$/!b loop
a\
cat > "$tmp/subs-djgpp.sed" << eof_djgpp\
# DJGPP specific Makefile changes.\
s,\\.deps,_deps,g\
s,\\.libs,_libs,g\
s,\\.new\\.,_new.,g\
s,\\.old\\.,_old.,g\
s,\\.tab\\.,_tab.,g\
s,config\\.h\\.in,config.h-in,g\
s,Makefile\\.am\\.in,Makefile.am-in,g\
s,Makefile\\.in\\.in,Makefile.in-in,g\
s,libpcrecpp\\.pc\\.in,libpcrecpp.pc-in,g\
s,libpcreposix\\.pc\\.in,libpcreposix.pc-in,g\
s,libpcre\\.pc\\.in,libpcre.pc-in,g\
s,pcrecpparg\\.h\\.in,pcrecpparg.h-in,g\
s,pcre\\.h\\.in,pcre.h-in,g\
s,pcre\\.h\\.generic,pcre.h-generic,g\
/^install-info-am:/,/^$/ {\
  /@list=.\\\$(INFO_DEPS)\[^ \]/s,DEPS),& libpcre.i,\
  s,\\(\\\$\\\$d/\\\$\\\$file-\\[0-9\\]\\[0-9\\]\\)\\(\[^ \]\\),\\1 \\$\\$d/\\$\\$file[0-9] \\$\\$d/\\$\\$file[0-9][0-9]\\2,\
  s,\\( \\\$\\\$file-\\[0-9\\]\\[0-9\\]\\)\\(\[^ \]\\),\\1 \\$\\$file[0-9] \\$\\$file[0-9][0-9]\\2,\
}\
/^uninstall-info-am:/,/^$/ {\
  /@list=.\\\$(INFO_DEPS)\[^ \]/s,DEPS),& libpcre.i,\
  s,\\(file-\\[0-9\\]\\[0-9\\]\\)\\(\[^ \]\\),\\1 \\$\\$file[0-9] \\$\\$file[0-9][0-9]\\2,\
}\
s,pcre_compile\\.html,compile.html,g\
s,pcre_compile2\\.html,compile2.html,g\
s,pcre_copy_named_substring\\.html,copy_named_substring.html,g\
s,pcre_copy_substring\\.html,copy_substring.html,g\
s,pcre_free_substring\\.html,fsubstr.html,g\
s,pcre_free_substring_list\\.html,fsubstr_list.html,g\
s,pcre_get_named_substring\\.html,get_named_substring.html,g\
s,pcre_get_stringnumber\\.html,gstringnumber.html,g\
s,pcre_get_stringtable_entries\\.html,gstringtable_entries.html,g\
s,pcre_get_substring\\.html,gsubstr.html,g\
s,pcre_get_substring_list\\.html,gsubstr_list.html,g\
s,pcre_compile\\.3,compile.3,g\
s,pcre_compile2\\.3,compile2.3,g\
s,pcre_copy_named_substring\\.3,copy_named_substring.3,g\
s,pcre_copy_substring\\.3,copy_substring.3,g\
s,pcre_free_substring\\.3,fsubstr.3,g\
s,pcre_free_substring_list\\.3,fsubstr_list.3,g\
s,pcre_get_named_substring\\.3,get_named_substring.3,g\
s,pcre_get_stringnumber\\.3,gstringnumber.3,g\
s,pcre_get_stringtable_entries\\.3,gstringtable_entries.3,g\
s,pcre_get_substring\\.3,gsubstr.3,g\
s,pcre_get_substring_list\\.3,gsubstr_list.3,g\
eof_djgpp\
sed -f "\$tmp/subs-djgpp.sed" \$tmp/out > \$tmp/out.djgpp\
mv -f \$tmp/out.djgpp \$tmp/out
}


# config.h.in is renamed to config.h-in.
/ac_config_headers=/,/^$/ {
  /config\.h:/! {
    s| config\.h|&:config.h-in|
  }
}
/CONFIG_HEADERS=/ {
  /config\.h:/! {
    s| config\.h|&:config.h-in|
  }
}

# Makefile.in.in is renamed to Makefile.in-in.
/ac_config_files=/,/_ACEOF/ {
  s|po/Makefile\.in|&:po/Makefile.in-in|
  s|libpcre\.pc|&:libpcre.pc-in|
  s|libpcreposix\.pc|&:libpcreposix.pc-in|
  s|libpcrecpp\.pc|&:libpcrecpp.pc-in|
  s|pcrecpparg\.h|&:pcrecpparg.h-in|
  s|pcre\.h|&:pcre.h-in|
}
/CONFIG_FILES=/ {
  s|po/Makefile\.in|&:po/Makefile.in-in|2
  s|libpcre\.pc\.in|&:libpcre.pc-in|2
  s|libpcreposix\.pc\.in|&:libpcreposix.pc-in|2
  s|libpcrecpp\.pc\.in|&:libpcrecpp.pc-in|2
  s|pcrecpparg\.h\.in|&:pcrecpparg.h-in|2
  s|pcre\.h|&:pcre.h-in|2
}


# We always use _deps and _libs instead of .deps and .libs, because
# the latter is an invalid name on 8+3 MS-DOS filesystem.  This makes
# the generated Makefiles good for every DJGPP installation, not only
# the one where the package was configured (which could happen to be
# a Windows box, where leading dots in file names are allowed).
s,\.deps,_deps,g
s,\.libs,_libs,g
/^rmdir[ 	]*\.tst/ i\
am__leading_dot=_

# Autoconf 2.63b produces if clauses that are enclosed in `
# so we cannot use ` to replace parenthesized commands.
# This case must be treated before the parenthesized commands
# are replaced by `.
/.*`if[ 	](/ {
  s/(/"/
  s/)/"/
}

# Replace (command) > /dev/null with `command > /dev/null`, since
# parenthesized commands always return zero status in the ported Bash,
# even if the named command doesn't exist
/if ([^|;`]*null/{
  s,(,`,
  s,\([^ 	)]\)),\1,
  /null[ 	]*2>&1/ s,2>&1,&`,
  /null.*null/ s,null.*null,&`,
  /null.*null/ !{
    /null[ 	]*2>&1/ !s,null,&`,
  }
}

# DOS-style absolute file names should be supported as well
/\*) top_srcdir=/s,/\*,[\\\\/]* | ?:[\\\\/]*,

# The following two items are changes needed for configuring
# and compiling across partitions.
# 1) The given srcdir value is always translated from the
#    "x:" syntax into "/dev/x" syntax while we run configure.
/^[ 	]*-srcdir=\*.*$/ a\
    ac_optarg=`echo "$ac_optarg" | sed "s,^\\([A-Za-z]\\):,/dev/\\1,"`
/set X `ls -Lt \$srcdir/ i\
   if `echo $srcdir | grep "^/dev/" - > /dev/null`; then\
     srcdir=`echo "$srcdir" | sed -e "s%^/dev/%%" -e "s%/%:/%"`\
   fi

# Autoconf 2.52e generated configure scripts
# write absolute paths into Makefiles making
# them useless for DJGPP installations for which
# the package has not been configured for.
/MISSING=/,/^$/ {
  /^fi$/ a\
am_missing_run=`echo "$am_missing_run" | sed 's%/dev.*/libpcre[-_0-9]\\{1,1\\}[-.0-9A-z+]*%${top_srcdir}%;s%.:.*/libpcre[-_0-9]\\{1,1\\}[-.0-9A-z+]*%${top_srcdir}%'`
}
/^install_sh=/a\
install_sh=`echo "$install_sh" | sed 's%/dev.*/libpcre[-_0-9]\\{1,1\\}[-.0-9A-z+]*%${top_srcdir}%;s%.:.*/libpcre[-_0-9]\\{1,1\\}[-.0-9A-z+]*%${top_srcdir}%'`

# This will only work if the assumption that the
# testsuite is ran from the following path:
#   ${top_srcdir}/tests/testsuite.dir
# holds. The explicit names are of no importance.
#   ../../. == ${top_srcdir}
#/^esac$/,/^ac_abs_srcdir=/ {
/^ac_abs_srcdir=/ i\
ac_abs_aux_dir=`echo "$ac_abs_aux_dir" | sed "s%/dev/.*/libpcre[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../.%;s%.:.*/libpcre[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../.%"`\
ac_abs_builddir=`echo "$ac_abs_builddir" | sed "s%/dev/.*/libpcre[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../.%;s%.:.*/libpcre[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../.%"`\
ac_abs_top_builddir=`echo "$ac_abs_top_builddir" | sed "s%/dev/.*/libpcre[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../..%;s%.:.*/libpcre[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../..%"`\
ac_abs_top_srcdir=`echo "$ac_abs_top_srcdir" | sed "s%/dev/.*/libpcre[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../..%;s%.:.*/libpcre[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../..%"`
#ac_abs_srcdir=`echo "$ac_abs_srcdir" | sed "s%/dev/.*/libpcre[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../.%;s%.:.*/libpcre[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../.%"`
/^ac_abs_srcdir=/ a\
for dj_dir in $ac_abs_builddir $ac_abs_top_builddir $ac_abs_top_srcdir $ac_abs_srcdir\
do\
  ac_abs_aux_dir=`echo "$ac_abs_aux_dir" | sed "s%//%/%g"`\
  ac_abs_builddir=`echo "$ac_abs_builddir" | sed "s%//%/%g"`\
  ac_abs_top_builddir=`echo "$ac_abs_top_builddir" | sed "s%//%/%g"`\
  ac_abs_top_srcdir=`echo "$ac_abs_top_srcdir" | sed "s%//%/%g"`\
  ac_abs_srcdir=`echo "$ac_abs_srcdir" | sed "s%//%/%g"`\
done

# Add DJGPP version information.
/^#define VERSION/ s/\$VERSION/&  (DJGPP port (r1))/

# We need makeinfo to make the html formated docs.
/\$am_missing_run[ 	]*makeinfo/ s,\$am_missing_run,,

# The path to the FORTRAN compiler and libraries
# shall contain no absolute path reference so it
# will be good for all djgpp installations.
/^FLIBS="\$ac_cv_flibs"/ i\
ac_djgpp_path=`echo "$DJDIR" | sed 's%\\\\\\%/%g' | tr $as_cr_LETTERS $as_cr_letters`\
ac_cv_flibs=`echo "$ac_cv_flibs" | sed "s%-L$ac_djgpp_path%-L/dev/env/DJDIR%g"`

# Do not split info output.
/^MAKEINFO=.*$/s:=.*$:&" --no-split":

# The CR test for awk does not work for DJGPP.
/^ac_cs_awk_cr=/,/^$/ {
  /^fi$/ a\
ac_cs_awk_cr=$ac_cr
}

# AWK program above erroneously prepends '/' to C:/dos/paths
/# AWK program above erroneously prepends/,/esac/ {
  s/mingw/*djgpp* | mingw/
}

# Force the test for 'ln -s' to report 'cp -pf'.
/as_ln_s='ln -s'/ s/ln -s/cp -pf/

# Bash 2.05b always dies with an error message like this:
#  malloc: print_cmd.c:1156: assertion botched
#
#  realloc: start and end chunk sizes differ
# The only reliable way that I have figured out to handle
# this has been to split the here document used to create
# config.status.
#
# Laeuft unter W2K problemlos aber nicht unter WXP.
/^[ #]*END LIBTOOL CONFIG$/ {
:loop1
n
/^_LT_EOF$/!b loop1
a\
_ACEOF\
cat >>\$CONFIG_STATUS <<\\_ACEOF || ac_write_fail=1
}

# Rename unique file.
/ac_unique_file=/ s/pcre.h.in/pcre.h-in/
