# DJGPP specific configuration file.
# Sed script for additional DJGPP specific editing
# of the configure script generated by autoconf 2.69.










# Additional editing of Makefiles
/^eval sed.*ac_file_inputs.*tmp\/subs.awk.*\\$/ {
:loop
n
/^$/!b loop
a\
cat > "$tmp/subs-djgpp.sed" << eof_djgpp\
# DJGPP specific Makefile changes.\
s,\\.deps,_deps,g\
s,\\.libs,_libs,g\
s,\\.new\\.,_new.,g\
s,\\.old\\.,_old.,g\
s,\\.tab\\.,_tab.,g\
s,config\\.h\\.in,config.h-in,g\
s,config\\.h\\.generic,config.h-generic,g\
s,config-cmake\\.h\\.in,config-cmake.h-in,g\
s,autoconf\\.h\\.in,autoconf.h-in,g\
s,Makefile\\.am\\.in,Makefile.am-in,g\
s,Makefile\\.in\\.in,Makefile.in-in,g\
s,libpcrecpp\\.pc\\.in,libpcrecpp.pc-in,g\
s,libpcreposix\\.pc\\.in,libpcreposix.pc-in,g\
s,libpcre\\.pc\\.in,libpcre.pc-in,g\
s,libpcre16\\.pc\\.in,libpcre16.pc-in,g\
s,libpcre32\\.pc\\.in,libpcre32.pc-in,g\
s,pcrecpparg\\.h\\.in,pcrecpparg.h-in,g\
s,pcre\\.h\\.in,pcre.h-in,g\
s,pcre\\.h\\.generic,pcre.h-generic,g\
s,pcre_chartables\\.c\\.dist,pcre_chartables.c-dist,g\
s,pcre_stringpiece\\.h\\.in,pcre_stringpiece.h-in,g\
/^install-info-am:/,/^$/ {\
  /@list=.\\\$(INFO_DEPS)\[^ \]/s,DEPS),& libpcre.i,\
  s,\\(\\\$\\\$d/\\\$\\\$file-\\[0-9\\]\\[0-9\\]\\)\\(\[^ \]\\),\\1 \\$\\$d/\\$\\$file[0-9] \\$\\$d/\\$\\$file[0-9][0-9]\\2,\
  s,\\( \\\$\\\$file-\\[0-9\\]\\[0-9\\]\\)\\(\[^ \]\\),\\1 \\$\\$file[0-9] \\$\\$file[0-9][0-9]\\2,\
}\
/^uninstall-info-am:/,/^$/ {\
  /@list=.\\\$(INFO_DEPS)\[^ \]/s,DEPS),& libpcre.i,\
  s,\\(file-\\[0-9\\]\\[0-9\\]\\)\\(\[^ \]\\),\\1 \\$\\$file[0-9] \\$\\$file[0-9][0-9]\\2,\
}\
/^\\([a-z]*\\.[1-9][ 	]*\\)*: Makefile\\.am/,/^$/ {\
  /\\.so[ 	]*man/ s/man/cat/\
}\
s,pcre_compile\\.html,compile.html,g\
s,pcre_compile2\\.html,compile2.html,g\
s,pcre_copy_named_substring\\.html,copy_named_substring.html,g\
s,pcre_copy_substring\\.html,copy_substring.html,g\
s,pcre_free_substring\\.html,fsubstr.html,g\
s,pcre_free_substring_list\\.html,fsubstr_list.html,g\
s,pcre_get_named_substring\\.html,get_named_substring.html,g\
s,pcre_get_stringnumber\\.html,gstringnumber.html,g\
s,pcre_get_stringtable_entries\\.html,gstringtable_entries.html,g\
s,pcre_get_substring\\.html,gsubstr.html,g\
s,pcre_get_substring_list\\.html,gsubstr_list.html,g\
s,pcre_jit_stack_alloc\\.html,jitstckalloc.html,g\
s,pcre_jit_stack_free\\.html,jitstckfree.html,g\
s,pcre_utf16_to_host_byte_order\\.html,utf16_to_host_byte_order.html,g\
s,pcre_utf32_to_host_byte_order\\.html,utf32_to_host_byte_order.html,g\
s,pcre_compile\\.3,compile.3,g\
s,pcre_compile2\\.3,compile2.3,g\
s,pcre_copy_named_substring\\.3,copy_named_substring.3,g\
s,pcre_copy_substring\\.3,copy_substring.3,g\
s,pcre_free_substring\\.3,fsubstr.3,g\
s,pcre_free_substring_list\\.3,fsubstr_list.3,g\
s,pcre_get_named_substring\\.3,get_named_substring.3,g\
s,pcre_get_stringnumber\\.3,gstringnumber.3,g\
s,pcre_get_stringtable_entries\\.3,gstringtable_entries.3,g\
s,pcre_get_substring\\.3,gsubstr.3,g\
s,pcre_get_substring_list\\.3,gsubstr_list.3,g\
s,pcre_jit_stack_alloc\\.3,jitstckalloc.3,g\
s,pcre_jit_stack_free\\.3,jitstckfree.3,g\
s,pcre_utf16_to_host_byte_order\\.3,utf16_to_host_byte_order.3,g\
s,pcre_utf32_to_host_byte_order\\.3,utf32_to_host_byte_order.3,g\
/^dist_doc_DATA[ 	]*=/,/^$/ {\
  s,AUTHORS,\\$(srcdir)/&,\
  s,COPYING,\\$(srcdir)/&,\
  s,ChangeLog,\\$(srcdir)/&,\
  s,LICENCE,\\$(srcdir)/&,\
  s,NEWS,\\$(srcdir)/&,\
  s,README,\\$(srcdir)/&,\
}\
/^install-data-am[ 	]*:/,/^$/ {\
/MAKE)/ s,^,#,\
}\
/^libpcre.la[ 	]*: .*(libpcre_la_OBJECTS).*/ {\
n\
a\\\\\
ifeq (\\\$(MAKE_DXE3), y)\\\\\
	cd _libs && dxe3gen -o libpcre.dxe -Y libpcre.tmp --whole-archive -U libpcre.a && mv -f libpcre.tmp libpcre.a\\\\\
endif\
}\
/^libpcrecpp.la[ 	]*: .*(libpcrecpp_la_OBJECTS).*/ {\
n\
a\\\\\
ifeq (\\\$(MAKE_DXE3), y)\\\\\
	cd _libs && dxe3gen -o libpcrecpp.dxe -Y libpcrecpp.tmp --whole-archive -U libpcrecpp.a && mv -f libpcrecpp.tmp libpcrecpp.a\\\\\
endif\
}\
/^libpcreposix.la[ 	]*: .*(libpcreposix_la_OBJECTS).*/ {\
n\
a\\\\\
ifeq (\\\$(MAKE_DXE3), y)\\\\\
	cd _libs && dxe3gen -o libpcreposix.dxe -Y libpcreposix.tmp --whole-archive -U libpcreposix.a && mv -f libpcreposix.tmp libpcreposix.a\\\\\
endif\
}\
/^install-l.*[ 	]*:.*lib_LTLIBRARIES.*$/,/^$/ {\
  /echo/ !{\
    /--mode=install/ {\
      n\
      a\\\\\
ifeq (\\\$(MAKE_DXE3), y)\\\\\
	cd _libs && cp -vf *.dxe \\\$(DESTDIR)\\\$(libdir)\\\\\
endif\
    }\
  }\
}\
/^check[	 ]*:.*$/,/^$/ {\
  /MAKE/ s/(AM_MAKEFLAGS)/& MAKE_DXE3="\\\$(MAKE_DXE3)"/\
}\
/^check-TESTS[ 	]*:$/,/AM_MAKEFLAGS/ {\
  /AM_MAKEFLAGS/ i\\\\\
	export LD_LIBRARY_PATH="\\\./_libs;/dev/env/DJDIR/lib"; \\\\\\\\\
}\
eof_djgpp\
sed -f "\$ac_tmp/subs-djgpp.sed" \$ac_tmp/out > \$ac_tmp/out.djgpp\
mv -f \$ac_tmp/out.djgpp \$ac_tmp/out
}


# config.h.in is renamed to config.h-in.
/ac_config_headers=/,/^$/ {
  /config\.h:/! {
    s| \([A-Za-z0-9_/-]*\)config\.h|&:\1config.h-in|
#    s| config\.h|&:config.h-in|
  }
}

# Makefile.in.in is renamed to Makefile.in-in.
/ac_config_files=/,/_ACEOF/ {
  s|po/Makefile\.in|&:po/Makefile.in-in|
  s|libpcre\.pc|&:libpcre.pc-in|
  s|libpcre16\.pc|&:libpcre16.pc-in|
  s|libpcre32\.pc|&:libpcre32.pc-in|
  s|libpcreposix\.pc|&:libpcreposix.pc-in|
  s|libpcrecpp\.pc|&:libpcrecpp.pc-in|
  s|pcrecpparg\.h|&:pcrecpparg.h-in|
  s|pcre_stringpiece\.h|&:pcre_stringpiece.h-in|
  s|pcre\.h|&:pcre.h-in|
}
/for ac_config_target/,/^done$/ {
  s|config\.h|&:config.h-in|2
  s|po/Makefile|&:po/Makefile.in-in|2
  s|libpcrecpp\.pc|&:libpcre.pc-in|2
  s|libpcre16\.pc|&:libpcre16.pc-in|2
  s|libpcre32\.pc|&:libpcre32.pc-in|2
  s|libpcreposix\.pc|&:libpcreposix.pc-in|2
  s|libpcrecpp\.pc|&:libpcrecpp.pc-in|2
  s|pcrecpparg\.h|&:pcrecpparg.h-in|2
  s|pcre_stringpiece\.h|&:pcre_stringpiece.h-in|2
  s|pcre\.h|&:pcre.h-in|2
}


# We always use _deps and _libs instead of .deps and .libs, because
# the latter is an invalid name on 8+3 MS-DOS filesystem.  This makes
# the generated Makefiles good for every DJGPP installation, not only
# the one where the package was configured (which could happen to be
# a Windows box, where leading dots in file names are allowed).
s,\.deps,_deps,g
s,\.libs,_libs,g
/^rmdir[ 	]*\.tst/ i\
am__leading_dot=_

# Autoconf 2.63b produces if clauses that are enclosed in `
# so we cannot use ` to replace parenthesized commands.
# This case must be treated before the parenthesized commands
# are replaced by `.
/.*`if[ 	](/ {
  s/(/"/
  s/)/"/
}

# Replace (command) > /dev/null with `command > /dev/null`, since
# parenthesized commands always return zero status in the ported Bash,
# even if the named command doesn't exist
/if ([^|;`]*null/{
  s,(,`,
  s,\([^ 	)]\)),\1,
  /null[ 	]*2>&1/ s,2>&1,&`,
  /null.*null/ s,null.*null,&`,
  /null.*null/ !{
    /null[ 	]*2>&1/ !s,null,&`,
  }
}

# DOS-style absolute file names should be supported as well
/\*) top_srcdir=/s,/\*,[\\\\/]* | ?:[\\\\/]*,

# The following two items are changes needed for configuring
# and compiling across partitions.
# 1) The given srcdir value is always translated from the
#    "x:" syntax into "/dev/x" syntax while we run configure.
/^[ 	]*-srcdir=\*.*$/ a\
    ac_optarg=`echo "$ac_optarg" | sed "s,^\\([A-Za-z]\\):,/dev/\\1,"`
/set X `ls -Lt \$srcdir/ i\
   if `echo $srcdir | grep "^/dev/" - > /dev/null`; then\
     srcdir=`echo "$srcdir" | sed -e "s%^/dev/%%" -e "s%/%:/%"`\
   fi

# Autoconf 2.52e generated configure scripts
# write absolute paths into Makefiles making
# them useless for DJGPP installations for which
# the package has not been configured for.
/MISSING=/,/^$/ {
  /^fi$/ a\
am_missing_run=`echo "$am_missing_run" | sed 's%/dev.*/pcre[-_0-9]\\{1,1\\}[-.0-9A-z+]*%${top_srcdir}%;s%.:.*/pcre[-_0-9]\\{1,1\\}[-.0-9A-z+]*%${top_srcdir}%'`
#am_missing_run=`echo "$am_missing_run" | sed 's%/dev.*/libpcre[-_0-9]\\{1,1\\}[-.0-9A-z+]*%${top_srcdir}%;s%.:.*/libpcre[-_0-9]\\{1,1\\}[-.0-9A-z+]*%${top_srcdir}%'`
}
/install_sh=/,/^$/ {
  /^fi$/ a\
install_sh=`echo "$install_sh" | sed 's%/dev.*/pcre[-_0-9]\\{1,1\\}[-.0-9A-z+]*%${top_srcdir}%;s%.:.*/pcre[-_0-9]\\{1,1\\}[-.0-9A-z+]*%${top_srcdir}%'`
#install_sh=`echo "$install_sh" | sed 's%/dev.*/libpcre[-_0-9]\\{1,1\\}[-.0-9A-z+]*%${top_srcdir}%;s%.:.*/libpcre[-_0-9]\\{1,1\\}[-.0-9A-z+]*%${top_srcdir}%'`
}
/^install_sh=/a\
install_sh=`echo "$install_sh" | sed 's%/dev.*/pcre[-_0-9]\\{1,1\\}[-.0-9A-z+]*%${top_srcdir}%;s%.:.*/pcre[-_0-9]\\{1,1\\}[-.0-9A-z+]*%${top_srcdir}%'`
#install_sh=`echo "$install_sh" | sed 's%/dev.*/libpcre[-_0-9]\\{1,1\\}[-.0-9A-z+]*%${top_srcdir}%;s%.:.*/libpcre[-_0-9]\\{1,1\\}[-.0-9A-z+]*%${top_srcdir}%'`

# Only if both builddir and srcdir are on the same
# partition the absolute paths are converted to
# relative paths so that the produced makefiles are
# good for all installations but not only for the one
# where it was configured.
/^# If the template does not know about datarootdir, expand it.$/ i\
# DJGPP specific.\
# Autoconf generated configure scripts write\
# absolute paths into Makefiles making them\
# useless for DJGPP installations for which\
# the package has not been configured for.\
djgpp_ac_abs_top_builddir_drive=\$(echo ${ac_abs_top_builddir} | sed -e 's%:[/\\\\]*.*$%%;s%^/dev/\\([A-z]\\)/.*$%\\1%')\
djgpp_ac_abs_top_srcdir_drive=\$(echo ${ac_abs_top_srcdir} | sed -e 's%:[/\\\\]*.*$%%;s%^/dev/\\([A-z]\\)/.*$%\\1%')\
if [ "x\${ac_abs_top_srcdir}" == "x\${ac_top_srcdir}" ]; then\
  paths_are_absolute=yes\
else\
  paths_are_absolute=no\
fi\
\
if [ "x\${djgpp_ac_abs_top_builddir_drive}" == "x\${djgpp_ac_abs_top_srcdir_drive}" ]; then\
  # builddir and srcdir are on the same partition.\
\
  # Convert absolute buildir paths to relative ones.\
  paths_to_be_adjusted="ac_abs_builddir ac_abs_top_builddir"\
  for path in \${paths_to_be_adjusted}; do\
    eval _path=\\\${$path}\
    eval djgpp_\${path}=$(echo \${_path} | sed -e "s%\${ac_abs_top_builddir}%\${ac_builddir}%")\
  done\
\
  if [ "x\${paths_are_absolute}" == "xyes" ]; then\
    # Convert absolute srcdir paths to relative ones.\
    djgpp_relative_prefix=$(echo \${ac_abs_builddir} | sed -e 's%^[A-z]:%%;s%^/dev/[A-z]%%;s%^%.%;s%[/\\\\][A-z0-9._+-]\\+%/..%g;s%[/\\\\]$%%')\
    paths_to_be_adjusted="ac_srcdir ac_abs_srcdir ac_top_srcdir ac_abs_top_srcdir"\
    for path in \${paths_to_be_adjusted}; do\
      eval _path=\\\${$path}\
      eval djgpp_\${path}=$(echo \${_path} | sed -e "s%^[A-z]:%%;s%^/dev/[A-z]%%;s%^%\${djgpp_relative_prefix}%")\
    done\
  else\
    djgpp_ac_srcdir="\${ac_srcdir}"\
    djgpp_ac_abs_srcdir="\${ac_srcdir}"\
    djgpp_ac_top_srcdir="\${ac_top_srcdir}"\
    djgpp_ac_abs_top_srcdir="\${ac_top_srcdir}"\
  fi\
else\
  # builddir and srcdir are on different partitions.\
\
  paths_to_be_adjusted="ac_abs_builddir ac_abs_top_builddir"\
  for path in \${paths_to_be_adjusted}; do\
    eval djgpp_\${path}=\\\${$path}\
  done\
\
  paths_to_be_adjusted="ac_srcdir ac_abs_srcdir ac_top_srcdir ac_abs_top_srcdir"\
  for path in \${paths_to_be_adjusted}; do\
    eval djgpp_\${path}=\\\${$path}\
  done\
fi\


/^s|@configure_input@|\$ac_sed_conf_input|;t t$/,/^\$ac_datarootdir_hack$/ {
  s/\$ac_srcdir/\$djgpp_ac_srcdir/
  s/\$ac_abs_srcdir/\$djgpp_ac_abs_srcdir/
  s/\$ac_top_srcdir/\$djgpp_ac_top_srcdir/
  s/\$ac_abs_top_srcdir/\$djgpp_ac_abs_top_srcdir/
  s/\$ac_abs_builddir/\$djgpp_ac_abs_builddir/
  s/\$ac_abs_top_builddir/\$djgpp_ac_abs_top_builddir/
}

# Add DJGPP version information.
/^#define VERSION/ s/\$VERSION/&  (DJGPP port (r1))/

# We need makeinfo to make the html formated docs.
/\$am_missing_run[ 	]*makeinfo/ s,\$am_missing_run,,

# The path to the FORTRAN compiler and libraries
# shall contain no absolute path reference so it
# will be good for all djgpp installations.
/^FLIBS="\$ac_cv_flibs"/ i\
ac_djgpp_path=`echo "$DJDIR" | sed 's%\\\\\\%/%g' | tr $as_cr_LETTERS $as_cr_letters`\
ac_cv_flibs=`echo "$ac_cv_flibs" | sed "s%-L$ac_djgpp_path%-L/dev/env/DJDIR%g"`

# Do not split info output.
/^MAKEINFO=.*$/s:=.*$:&" --no-split":

# The CR test for awk does not work for DJGPP.
/^ac_cs_awk_cr=/,/^$/ {
  /^fi$/ a\
ac_cs_awk_cr=$ac_cr
}

# AWK program above erroneously prepends '/' to C:/dos/paths
/# AWK program above erroneously prepends/,/esac/ {
  s/mingw/*djgpp* | mingw/
}

# Force the test for 'ln -s' to report 'cp -pf'.
/as_ln_s='ln -s'/ s/ln -s/cp -pf/

# Bash 2.05b always dies with an error message like this:
#  malloc: print_cmd.c:1156: assertion botched
#
#  realloc: start and end chunk sizes differ
# The only reliable way that I have figured out to handle
# this has been to split the here document used to create
# config.status.
#
# Laeuft unter W2K problemlos aber nicht unter WXP.
/^[ #]*END LIBTOOL CONFIG$/ {
:loop1
n
/^_LT_EOF$/!b loop1
a\
_ACEOF\
cat >>\$CONFIG_STATUS <<\\_ACEOF || ac_write_fail=1
}

# Rename unique file.
/ac_unique_file=/ s/pcre.h.in/pcre.h-in/

##LIBTOOL="${CONFIG_SHELL-$SHELL} "'$(top_builddir)/libtool'
# Set the right shell for libtool
/^LIBTOOL=.*libtool'$/ s/".*"/'$(SHELL) '/

# Adjust the config.site path for the case
# of recursive called configure scripts
/^if test "$no_recursion" != yes; then/ a\
  djgpp_config_site=$CONFIG_SITE
/case $srcdir in/,/esac/ {
  / # Relative name.$/ a\
export CONFIG_SITE=$ac_top_build_prefix$djgpp_config_site
}

# DJGPP specific adjustments of the compile-time system search path for libraries.
/^[ 	]*lt_search_path_spec=.*-print-search-dirs/ s,`$, -e \"s%[A-z]:[\\\\/]djgpp-[0-9].[0-9][0-9][\\\\/]%/dev/env/DJDIR/%g\"&,

# Fix realpath check.  DJGPP always prepends a drive letter.
/checking whether realpath works/,/^_ACEOF$/ {
  /name && \*name == '\/'/ s/\*name/name[2]/
}

# This works around a bug in DJGPP port of Bash 2.0x.
s|return $ac_retval|(&)|g

# DJGPP port of Bash 2.04 doesn't like this redirection of stdin
/exec 7</s|7<&0 </dev/null||

# Remove LINGUAS from dependecy list in ./po/Makefile
/POMAKEFILEDEPS=/ s/POMAKEFILEDEPS LINGUAS/POMAKEFILEDEPS #LINGUAS/
