FLEX(1)                    OpenBSD Reference Manual                    FLEX(1)

NAME
     flex - fast lexical analyzer generator

SYNOPSIS
     flex [-78BbcdFfhIiLlnpsTtVvw+?] [-C[aeFfmr]] [--help] [--version]
          [-ooutput] [-Pprefix] [-Sskeleton] [filename...]

DESCRIPTION
     flex is a tool for generating scanners: programs which recognize lexical
     patterns in text.  flex reads the given input files, or its standard in-
     put if no file names are given, for a description of a scanner to gener-
     ate.  The description is in the form of pairs of regular expressions and
     C code, called rules.  flex generates as output a C source file,
     lex.yy.c, which defines a routine yylex().  This file is compiled and
     linked with the -lfl library to produce an executable.  When the exe-
     cutable is run, it analyzes its input for occurrences of the regular ex-
     pressions.  Whenever it finds one, it executes the corresponding C code.

     The manual includes both tutorial and reference sections:

     Some Simple Examples

     Format of the Input File

     Patterns
     The extended regular expressions used by flex.

     How the Input is Matched
     The rules for determining what has been matched.

     Actions
     How to specify what to do when a pattern is matched.

     The Generated Scanner
     Details regarding the scanner that flex produces; how to control the in-
     put source.

     Start Conditions
     Introducing context into scanners, and managing "mini-scanners".

     Multiple Input Buffers
     How to manipulate multiple input sources; how to scan from strings in-
     stead of files.

     End-of-File Rules
     Special rules for matching the end of the input.

     Miscellaneous Macros
     A summary of macros available to the actions.

     Values Available to the User
     A summary of values available to the actions.

     Interfacing with Yacc
     Connecting flex scanners together with yacc(1) parsers.

     Options
     flex command-line options, and the ``%option'' directive.

     Performance Considerations
     How to make scanners go as fast as possible.

     Generating C++ Scanners
     The (experimental) facility for generating C++ scanner classes.

     Incompatibilities with Lex and POSIX
     How flex differs from AT&T lex and the POSIX lex standard.

     Files
     Files used by flex.

     Diagnostics
     Those error messages produced by flex (or scanners it generates) whose
     meanings might not be apparent.

     See Also
     Other documentation, related tools.

     Authors
     Includes contact information.

     Bugs
     Known problems with flex.

SOME SIMPLE EXAMPLES
     First some simple examples to get the flavor of how one uses flex.  The
     following flex input specifies a scanner which whenever it encounters the
     string "username" will replace it with the user's login name:

           %%
           username    printf("%s", getlogin());

     By default, any text not matched by a flex scanner is copied to the out-
     put, so the net effect of this scanner is to copy its input file to its
     output with each occurrence of "username" expanded.  In this input, there
     is just one rule.  "username" is the pattern and the "printf" is the
     action.  The "%%" marks the beginning of the rules.

     Here's another simple example:

           %{
           int num_lines = 0, num_chars = 0;
           %}

           %%
           \n      ++num_lines; ++num_chars;
           .       ++num_chars;

           %%
           main()
           {
                   yylex();
                   printf("# of lines = %d, # of chars = %d\n",
                       num_lines, num_chars);
           }

     This scanner counts the number of characters and the number of lines in
     its input (it produces no output other than the final report on the
     counts).  The first line declares two globals, "num_lines" and
     "num_chars", which are accessible both inside yylex() and in the main()
     routine declared after the second "%%".  There are two rules, one which
     matches a newline ("\n") and increments both the line count and the char-
     acter count, and one which matches any character other than a newline
     (indicated by the "." regular expression).

     A somewhat more complicated example:

           /* scanner for a toy Pascal-like language */

           %{
           /* need this for the call to atof() below */
           #include <math.h>
           %}

           DIGIT    [0-9]
           ID       [a-z][a-z0-9]*

           %%

           {DIGIT}+ {
                   printf("An integer: %s (%d)\n", yytext,
                       atoi(yytext));
           }

           {DIGIT}+"."{DIGIT}* {
                   printf("A float: %s (%g)\n", yytext,
                       atof(yytext));
           }

           if|then|begin|end|procedure|function {
                   printf("A keyword: %s\n", yytext);
           }

           {ID}    printf("An identifier: %s\n", yytext);

           "+"|"-"|"*"|"/"   printf("An operator: %s\n", yytext);

           "{"[^}\n]*"}"     /* eat up one-line comments */

           [ \t\n]+          /* eat up whitespace */

           .       printf("Unrecognized character: %s\n", yytext);

           %%

           main(int argc, char *argv[])
           {
                   ++argv; --argc;  /* skip over program name */
                   if (argc > 0)
                           yyin = fopen(argv[0], "r");
                   else
                           yyin = stdin;

                   yylex();
           }

     This is the beginnings of a simple scanner for a language like Pascal.
     It identifies different types of tokens and reports on what it has seen.

     The details of this example will be explained in the following sections.

FORMAT OF THE INPUT FILE
     The flex input file consists of three sections, separated by a line with
     just "%%" in it:

           definitions
           %%
           rules
           %%
           user code

     The definitions section contains declarations of simple name definitions
     to simplify the scanner specification, and declarations of start
     conditions, which are explained in a later section.

     Name definitions have the form:

           name definition

     The "name" is a word beginning with a letter or an underscore (`_') fol-
     lowed by zero or more letters, digits, `_', or `-' (dash).  The defini-
     tion is taken to begin at the first non-whitespace character following
     the name and continuing to the end of the line.  The definition can sub-
     sequently be referred to using "{name}", which will expand to
     "(definition)".  For example:

           DIGIT    [0-9]
           ID       [a-z][a-z0-9]*

     This defines "DIGIT" to be a regular expression which matches a single
     digit, and "ID" to be a regular expression which matches a letter fol-
     lowed by zero-or-more letters-or-digits.  A subsequent reference to

           {DIGIT}+"."{DIGIT}*

     is identical to

           ([0-9])+"."([0-9])*

     and matches one-or-more digits followed by a `.' followed by zero-or-more
     digits.

     The rules section of the flex input contains a series of rules of the
     form:

           pattern   action

     The pattern must be unindented and the action must begin on the same
     line.

     See below for a further description of patterns and actions.

     Finally, the user code section is simply copied to lex.yy.c verbatim.  It
     is used for companion routines which call or are called by the scanner.
     The presence of this section is optional; if it is missing, the second
     "%%" in the input file may be skipped too.

     In the definitions and rules sections, any indented text or text enclosed
     in `%{' and `%}' is copied verbatim to the output (with the %{}'s
     removed).  The %{}'s must appear unindented on lines by themselves.

     In the rules section, any indented or %{} text appearing before the first
     rule may be used to declare variables which are local to the scanning
     routine and (after the declarations) code which is to be executed whenev-
     er the scanning routine is entered.  Other indented or %{} text in the
     rule section is still copied to the output, but its meaning is not well-
     defined and it may well cause compile-time errors (this feature is pre-
     sent for POSIX compliance; see below for other such features).

     In the definitions section (but not in the rules section), an unindented
     comment (i.e., a line beginning with "/*") is also copied verbatim to the
     output up to the next "*/".

PATTERNS
     The patterns in the input are written using an extended set of regular
     expressions.  These are:

     x         Match the character `x'.

     .         Any character (byte) except newline.

     [xyz]     A "character class"; in this case, the pattern matches either
               an `x', a `y', or a `z'.

     [abj-oZ]  A "character class" with a range in it; matches an `a', a `b',
               any letter from `j' through `o', or a `Z'.

     [^A-Z]    A "negated character class", i.e., any character but those in
               the class.  In this case, any character EXCEPT an uppercase
               letter.

     [^A-Z\n]  Any character EXCEPT an uppercase letter or a newline.

     r*        Zero or more r's, where `r' is any regular expression.

     r+        One or more r's.

     r?        Zero or one r's (that is, "an optional r").

     r{2,5}    Anywhere from two to five r's.

     r{2,}     Two or more r's.

     r{4}      Exactly 4 r's.

     {name}    The expansion of the "name" definition (see above).

     "[xyz]\"foo"
               The literal string: [xyz]"foo.

     \X        If `X' is an `a', `b', `f', `n', `r', `t', or `v', then the AN-
               SI-C interpretation of `\X'.  Otherwise, a literal `X' (used to
               escape operators such as `*').

     \0        A NUL character (ASCII code 0).

     \123      The character with octal value 123.

     \x2a      The character with hexadecimal value 2a.

     (r)       Match an `r'; parentheses are used to override precedence (see
               below).

     rs        The regular expression `r' followed by the regular expression
               `s'; called "concatenation".

     r|s       Either an `r' or an `s'.

     r/s       An `r', but only if it is followed by an `s'.  The text matched
               by `s' is included when determining whether this rule is the
               "longest match", but is then returned to the input before the
               action is executed.  So the action only sees the text matched
               by `r'.  This type of pattern is called "trailing context".
               (There are some combinations of r/s that flex cannot match cor-
               rectly; see notes in the BUGS section below regarding
               "dangerous trailing context".)

     ^r        An `r', but only at the beginning of a line (i.e., just start-
               ing to scan, or right after a newline has been scanned).

     r$        An `r', but only at the end of a line (i.e., just before a
               newline).  Equivalent to "r/\n".

               Note that flex's notion of "newline" is exactly whatever the C
               compiler used to compile flex interprets `\n' as.

     <s>r      An `r', but only in start condition `s' (see below for
               discussion of start conditions).

     <s1,s2,s3>r
               The same, but in any of start conditions s1, s2, or s3.

     <*>r      An `r' in any start condition, even an exclusive one.

     <<EOF>>   An end-of-file.

     <s1,s2><<EOF>>
               An end-of-file when in start condition s1 or s2.

     Note that inside of a character class, all regular expression operators
     lose their special meaning except escape (`\') and the character class
     operators, `-', `]', and, at the beginning of the class, `^'.

     The regular expressions listed above are grouped according to precedence,
     from highest precedence at the top to lowest at the bottom.  Those
     grouped together have equal precedence.  For example,

           foo|bar*

     is the same as

           (foo)|(ba(r*))

     since the `*' operator has higher precedence than concatenation, and con-
     catenation higher than alternation (`|').  This pattern therefore matches
     either the string "foo" or the string "ba" followed by zero-or-more r's.
     To match "foo" or zero-or-more "bar"'s, use:

           foo|(bar)*

     and to match zero-or-more "foo"'s-or-"bar"'s:

           (foo|bar)*

     In addition to characters and ranges of characters, character classes can
     also contain character class expressions.  These are expressions enclosed
     inside `[:' and `:]' delimiters (which themselves must appear between the
     `[' and `]' of the character class; other elements may occur inside the
     character class, too).  The valid expressions are:

           [:alnum:] [:alpha:] [:blank:]
           [:cntrl:] [:digit:] [:graph:]
           [:lower:] [:print:] [:punct:]
           [:space:] [:upper:] [:xdigit:]

     These expressions all designate a set of characters equivalent to the
     corresponding standard C isXXX() function.  For example, [:alnum:] desig-
     nates those characters for which isalnum(3) returns true - i.e., any al-
     phabetic or numeric.  Some systems don't provide isblank(3), so flex de-
     fines [:blank:] as a blank or a tab.

     For example, the following character classes are all equivalent:

           [[:alnum:]]
           [[:alpha:][:digit:]]
           [[:alpha:]0-9]
           [a-zA-Z0-9]

     If the scanner is case-insensitive (the -i flag), then [:upper:] and
     [:lower:] are equivalent to [:alpha:].

     Some notes on patterns:

     -   A negated character class such as the example "[^A-Z]" above will
         match a newline unless "\n" (or an equivalent escape sequence) is one
         of the characters explicitly present in the negated character class
         (e.g., "[^A-Z\n]").  This is unlike how many other regular expression
         tools treat negated character classes, but unfortunately the incon-
         sistency is historically entrenched.  Matching newlines means that a
         pattern like "[^"]*" can match the entire input unless there's anoth-
         er quote in the input.

     -   A rule can have at most one instance of trailing context (the `/' op-
         erator or the `$' operator).  The start condition, `^', and "<<EOF>>"
         patterns can only occur at the beginning of a pattern, and, as well
         as with `/' and `$', cannot be grouped inside parentheses.  A `^'
         which does not occur at the beginning of a rule or a `$' which does
         not occur at the end of a rule loses its special properties and is
         treated as a normal character.

     -   The following are illegal:

               foo/bar$
               <sc1>foo<sc2>bar

         Note that the first of these, can be written "foo/bar\n".

     -   The following will result in `$' or `^' being treated as a normal
         character:

               foo|(bar$)
               foo|^bar

         If what's wanted is a "foo" or a bar-followed-by-a-newline, the fol-
         lowing could be used (the special `|' action is explained below):

               foo      |
               bar$     /* action goes here */

         A similar trick will work for matching a foo or a bar-at-the-begin-
         ning-of-a-line.

HOW THE INPUT IS MATCHED
     When the generated scanner is run, it analyzes its input looking for
     strings which match any of its patterns.  If it finds more than one
     match, it takes the one matching the most text (for trailing context
     rules, this includes the length of the trailing part, even though it will
     then be returned to the input).  If it finds two or more matches of the
     same length, the rule listed first in the flex input file is chosen.

     Once the match is determined, the text corresponding to the match (called
     the token) is made available in the global character pointer yytext, and
     its length in the global integer yyleng.  The action corresponding to the
     matched pattern is then executed (a more detailed description of actions
     follows), and then the remaining input is scanned for another match.

     If no match is found, then the default rule is executed: the next charac-
     ter in the input is considered matched and copied to the standard output.
     Thus, the simplest legal flex input is:

           %%

     which generates a scanner that simply copies its input (one character at
     a time) to its output.

     Note that yytext can be defined in two different ways: either as a char-
     acter pointer or as a character array.  Which definition flex uses can be
     controlled by including one of the special directives ``%pointer'' or
     ``%array'' in the first (definitions) section of flex input.  The default
     is ``%pointer'', unless the -l lex compatibility option is used, in which
     case yytext will be an array.  The advantage of using ``%pointer'' is
     substantially faster scanning and no buffer overflow when matching very
     large tokens (unless not enough dynamic memory is available).  The disad-
     vantage is that actions are restricted in how they can modify yytext (see
     the next section), and calls to the unput() function destroy the present
     contents of yytext, which can be a considerable porting headache when
     moving between different lex versions.

     The advantage of ``%array'' is that yytext can be modified as much as
     wanted, and calls to unput() do not destroy yytext (see below).  Further-
     more, existing lex programs sometimes access yytext externally using dec-
     larations of the form:

           extern char yytext[];

     This definition is erroneous when used with ``%pointer'', but correct for
     ``%array''.

     ``%array'' defines yytext to be an array of YYLMAX characters, which de-
     faults to a fairly large value.  The size can be changed by simply #de-
     fine'ing YYLMAX to a different value in the first section of flex input.
     As mentioned above, with ``%pointer'' yytext grows dynamically to accom-
     modate large tokens.  While this means a ``%pointer'' scanner can accom-
     modate very large tokens (such as matching entire blocks of comments),
     bear in mind that each time the scanner must resize yytext it also must
     rescan the entire token from the beginning, so matching such tokens can
     prove slow.  yytext presently does not dynamically grow if a call to
     unput() results in too much text being pushed back; instead, a run-time
     error results.

     Also note that ``%array'' cannot be used with C++ scanner classes (the
     c++ option; see below).

ACTIONS
     Each pattern in a rule has a corresponding action, which can be any arbi-
     trary C statement.  The pattern ends at the first non-escaped whitespace
     character; the remainder of the line is its action.  If the action is
     empty, then when the pattern is matched the input token is simply dis-
     carded.  For example, here is the specification for a program which
     deletes all occurrences of "zap me" from its input:

           %%
           "zap me"

     (It will copy all other characters in the input to the output since they
     will be matched by the default rule.)

     Here is a program which compresses multiple blanks and tabs down to a
     single blank, and throws away whitespace found at the end of a line:

           %%
           [ \t]+        putchar(' ');
           [ \t]+$       /* ignore this token */

     If the action contains a `{', then the action spans till the balancing
     `}' is found, and the action may cross multiple lines.  flex knows about
     C strings and comments and won't be fooled by braces found within them,
     but also allows actions to begin with `%{' and will consider the action
     to be all the text up to the next `%}' (regardless of ordinary braces
     inside the action).

     An action consisting solely of a vertical bar (`|') means "same as the
     action for the next rule".  See below for an illustration.

     Actions can include arbitrary C code, including return statements to re-
     turn a value to whatever routine called yylex().  Each time yylex() is
     called, it continues processing tokens from where it last left off until
     it either reaches the end of the file or executes a return.

     Actions are free to modify yytext except for lengthening it (adding char-
     acters to its end - these will overwrite later characters in the input
     stream).  This, however, does not apply when using ``%array'' (see
     above); in that case, yytext may be freely modified in any way.

     Actions are free to modify yyleng except they should not do so if the ac-
     tion also includes use of yymore() (see below).

     There are a number of special directives which can be included within an
     action:

     ECHO    Copies yytext to the scanner's output.

     BEGIN   Followed by the name of a start condition, places the scanner in
             the corresponding start condition (see below).

     REJECT  Directs the scanner to proceed on to the "second best" rule which
             matched the input (or a prefix of the input).  The rule is chosen
             as described above in HOW THE INPUT IS MATCHED, and yytext and
             yyleng set up appropriately.  It may either be one which matched
             as much text as the originally chosen rule but came later in the
             flex input file, or one which matched less text.  For example,
             the following will both count the words in the input and call the
             routine special() whenever "frob" is seen:

                   int word_count = 0;
                   %%

                   frob        special(); REJECT;
                   [^ \t\n]+   ++word_count;

             Without the REJECT, any "frob"'s in the input would not be count-
             ed as words, since the scanner normally executes only one action
             per token.  Multiple REJECT's are allowed, each one finding the
             next best choice to the currently active rule.  For example, when
             the following scanner scans the token "abcd", it will write
             "abcdabcaba" to the output:

                   %%
                   a        |
                   ab       |
                   abc      |
                   abcd     ECHO; REJECT;
                   .|\n     /* eat up any unmatched character */

             (The first three rules share the fourth's action since they use
             the special `|' action.)  REJECT is a particularly expensive fea-
             ture in terms of scanner performance; if it is used in any of the
             scanner's actions it will slow down all of the scanner's match-
             ing.  Furthermore, REJECT cannot be used with the -Cf or -CF op-
             tions (see below).

             Note also that unlike the other special actions, REJECT is a
             branch; code immediately following it in the action will not be
             executed.

     yymore()
             Tells the scanner that the next time it matches a rule, the cor-
             responding token should be appended onto the current value of
             yytext rather than replacing it.  For example, given the input
             "mega-kludge" the following will write "mega-mega-kludge" to the
             output:

                   %%
                   mega-    ECHO; yymore();
                   kludge   ECHO;

             First "mega-" is matched and echoed to the output.  Then "kludge"
             is matched, but the previous "mega-" is still hanging around at
             the beginning of yytext so the ECHO for the "kludge" rule will
             actually write "mega-kludge".

             Two notes regarding use of yymore(): First, yymore() depends on
             the value of yyleng correctly reflecting the size of the current
             token, so yyleng must not be modified when using yymore().  Sec-
             ond, the presence of yymore() in the scanner's action entails a
             minor performance penalty in the scanner's matching speed.

     yyless(n)
             Returns all but the first n characters of the current token back
             to the input stream, where they will be rescanned when the scan-
             ner looks for the next match.  yytext and yyleng are adjusted ap-
             propriately (e.g., yyleng will now be equal to n).  For example,
             on the input "foobar" the following will write out "foobarbar":

                   %%
                   foobar    ECHO; yyless(3);
                   [a-z]+    ECHO;

             An argument of 0 to yyless will cause the entire current input
             string to be scanned again.  Unless how the scanner will subse-
             quently process its input has been changed (using BEGIN, for ex-
             ample), this will result in an endless loop.

             Note that yyless is a macro and can only be used in the flex in-
             put file, not from other source files.

     unput(c)
             Puts the character c back into the input stream.  It will be the
             next character scanned.  The following action will take the cur-
             rent token and cause it to be rescanned enclosed in parentheses.

                   {
                           int i;
                           char *yycopy;

                           /* Copy yytext because unput() trashes yytext */
                           if ((yycopy = strdup(yytext)) == NULL)
                                   err(1, NULL);
                           unput(')');
                           for (i = yyleng - 1; i >= 0; --i)
                                   unput(yycopy[i]);
                           unput('(');
                           free(yycopy);
                   }

             Note that since each unput() puts the given character back at the
             beginning of the input stream, pushing back strings must be done
             back-to-front.

             An important potential problem when using unput() is that if us-
             ing ``%pointer'' (the default), a call to unput() destroys the
             contents of yytext, starting with its rightmost character and de-
             vouring one character to the left with each call.  If the value
             of yytext should be preserved after a call to unput() (as in the
             above example), it must either first be copied elsewhere, or the
             scanner must be built using ``%array'' instead (see HOW THE INPUT
             IS MATCHED).

             Finally, note that EOF cannot be put back to attempt to mark the
             input stream with an end-of-file.

     input()
             Reads the next character from the input stream.  For example, the
             following is one way to eat up C comments:

                   %%
                   "/*" {
                           int c;

                           for (;;) {
                                   while ((c = input()) != '*' && c != EOF)
                                           ; /* eat up text of comment */

                                   if (c == '*') {
                                           while ((c = input()) == '*')
                                                   ;
                                           if (c == '/')
                                                   break; /* found the end */
                                   }

                                   if (c == EOF) {
                                           errx(1, "EOF in comment");
                                           break;
                                   }
                           }
                   }

             (Note that if the scanner is compiled using C++, then input() is
             instead referred to as yyinput(), in order to avoid a name clash
             with the C++ stream by the name of input.)

     YY_FLUSH_BUFFER
             Flushes the scanner's internal buffer so that the next time the
             scanner attempts to match a token, it will first refill the
             buffer using YY_INPUT (see THE GENERATED SCANNER, below).  This
             action is a special case of the more general yy_flush_buffer()
             function, described below in the section MULTIPLE INPUT BUFFERS.

     yyterminate()
             Can be used in lieu of a return statement in an action.  It ter-
             minates the scanner and returns a 0 to the scanner's caller, in-
             dicating "all done".  By default, yyterminate() is also called
             when an end-of-file is encountered.  It is a macro and may be re-
             defined.

THE GENERATED SCANNER
     The output of flex is the file lex.yy.c, which contains the scanning rou-
     tine yylex(), a number of tables used by it for matching tokens, and a
     number of auxiliary routines and macros.  By default, yylex() is declared
     as follows:

           int yylex()
           {
               ... various definitions and the actions in here ...
           }

     (If the environment supports function prototypes, then it will be "int
     yylex(void)".)  This definition may be changed by defining the YY_DECL
     macro.  For example:

           #define YY_DECL float lexscan(a, b) float a, b;

     would give the scanning routine the name lexscan, returning a float, and
     taking two floats as arguments.  Note that if arguments are given to the
     scanning routine using a K&R-style/non-prototyped function declaration,
     the definition must be terminated with a semi-colon (`;').

     Whenever yylex() is called, it scans tokens from the global input file
     yyin (which defaults to stdin).  It continues until it either reaches an
     end-of-file (at which point it returns the value 0) or one of its actions
     executes a return statement.

     If the scanner reaches an end-of-file, subsequent calls are undefined un-
     less either yyin is pointed at a new input file (in which case scanning
     continues from that file), or yyrestart() is called.  yyrestart() takes
     one argument, a FILE * pointer (which can be nil, if YY_INPUT has been
     set up to scan from a source other than yyin), and initializes yyin for
     scanning from that file.  Essentially there is no difference between just
     assigning yyin to a new input file or using yyrestart() to do so; the
     latter is available for compatibility with previous versions of flex, and
     because it can be used to switch input files in the middle of scanning.
     It can also be used to throw away the current input buffer, by calling it
     with an argument of yyin; but better is to use YY_FLUSH_BUFFER (see
     above).  Note that yyrestart() does not reset the start condition to
     INITIAL (see START CONDITIONS, below).

     If yylex() stops scanning due to executing a return statement in one of
     the actions, the scanner may then be called again and it will resume
     scanning where it left off.

     By default (and for purposes of efficiency), the scanner uses block-reads
     rather than simple getc(3) calls to read characters from yyin.  The na-
     ture of how it gets its input can be controlled by defining the YY_INPUT
     macro.  YY_INPUT's calling sequence is "YY_INPUT(buf,result,max_size)".
     Its action is to place up to max_size characters in the character array
     buf and return in the integer variable result either the number of char-
     acters read or the constant YY_NULL (0 on UNIX systems) to indicate EOF.
     The default YY_INPUT reads from the global file-pointer "yyin".

     A sample definition of YY_INPUT (in the definitions section of the input
     file):

           %{
           #define YY_INPUT(buf,result,max_size) \
           { \
                   int c = getchar(); \
                   result = (c == EOF) ? YY_NULL : (buf[0] = c, 1); \
           }
           %}

     This definition will change the input processing to occur one character
     at a time.

     When the scanner receives an end-of-file indication from YY_INPUT, it
     then checks the yywrap() function.  If yywrap() returns false (zero),
     then it is assumed that the function has gone ahead and set up yyin to
     point to another input file, and scanning continues.  If it returns true
     (non-zero), then the scanner terminates, returning 0 to its caller.  Note
     that in either case, the start condition remains unchanged; it does not
     revert to INITIAL.

     If you do not supply your own version of yywrap(), then you must either
     use ``%option noyywrap'' (in which case the scanner behaves as though
     yywrap() returned 1), or you must link with -lfl to obtain the default
     version of the routine, which always returns 1.

     Three routines are available for scanning from in-memory buffers rather
     than files: yy_scan_string(), yy_scan_bytes(), and yy_scan_buffer().  See
     the discussion of them below in the section MULTIPLE INPUT BUFFERS.

     The scanner writes its ECHO output to the yyout global (default, stdout),
     which may be redefined by the user simply by assigning it to some other
     FILE pointer.

START CONDITIONS
     flex provides a mechanism for conditionally activating rules.  Any rule
     whose pattern is prefixed with "<sc>" will only be active when the scan-
     ner is in the start condition named "sc".  For example,

           <STRING>[^"]* { /* eat up the string body ... */
                   ...
           }

     will be active only when the scanner is in the "STRING" start condition,
     and

           <INITIAL,STRING,QUOTE>\. { /* handle an escape ... */
                   ...
           }

     will be active only when the current start condition is either "INITIAL",
     "STRING", or "QUOTE".

     Start conditions are declared in the definitions (first) section of the
     input using unindented lines beginning with either `%s' or `%x' followed
     by a list of names.  The former declares inclusive start conditions, the
     latter exclusive start conditions.  A start condition is activated using
     the BEGIN action.  Until the next BEGIN action is executed, rules with
     the given start condition will be active and rules with other start con-
     ditions will be inactive.  If the start condition is inclusive, then
     rules with no start conditions at all will also be active.  If it is ex-
     clusive, then only rules qualified with the start condition will be ac-
     tive.  A set of rules contingent on the same exclusive start condition
     describe a scanner which is independent of any of the other rules in the
     flex input.  Because of this, exclusive start conditions make it easy to
     specify "mini-scanners" which scan portions of the input that are syntac-
     tically different from the rest (e.g., comments).

     If the distinction between inclusive and exclusive start conditions is
     still a little vague, here's a simple example illustrating the connection
     between the two.  The set of rules:

           %s example
           %%

           <example>foo   do_something();

           bar            something_else();

     is equivalent to

           %x example
           %%

           <example>foo   do_something();

           <INITIAL,example>bar    something_else();

     Without the <INITIAL,example> qualifier, the ``bar'' pattern in the sec-
     ond example wouldn't be active (i.e., couldn't match) when in start con-
     dition ``example''.  If we just used <example> to qualify ``bar'',
     though, then it would only be active in ``example'' and not in INITIAL,
     while in the first example it's active in both, because in the first ex-
     ample the ``example'' start condition is an inclusive (`%s') start condi-
     tion.

     Also note that the special start-condition specifier `<*>' matches every
     start condition.  Thus, the above example could also have been written:

           %x example
           %%

           <example>foo   do_something();

           <*>bar         something_else();

     The default rule (to ECHO any unmatched character) remains active in
     start conditions.  It is equivalent to:

           <*>.|\n     ECHO;

     ``BEGIN(0)'' returns to the original state where only the rules with no
     start conditions are active.  This state can also be referred to as the
     start-condition INITIAL, so ``BEGIN(INITIAL)'' is equivalent to
     ``BEGIN(0)''.  (The parentheses around the start condition name are not
     required but are considered good style.)

     BEGIN actions can also be given as indented code at the beginning of the
     rules section.  For example, the following will cause the scanner to en-
     ter the "SPECIAL" start condition whenever yylex() is called and the
     global variable enter_special is true:

           int enter_special;

           %x SPECIAL
           %%
                   if (enter_special)
                           BEGIN(SPECIAL);

           <SPECIAL>blahblahblah
           ...more rules follow...

     To illustrate the uses of start conditions, here is a scanner which pro-
     vides two different interpretations of a string like "123.456".  By de-
     fault it will treat it as three tokens: the integer "123", a dot (`.'),
     and the integer "456".  But if the string is preceded earlier in the line
     by the string "expect-floats" it will treat it as a single token, the
     floating-point number 123.456:

           %{
           #include <math.h>
           %}
           %s expect

           %%
           expect-floats        BEGIN(expect);

           <expect>[0-9]+"."[0-9]+ {
                   printf("found a float, = %f\n",
                       atof(yytext));
           }
           <expect>\n {
                   /*
                    * That's the end of the line, so
                    * we need another "expect-number"
                    * before we'll recognize any more
                    * numbers.
                    */
                   BEGIN(INITIAL);
           }

           [0-9]+ {
                   printf("found an integer, = %d\n",
                       atoi(yytext));
           }

           "."     printf("found a dot\n");

     Here is a scanner which recognizes (and discards) C comments while main-
     taining a count of the current input line:

           %x comment
           %%
           int line_num = 1;

           "/*"                    BEGIN(comment);

           <comment>[^*\n]*        /* eat anything that's not a '*' */
           <comment>"*"+[^*/\n]*   /* eat up '*'s not followed by '/'s */
           <comment>\n             ++line_num;
           <comment>"*"+"/"        BEGIN(INITIAL);

     This scanner goes to a bit of trouble to match as much text as possible
     with each rule.  In general, when attempting to write a high-speed scan-
     ner try to match as much as possible in each rule, as it's a big win.

     Note that start-condition names are really integer values and can be
     stored as such.  Thus, the above could be extended in the following fash-
     ion:

           %x comment foo
           %%
           int line_num = 1;
           int comment_caller;

           "/*" {
                   comment_caller = INITIAL;
                   BEGIN(comment);
           }

           ...

           <foo>"/*" {
                   comment_caller = foo;
                   BEGIN(comment);
           }

           <comment>[^*\n]*        /* eat anything that's not a '*' */
           <comment>"*"+[^*/\n]*   /* eat up '*'s not followed by '/'s */
           <comment>\n             ++line_num;
           <comment>"*"+"/"        BEGIN(comment_caller);

     Furthermore, the current start condition can be accessed by using the in-
     teger-valued YY_START macro.  For example, the above assignments to
     comment_caller could instead be written

           comment_caller = YY_START;

     Flex provides YYSTATE as an alias for YY_START (since that is what's used
     by AT&T lex).

     Note that start conditions do not have their own name-space; %s's and
     %x's declare names in the same fashion as #define's.

     Finally, here's an example of how to match C-style quoted strings using
     exclusive start conditions, including expanded escape sequences (but not
     including checking for a string that's too long):

           %x str

           %%
           #define MAX_STR_CONST 1024
           char string_buf[MAX_STR_CONST];
           char *string_buf_ptr;

           \"      string_buf_ptr = string_buf; BEGIN(str);

           <str>\" { /* saw closing quote - all done */
                   BEGIN(INITIAL);
                   *string_buf_ptr = '\0';
                   /*
                    * return string constant token type and
                    * value to parser
                    */
           }

           <str>\n {
                   /* error - unterminated string constant */
                   /* generate error message */
           }

           <str>\\[0-7]{1,3} {
                   /* octal escape sequence */
                   int result;

                   (void) sscanf(yytext + 1, "%o", &result);

                   if (result > 0xff) {
                           /* error, constant is out-of-bounds */
                   } else
                           *string_buf_ptr++ = result;
           }

           <str>\\[0-9]+ {
                   /*
                    * generate error - bad escape sequence; something
                    * like '\48' or '\0777777'
                    */
           }

           <str>\\n  *string_buf_ptr++ = '\n';
           <str>\\t  *string_buf_ptr++ = '\t';
           <str>\\r  *string_buf_ptr++ = '\r';
           <str>\\b  *string_buf_ptr++ = '\b';
           <str>\\f  *string_buf_ptr++ = '\f';

           <str>\\(.|\n)  *string_buf_ptr++ = yytext[1];

           <str>[^\\\n\"]+ {
                   char *yptr = yytext;

                   while (*yptr)
                           *string_buf_ptr++ = *yptr++;
           }

     Often, such as in some of the examples above, a whole bunch of rules are
     all preceded by the same start condition(s).  flex makes this a little
     easier and cleaner by introducing a notion of start condition scope.  A
     start condition scope is begun with:

           <SCs>{

     where ``SCs'' is a list of one or more start conditions.  Inside the
     start condition scope, every rule automatically has the prefix <SCs> ap-
     plied to it, until a `}' which matches the initial `{'.  So, for example,

           <ESC>{
               "\\n"   return '\n';
               "\\r"   return '\r';
               "\\f"   return '\f';
               "\\0"   return '\0';
           }

     is equivalent to:

           <ESC>"\\n"  return '\n';
           <ESC>"\\r"  return '\r';
           <ESC>"\\f"  return '\f';
           <ESC>"\\0"  return '\0';

     Start condition scopes may be nested.

     Three routines are available for manipulating stacks of start conditions:

     void yy_push_state(int new_state)
             Pushes the current start condition onto the top of the start con-
             dition stack and switches to new_state as though ``BEGIN
             new_state'' had been used (recall that start condition names are
             also integers).

     void yy_pop_state()
             Pops the top of the stack and switches to it via BEGIN.

     int yy_top_state()
             Returns the top of the stack without altering the stack's con-
             tents.

     The start condition stack grows dynamically and so has no built-in size
     limitation.  If memory is exhausted, program execution aborts.

     To use start condition stacks, scanners must include a ``%option stack''
     directive (see OPTIONS below).

MULTIPLE INPUT BUFFERS
     Some scanners (such as those which support "include" files) require read-
     ing from several input streams.  As flex scanners do a large amount of
     buffering, one cannot control where the next input will be read from by
     simply writing a YY_INPUT which is sensitive to the scanning context.
     YY_INPUT is only called when the scanner reaches the end of its buffer,
     which may be a long time after scanning a statement such as an "include"
     which requires switching the input source.

     To negotiate these sorts of problems, flex provides a mechanism for cre-
     ating and switching between multiple input buffers.  An input buffer is
     created by using:

           YY_BUFFER_STATE yy_create_buffer(FILE *file, int size)

     which takes a FILE pointer and a size and creates a buffer associated
     with the given file and large enough to hold size characters (when in
     doubt, use YY_BUF_SIZE for the size).  It returns a YY_BUFFER_STATE han-
     dle, which may then be passed to other routines (see below).  The
     YY_BUFFER_STATE type is a pointer to an opaque ``struct yy_buffer_state''
     structure, so YY_BUFFER_STATE variables may be safely initialized to
     ``((YY_BUFFER_STATE) 0)'' if desired, and the opaque structure can also
     be referred to in order to correctly declare input buffers in source
     files other than that of scanners.  Note that the FILE pointer in the
     call to yy_create_buffer() is only used as the value of yyin seen by
     YY_INPUT; if YY_INPUT is redefined so that it no longer uses yyin, then a
     nil FILE pointer can safely be passed to yy_create_buffer().  To select a
     particular buffer to scan:

           void yy_switch_to_buffer(YY_BUFFER_STATE new_buffer)

     It switches the scanner's input buffer so subsequent tokens will come
     from new_buffer.  Note that yy_switch_to_buffer() may be used by yywrap()
     to set things up for continued scanning, instead of opening a new file
     and pointing yyin at it.  Note also that switching input sources via ei-
     ther yy_switch_to_buffer() or yywrap() does not change the start condi-
     tion.

           void yy_delete_buffer(YY_BUFFER_STATE buffer)

     is used to reclaim the storage associated with a buffer.  (buffer can be
     nil, in which case the routine does nothing.)  To clear the current con-
     tents of a buffer:

           void yy_flush_buffer(YY_BUFFER_STATE buffer)

     This function discards the buffer's contents, so the next time the scan-
     ner attempts to match a token from the buffer, it will first fill the
     buffer anew using YY_INPUT.

     yy_new_buffer() is an alias for yy_create_buffer(), provided for compati-
     bility with the C++ use of new and delete for creating and destroying dy-
     namic objects.

     Finally, the YY_CURRENT_BUFFER macro returns a YY_BUFFER_STATE handle to
     the current buffer.

     Here is an example of using these features for writing a scanner which
     expands include files (the <<EOF>> feature is discussed below):

           /*
            * the "incl" state is used for picking up the name
            * of an include file
            */
           %x incl

           %{
           #define MAX_INCLUDE_DEPTH 10
           YY_BUFFER_STATE include_stack[MAX_INCLUDE_DEPTH];
           int include_stack_ptr = 0;
           %}

           %%
           include             BEGIN(incl);

           [a-z]+              ECHO;
           [^a-z\n]*\n?        ECHO;

           <incl>[ \t]*        /* eat the whitespace */
           <incl>[^ \t\n]+ {   /* got the include file name */
                   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
                           errx(1, "Includes nested too deeply");

                   include_stack[include_stack_ptr++] =
                       YY_CURRENT_BUFFER;

                   yyin = fopen(yytext, "r");

                   if (yyin == NULL)
                           err(1, NULL);

                   yy_switch_to_buffer(
                       yy_create_buffer(yyin, YY_BUF_SIZE));

                   BEGIN(INITIAL);
           }

           <<EOF>> {
                   if (--include_stack_ptr < 0)
                           yyterminate();
                   else {
                           yy_delete_buffer(YY_CURRENT_BUFFER);
                           yy_switch_to_buffer(
                               include_stack[include_stack_ptr]);
                  }
           }

     Three routines are available for setting up input buffers for scanning
     in-memory strings instead of files.  All of them create a new input
     buffer for scanning the string, and return a corresponding
     YY_BUFFER_STATE handle (which should be deleted afterwards using
     yy_delete_buffer()).  They also switch to the new buffer using
     yy_switch_to_buffer(), so the next call to yylex() will start scanning
     the string.

     yy_scan_string(const char *str)
             Scans a NUL-terminated string.

     yy_scan_bytes(const char *bytes, int len)
             Scans len bytes (including possibly NUL's) starting at location
             bytes.

     Note that both of these functions create and scan a copy of the string or
     bytes.  (This may be desirable, since yylex() modifies the contents of
     the buffer it is scanning.)  The copy can be avoided by using:

     yy_scan_buffer(char *base, yy_size_t size)
             Which scans the buffer starting at base, consisting of size
             bytes, the last two bytes of which must be YY_END_OF_BUFFER_CHAR
             (ASCII NUL).  These last two bytes are not scanned; thus, scan-
             ning consists of base[0] through base[size-2], inclusive.

             If base is not set up in this manner (i.e., forget the final two
             YY_END_OF_BUFFER_CHAR bytes), then yy_scan_buffer() returns a nil
             pointer instead of creating a new input buffer.

             The type yy_size_t is an integral type which can be cast to an
             integer expression reflecting the size of the buffer.

END-OF-FILE RULES
     The special rule "<<EOF>>" indicates actions which are to be taken when
     an end-of-file is encountered and yywrap() returns non-zero (i.e.,
     indicates no further files to process).  The action must finish by doing
     one of four things:

     -   Assigning yyin to a new input file (in previous versions of flex, af-
         ter doing the assignment, it was necessary to call the special action
         YY_NEW_FILE; this is no longer necessary).

     -   Executing a return statement.

     -   Executing the special yyterminate() action.

     -   Switching to a new buffer using yy_switch_to_buffer() as shown in the
         example above.

     <<EOF>> rules may not be used with other patterns; they may only be qual-
     ified with a list of start conditions.  If an unqualified <<EOF>> rule is
     given, it applies to all start conditions which do not already have
     <<EOF>> actions.  To specify an <<EOF>> rule for only the initial start
     condition, use

           <INITIAL><<EOF>>

     These rules are useful for catching things like unclosed comments.  An
     example:

           %x quote
           %%

           ...other rules for dealing with quotes...

           <quote><<EOF>> {
                    error("unterminated quote");
                    yyterminate();
           }
           <<EOF>> {
                    if (*++filelist)
                            yyin = fopen(*filelist, "r");
                    else
                            yyterminate();
           }

MISCELLANEOUS MACROS
     The macro YY_USER_ACTION can be defined to provide an action which is al-
     ways executed prior to the matched rule's action.  For example, it could
     be #define'd to call a routine to convert yytext to lower-case.  When
     YY_USER_ACTION is invoked, the variable yy_act gives the number of the
     matched rule (rules are numbered starting with 1).  For example, to pro-
     file how often each rule is matched, the following would do the trick:

           #define YY_USER_ACTION ++ctr[yy_act]

     where ctr is an array to hold the counts for the different rules.  Note
     that the macro YY_NUM_RULES gives the total number of rules (including
     the default rule, even if -s is used), so a correct declaration for ctr
     is:

           int ctr[YY_NUM_RULES];

     The macro YY_USER_INIT may be defined to provide an action which is al-
     ways executed before the first scan (and before the scanner's internal
     initializations are done).  For example, it could be used to call a rou-
     tine to read in a data table or open a logging file.

     The macro yy_set_interactive(is_interactive) can be used to control
     whether the current buffer is considered interactive.  An interactive
     buffer is processed more slowly, but must be used when the scanner's in-
     put source is indeed interactive to avoid problems due to waiting to fill
     buffers (see the discussion of the -I flag below).  A non-zero value in
     the macro invocation marks the buffer as interactive, a zero value as
     non-interactive.  Note that use of this macro overrides ``%option always-
     interactive'' or ``%option never-interactive'' (see OPTIONS below).
     yy_set_interactive() must be invoked prior to beginning to scan the
     buffer that is (or is not) to be considered interactive.

     The macro yy_set_bol(at_bol) can be used to control whether the current
     buffer's scanning context for the next token match is done as though at
     the beginning of a line.  A non-zero macro argument makes rules anchored
     with `^' active, while a zero argument makes `^' rules inactive.

     The macro YY_AT_BOL returns true if the next token scanned from the cur-
     rent buffer will have `^' rules active, false otherwise.

     In the generated scanner, the actions are all gathered in one large
     switch statement and separated using YY_BREAK, which may be redefined.
     By default, it is simply a "break", to separate each rule's action from
     the following rules.  Redefining YY_BREAK allows, for example, C++ users
     to ``#define YY_BREAK'' to do nothing (while being very careful that ev-
     ery rule ends with a "break" or a "return"!) to avoid suffering from un-
     reachable statement warnings where because a rule's action ends with
     ``return'', the YY_BREAK is inaccessible.

VALUES AVAILABLE TO THE USER
     This section summarizes the various values available to the user in the
     rule actions.

     char *yytext
             Holds the text of the current token.  It may be modified but not
             lengthened (characters cannot be appended to the end).

             If the special directive ``%array'' appears in the first section
             of the scanner description, then yytext is instead declared
             ``char yytext[YYLMAX]'', where YYLMAX is a macro definition that
             can be redefined in the first section to change the default value
             (generally 8KB).  Using ``%array'' results in somewhat slower
             scanners, but the value of yytext becomes immune to calls to
             input() and unput(), which potentially destroy its value when
             yytext is a character pointer.  The opposite of ``%array'' is
             ``%pointer'', which is the default.

             ``%array'' cannot be used when generating C++ scanner classes
             (the -+ flag).

     int yyleng
             Holds the length of the current token.

     FILE *yyin
             Is the file which by default flex reads from.  It may be rede-
             fined, but doing so only makes sense before scanning begins or
             after an EOF has been encountered.  Changing it in the midst of
             scanning will have unexpected results since flex buffers its in-
             put; use yyrestart() instead.  Once scanning terminates because
             an end-of-file has been seen, yyin can be assigned as the new in-
             put file and the scanner can be called again to continue scan-
             ning.

     void yyrestart(FILE *new_file)
             May be called to point yyin at the new input file.  The switch-
             over to the new file is immediate (any previously buffered-up
             input is lost).  Note that calling yyrestart() with yyin as an
             argument thus throws away the current input buffer and continues
             scanning the same input file.

     FILE *yyout
             Is the file to which ECHO actions are done.  It can be reassigned
             by the user.

     YY_CURRENT_BUFFER
             Returns a YY_BUFFER_STATE handle to the current buffer.

     YY_START
             Returns an integer value corresponding to the current start con-
             dition.  This value can subsequently be used with BEGIN to return
             to that start condition.

INTERFACING WITH YACC
     One of the main uses of flex is as a companion to the yacc(1) parser-gen-
     erator.  yacc parsers expect to call a routine named yylex() to find the
     next input token.  The routine is supposed to return the type of the next
     token as well as putting any associated value in the global yylval, which
     is defined externally, and can be a union or any other complex data
     structure.  To use flex with yacc, one specifies the -d option to yacc to
     instruct it to generate the file y.tab.h containing definitions of all
     the ``%tokens'' appearing in the yacc input.  This file is then included
     in the flex scanner.  For example, if one of the tokens is "TOK_NUMBER",
     part of the scanner might look like:

           %{
           #include "y.tab.h"
           %}

           %%

           [0-9]+        yylval = atoi(yytext); return TOK_NUMBER;

OPTIONS
     flex has the following options:

     -7      Instructs flex to generate a 7-bit scanner, i.e., one which can
             only recognize 7-bit characters in its input.  The advantage of
             using -7 is that the scanner's tables can be up to half the size
             of those generated using the -8 option (see below).  The disad-
             vantage is that such scanners often hang or crash if their input
             contains an 8-bit character.

             Note, however, that unless generating a scanner using the -Cf or
             -CF table compression options, use of -7 will save only a small
             amount of table space, and make the scanner considerably less
             portable.  flex's default behavior is to generate an 8-bit scan-
             ner unless -Cf or -CF is specified, in which case flex defaults
             to generating 7-bit scanners unless it was configured to generate
             8-bit scanners (as will often be the case with non-USA sites).
             It is possible tell whether flex generated a 7-bit or an 8-bit
             scanner by inspecting the flag summary in the -v output as de-
             scribed below.

             Note that if -Cfe or -CFe are used (the table compression op-
             tions, but also using equivalence classes as discussed below),
             flex still defaults to generating an 8-bit scanner, since usually
             with these compression options full 8-bit tables are not much
             more expensive than 7-bit tables.

     -8      Instructs flex to generate an 8-bit scanner, i.e., one which can
             recognize 8-bit characters.  This flag is only needed for scan-
             ners generated using -Cf or -CF, as otherwise flex defaults to
             generating an 8-bit scanner anyway.

             See the discussion of -7 above for flex's default behavior and
             the tradeoffs between 7-bit and 8-bit scanners.

     -B      Instructs flex to generate a batch scanner, the opposite of
             interactive scanners generated by -I (see below).  In general, -B
             is used when the scanner will never be used interactively, and
             you want to squeeze a little more performance out of it.  If the
             aim is instead to squeeze out a lot more performance, use the -Cf
             or -CF options (discussed below), which turn on -B automatically
             anyway.

     -b      Generate backing-up information to lex.backup.  This is a list of
             scanner states which require backing up and the input characters
             on which they do so.  By adding rules one can remove backing-up
             states.  If all backing-up states are eliminated and -Cf or -CF
             is used, the generated scanner will run faster (see the -p flag).
             Only users who wish to squeeze every last cycle out of their
             scanners need worry about this option.  (See the section on
             PERFORMANCE CONSIDERATIONS below.)

     -C[aeFfmr]
             Controls the degree of table compression and, more generally,
             trade-offs between small scanners and fast scanners.

             -Ca     Instructs flex to trade off larger tables in the generat-
                     ed scanner for faster performance because the elements of
                     the tables are better aligned for memory access and com-
                     putation.  On some RISC architectures, fetching and ma-
                     nipulating longwords is more efficient than with smaller-
                     sized units such as shortwords.  This option can double
                     the size of the tables used by the scanner.

             -Ce     Directs flex to construct equivalence classes, i.e., sets
                     of characters which have identical lexical properties
                     (for example, if the only appearance of digits in the
                     flex input is in the character class "[0-9]" then the
                     digits `0', `1', `...', `9' will all be put in the same
                     equivalence class).  Equivalence classes usually give
                     dramatic reductions in the final table/object file sizes
                     (typically a factor of 2-5) and are pretty cheap perfor-
                     mance-wise (one array look-up per character scanned).

             -CF     Specifies that the alternate fast scanner representation
                     (described below under the -F option) should be used.
                     This option cannot be used with -+.

             -Cf     Specifies that the full scanner tables should be generat-
                     ed - flex should not compress the tables by taking advan-
                     tage of similar transition functions for different
                     states.

             -Cm     Directs flex to construct meta-equivalence classes, which
                     are sets of equivalence classes (or characters, if equiv-
                     alence classes are not being used) that are commonly used
                     together.  Meta-equivalence classes are often a big win
                     when using compressed tables, but they have a moderate
                     performance impact (one or two "if" tests and one array
                     look-up per character scanned).

             -Cr     Causes the generated scanner to bypass use of the stan-
                     dard I/O library (stdio) for input.  Instead of calling
                     fread(3) or getc(3), the scanner will use the read(2)
                     system call, resulting in a performance gain which varies
                     from system to system, but in general is probably negli-
                     gible unless -Cf or -CF are being used.  Using -Cr can
                     cause strange behavior if, for example, reading from yyin
                     using stdio prior to calling the scanner (because the
                     scanner will miss whatever text previous reads left in
                     the stdio input buffer).

                     -Cr has no effect if YY_INPUT is defined (see THE
                     GENERATED SCANNER above).

             A lone -C specifies that the scanner tables should be compressed
             but neither equivalence classes nor meta-equivalence classes
             should be used.

             The options -Cf or -CF and -Cm do not make sense together - there
             is no opportunity for meta-equivalence classes if the table is
             not being compressed.  Otherwise the options may be freely mixed,
             and are cumulative.

             The default setting is -Cem which specifies that flex should gen-
             erate equivalence classes and meta-equivalence classes.  This
             setting provides the highest degree of table compression.  It is
             possible to trade off faster-executing scanners at the cost of
             larger tables with the following generally being true:

                   slowest & smallest
                         -Cem
                         -Cm
                         -Ce
                         -C
                         -C{f,F}e
                         -C{f,F}
                         -C{f,F}a
                   fastest & largest

             Note that scanners with the smallest tables are usually generated
             and compiled the quickest, so during development the default is
             usually best, maximal compression.

             -Cfe is often a good compromise between speed and size for pro-
             duction scanners.

     -c      A do-nothing, deprecated option included for POSIX compliance.

     -d      Makes the generated scanner run in debug mode.  Whenever a pat-
             tern is recognized and the global yy_flex_debug is non-zero
             (which is the default), the scanner will write to stderr a line
             of the form:

                   --accepting rule at line 53 ("the matched text")

             The line number refers to the location of the rule in the file
             defining the scanner (i.e., the file that was fed to flex).  Mes-
             sages are also generated when the scanner backs up, accepts the
             default rule, reaches the end of its input buffer (or encounters
             a NUL; at this point, the two look the same as far as the scan-
             ner's concerned), or reaches an end-of-file.

     -F      Specifies that the fast scanner table representation should be
             used (and stdio bypassed).  This representation is about as fast
             as the full table representation (-f), and for some sets of pat-
             terns will be considerably smaller (and for others, larger).  In
             general, if the pattern set contains both "keywords" and a catch-
             all, "identifier" rule, such as in the set:

                   "case"    return TOK_CASE;
                   "switch"  return TOK_SWITCH;
                   ...
                   "default" return TOK_DEFAULT;
                   [a-z]+    return TOK_ID;

             then it's better to use the full table representation.  If only
             the "identifier" rule is present and a hash table or some such is
             used to detect the keywords, it's better to use -F.

             This option is equivalent to -CFr (see above).  It cannot be used
             with -+.

     -f      Specifies fast scanner.  No table compression is done and stdio
             is bypassed.  The result is large but fast.  This option is
             equivalent to -Cfr (see above).

     -h      Generates a help summary of flex's options to stdout and then ex-
             its.  -? and --help are synonyms for -h.

     -I      Instructs flex to generate an interactive scanner.  An interac-
             tive scanner is one that only looks ahead to decide what token
             has been matched if it absolutely must.  It turns out that always
             looking one extra character ahead, even if the scanner has al-
             ready seen enough text to disambiguate the current token, is a
             bit faster than only looking ahead when necessary.  But scanners
             that always look ahead give dreadful interactive performance; for
             example, when a user types a newline, it is not recognized as a
             newline token until they enter another token, which often means
             typing in another whole line.

             flex scanners default to interactive unless -Cf or -CF table-com-
             pression options are specified (see above).  That's because if
             high-performance is most important, one of these options should
             be used, so if they weren't, flex assumes it is preferable to
             trade off a bit of run-time performance for intuitive interactive
             behavior.  Note also that -I cannot be used in conjunction with
             -Cf or -CF.  Thus, this option is not really needed; it is on by
             default for all those cases in which it is allowed.

             A scanner can be forced to not be interactive by using -B (see
             above).

     -i      Instructs flex to generate a case-insensitive scanner.  The case
             of letters given in the flex input patterns will be ignored, and
             tokens in the input will be matched regardless of case.  The
             matched text given in yytext will have the preserved case (i.e.,
             it will not be folded).

     -L      Instructs flex not to generate ``#line'' directives.  Without
             this option, flex peppers the generated scanner with #line direc-
             tives so error messages in the actions will be correctly located
             with respect to either the original flex input file (if the er-
             rors are due to code in the input file), or lex.yy.c (if the er-
             rors are flex's fault - these sorts of errors should be reported
             to the email address given below).

     -l      Turns on maximum compatibility with the original AT&T lex imple-
             mentation.  Note that this does not mean full compatibility.  Use
             of this option costs a considerable amount of performance, and it
             cannot be used with the -+, -f, -F, -Cf, or -CF options.  For de-
             tails on the compatibilities it provides, see the section
             INCOMPATIBILITIES WITH LEX AND POSIX below.  This option also re-
             sults in the name YY_FLEX_LEX_COMPAT being #define'd in the gen-
             erated scanner.

     -n      Another do-nothing, deprecated option included only for POSIX
             compliance.

     -ooutput
             Directs flex to write the scanner to the file output instead of
             lex.yy.c.  If -o is combined with the -t option, then the scanner
             is written to stdout but its ``#line'' directives (see the -L op-
             tion above) refer to the file output.

     -Pprefix
             Changes the default "yy" prefix used by flex for all globally
             visible variable and function names to instead be prefix.  For
             example, -Pfoo changes the name of yytext to footext.  It also
             changes the name of the default output file from lex.yy.c to
             lex.foo.c.  Here are all of the names affected:

                   yy_create_buffer
                   yy_delete_buffer
                   yy_flex_debug
                   yy_init_buffer
                   yy_flush_buffer
                   yy_load_buffer_state
                   yy_switch_to_buffer
                   yyin
                   yyleng
                   yylex
                   yylineno
                   yyout
                   yyrestart
                   yytext
                   yywrap

             (If using a C++ scanner, then only yywrap and yyFlexLexer are af-
             fected.)  Within the scanner itself, it is still possible to re-
             fer to the global variables and functions using either version of
             their name; but externally, they have the modified name.

             This option allows multiple flex programs to be easily linked to-
             gether into the same executable.  Note, though, that using this
             option also renames yywrap(), so now either an (appropriately
             named) version of the routine for the scanner must be supplied,
             or ``%option noyywrap'' must be used, as linking with -lfl no
             longer provides one by default.

     -p      Generates a performance report to stderr.  The report consists of
             comments regarding features of the flex input file which will
             cause a serious loss of performance in the resulting scanner.  If
             the flag is specified twice, comments regarding features that
             lead to minor performance losses will also be reported>

             Note that the use of REJECT, ``%option yylineno'', and variable
             trailing context (see the BUGS section below) entails a substan-
             tial performance penalty; use of yymore(), the `^' operator, and
             the -I flag entail minor performance penalties.

     -Sskeleton
             Overrides the default skeleton file from which flex constructs
             its scanners.  This option is needed only for flex maintenance or
             development.

     -s      Causes the default rule (that unmatched scanner input is echoed
             to stdout) to be suppressed.  If the scanner encounters input
             that does not match any of its rules, it aborts with an error.
             This option is useful for finding holes in a scanner's rule set.

     -T      Makes flex run in trace mode.  It will generate a lot of messages
             to stderr concerning the form of the input and the resultant non-
             deterministic and deterministic finite automata.  This option is
             mostly for use in maintaining flex.

     -t      Instructs flex to write the scanner it generates to standard out-
             put instead of lex.yy.c.

     -V      Prints the version number to stdout and exits.  --version is a
             synonym for -V.

     -v      Specifies that flex should write to stderr a summary of statis-
             tics regarding the scanner it generates.  Most of the statistics
             are meaningless to the casual flex user, but the first line iden-
             tifies the version of flex (same as reported by -V), and the next
             line the flags used when generating the scanner, including those
             that are on by default.

     -w      Suppresses warning messages.

     -+      Specifies that flex should generate a C++ scanner class.  See the
             section on GENERATING C++ SCANNERS below for details.

     flex also provides a mechanism for controlling options within the scanner
     specification itself, rather than from the flex command-line.  This is
     done by including ``%option'' directives in the first section of the
     scanner specification.  Multiple options can be specified with a single
     ``%option'' directive, and multiple directives in the first section of
     the flex input file.

     Most options are given simply as names, optionally preceded by the word
     "no" (with no intervening whitespace) to negate their meaning.  A number
     are equivalent to flex flags or their negation:

           7bit            -7 option
           8bit            -8 option
           align           -Ca option
           backup          -b option
           batch           -B option
           c++             -+ option

           caseful or
           case-sensitive  opposite of -i (default)

           case-insensitive or
           caseless        -i option

           debug           -d option
           default         opposite of -s option
           ecs             -Ce option
           fast            -F option
           full            -f option
           interactive     -I option
           lex-compat      -l option
           meta-ecs        -Cm option
           perf-report     -p option
           read            -Cr option
           stdout          -t option
           verbose         -v option
           warn            opposite of -w option
                           (use "%option nowarn" for -w)

           array           equivalent to "%array"
           pointer         equivalent to "%pointer" (default)

     Some %option's provide features otherwise not available:

     always-interactive
             Instructs flex to generate a scanner which always considers its
             input "interactive".  Normally, on each new input file the scan-
             ner calls isatty() in an attempt to determine whether the scan-
             ner's input source is interactive and thus should be read a char-
             acter at a time.  When this option is used, however, no such call
             is made.

     main    Directs flex to provide a default main() program for the scanner,
             which simply calls yylex().  This option implies ``noyywrap''
             (see below).

     never-interactive
             Instructs flex to generate a scanner which never considers its
             input "interactive" (again, no call made to isatty()).  This is
             the opposite of ``always-interactive''.

     stack   Enables the use of start condition stacks (see START CONDITIONS
             above).

     stdinit
             If set (i.e., ``%option stdinit''), initializes yyin and yyout to
             stdin and stdout, instead of the default of ``nil''.  Some exist-
             ing lex programs depend on this behavior, even though it is not
             compliant with ANSI C, which does not require stdin and stdout to
             be compile-time constant.

     yylineno
             Directs flex to generate a scanner that maintains the number of
             the current line read from its input in the global variable
             yylineno.  This option is implied by ``%option lex-compat''.

     yywrap  If unset (i.e., ``%option noyywrap''), makes the scanner not call
             yywrap() upon an end-of-file, but simply assume that there are no
             more files to scan (until the user points yyin at a new file and
             calls yylex() again).

     flex scans rule actions to determine whether the REJECT or yymore() fea-
     tures are being used.  The ``reject'' and ``yymore'' options are avail-
     able to override its decision as to whether to use the options, either by
     setting them (e.g., ``%option reject'') to indicate the feature is indeed
     used, or unsetting them to indicate it actually is not used (e.g.,
     ``%option noyymore'').

     Three options take string-delimited values, offset with `=':

           %option outfile="ABC"

     is equivalent to -oABC, and

           %option prefix="XYZ"

     is equivalent to -PXYZ.  Finally,

           %option yyclass="foo"

     only applies when generating a C++ scanner (-+ option).  It informs flex
     that ``foo'' has been derived as a subclass of yyFlexLexer, so flex will
     place actions in the member function ``foo::yylex()'' instead of
     ``yyFlexLexer::yylex()''.  It also generates a ``yyFlexLexer::yylex()''
     member function that emits a run-time error (by invoking
     ``yyFlexLexer::LexerError()'') if called.  See GENERATING C++ SCANNERS,
     below, for additional information.

     A number of options are available for lint(1) purists who want to sup-
     press the appearance of unneeded routines in the generated scanner.  Each
     of the following, if unset (e.g., ``%option nounput''), results in the
     corresponding routine not appearing in the generated scanner:

           input, unput
           yy_push_state, yy_pop_state, yy_top_state
           yy_scan_buffer, yy_scan_bytes, yy_scan_string

     (though yy_push_state() and friends won't appear anyway unless ``%option
     stack'' is being used).

PERFORMANCE CONSIDERATIONS
     The main design goal of flex is that it generate high-performance scan-
     ners.  It has been optimized for dealing well with large sets of rules.
     Aside from the effects on scanner speed of the table compression -C op-
     tions outlined above, there are a number of options/actions which degrade
     performance.  These are, from most expensive to least:

           REJECT
           %option yylineno
           arbitrary trailing context

           pattern sets that require backing up
           %array
           %option interactive
           %option always-interactive

           '^' beginning-of-line operator
           yymore()

     with the first three all being quite expensive and the last two being
     quite cheap.  Note also that unput() is implemented as a routine call
     that potentially does quite a bit of work, while yyless() is a quite-
     cheap macro; so if just putting back some excess text, use yyless().

     REJECT should be avoided at all costs when performance is important.  It
     is a particularly expensive option.

     Getting rid of backing up is messy and often may be an enormous amount of
     work for a complicated scanner.  In principal, one begins by using the -b
     flag to generate a lex.backup file.  For example, on the input

           %%
           foo        return TOK_KEYWORD;
           foobar     return TOK_KEYWORD;

     the file looks like:

           State #6 is non-accepting -
            associated rule line numbers:
                  2       3
            out-transitions: [ o ]
            jam-transitions: EOF [ \001-n  p-\177 ]

           State #8 is non-accepting -
            associated rule line numbers:
                  3
            out-transitions: [ a ]
            jam-transitions: EOF [ \001-`  b-\177 ]

           State #9 is non-accepting -
            associated rule line numbers:
                  3
            out-transitions: [ r ]
            jam-transitions: EOF [ \001-q  s-\177 ]

           Compressed tables always back up.

     The first few lines tell us that there's a scanner state in which it can
     make a transition on an `o' but not on any other character, and that in
     that state the currently scanned text does not match any rule.  The state
     occurs when trying to match the rules found at lines 2 and 3 in the input
     file.  If the scanner is in that state and then reads something other
     than an `o', it will have to back up to find a rule which is matched.
     With a bit of headscratching one can see that this must be the state it's
     in when it has seen `fo'.  When this has happened, if anything other than
     another `o' is seen, the scanner will have to back up to simply match the
     `f' (by the default rule).

     The comment regarding State #8 indicates there's a problem when "foob"
     has been scanned.  Indeed, on any character other than an `a', the scan-
     ner will have to back up to accept "foo".  Similarly, the comment for
     State #9 concerns when "fooba" has been scanned and an `r' does not fol-
     low.

     The final comment reminds us that there's no point going to all the trou-
     ble of removing backing up from the rules unless we're using -Cf or -CF,
     since there's no performance gain doing so with compressed scanners.

     The way to remove the backing up is to add "error" rules:

           %%
           foo    return TOK_KEYWORD;
           foobar return TOK_KEYWORD;

           fooba  |
           foob   |
           fo {
                   /* false alarm, not really a keyword */
                   return TOK_ID;
           }

     Eliminating backing up among a list of keywords can also be done using a
     "catch-all" rule:

           %%
           foo    return TOK_KEYWORD;
           foobar return TOK_KEYWORD;

           [a-z]+ return TOK_ID;

     This is usually the best solution when appropriate.

     Backing up messages tend to cascade.  With a complicated set of rules
     it's not uncommon to get hundreds of messages.  If one can decipher them,
     though, it often only takes a dozen or so rules to eliminate the backing
     up (though it's easy to make a mistake and have an error rule accidental-
     ly match a valid token; a possible future flex feature will be to auto-
     matically add rules to eliminate backing up).

     It's important to keep in mind that the benefits of eliminating backing
     up are gained only if every instance of backing up is eliminated.  Leav-
     ing just one gains nothing.

     Variable trailing context (where both the leading and trailing parts do
     not have a fixed length) entails almost the same performance loss as
     REJECT (i.e., substantial).  So when possible a rule like:

           %%
           mouse|rat/(cat|dog)   run();

     is better written:

           %%
           mouse/cat|dog         run();
           rat/cat|dog           run();

     or as

           %%
           mouse|rat/cat         run();
           mouse|rat/dog         run();

     Note that here the special `|' action does not provide any savings, and
     can even make things worse (see BUGS below).

     Another area where the user can increase a scanner's performance (and one
     that's easier to implement) arises from the fact that the longer the to-
     kens matched, the faster the scanner will run.  This is because with long
     tokens the processing of most input characters takes place in the (short)
     inner scanning loop, and does not often have to go through the additional
     work of setting up the scanning environment (e.g., yytext) for the ac-
     tion.  Recall the scanner for C comments:

           %x comment
           %%
           int line_num = 1;

           "/*"                    BEGIN(comment);

           <comment>[^*\n]*
           <comment>"*"+[^*/\n]*
           <comment>\n             ++line_num;
           <comment>"*"+"/"        BEGIN(INITIAL);

     This could be sped up by writing it as:

           %x comment
           %%
           int line_num = 1;

           "/*"                    BEGIN(comment);

           <comment>[^*\n]*
           <comment>[^*\n]*\n      ++line_num;
           <comment>"*"+[^*/\n]*
           <comment>"*"+[^*/\n]*\n ++line_num;
           <comment>"*"+"/"        BEGIN(INITIAL);

     Now instead of each newline requiring the processing of another action,
     recognizing the newlines is "distributed" over the other rules to keep
     the matched text as long as possible.  Note that adding rules does not
     slow down the scanner!  The speed of the scanner is independent of the
     number of rules or (modulo the considerations given at the beginning of
     this section) how complicated the rules are with regard to operators such
     as `*' and `|'.

     A final example in speeding up a scanner: scan through a file containing
     identifiers and keywords, one per line and with no other extraneous char-
     acters, and recognize all the keywords.  A natural first approach is:

           %%
           asm      |
           auto     |
           break    |
           ... etc ...
           volatile |
           while    /* it's a keyword */

           .|\n     /* it's not a keyword */

     To eliminate the back-tracking, introduce a catch-all rule:

           %%
           asm      |
           auto     |
           break    |
           ... etc ...
           volatile |
           while    /* it's a keyword */

           [a-z]+   |
           .|\n     /* it's not a keyword */

     Now, if it's guaranteed that there's exactly one word per line, then we
     can reduce the total number of matches by a half by merging in the recog-
     nition of newlines with that of the other tokens:

           %%
           asm\n      |
           auto\n     |
           break\n    |
           ... etc ...
           volatile\n |
           while\n    /* it's a keyword */

           [a-z]+\n   |
           .|\n       /* it's not a keyword */

     One has to be careful here, as we have now reintroduced backing up into
     the scanner.  In particular, while we know that there will never be any
     characters in the input stream other than letters or newlines, flex can't
     figure this out, and it will plan for possibly needing to back up when it
     has scanned a token like "auto" and then the next character is something
     other than a newline or a letter.  Previously it would then just match
     the "auto" rule and be done, but now it has no "auto" rule, only an
     "auto\n" rule.  To eliminate the possibility of backing up, we could ei-
     ther duplicate all rules but without final newlines, or, since we never
     expect to encounter such an input and therefore don't how it's classi-
     fied, we can introduce one more catch-all rule, this one which doesn't
     include a newline:

           %%
           asm\n      |
           auto\n     |
           break\n    |
           ... etc ...
           volatile\n |
           while\n    /* it's a keyword */

           [a-z]+\n   |
           [a-z]+     |
           .|\n       /* it's not a keyword */

     Compiled with -Cf, this is about as fast as one can get a flex scanner to
     go for this particular problem.

     A final note: flex is slow when matching NUL's, particularly when a token
     contains multiple NUL's.  It's best to write rules which match short
     amounts of text if it's anticipated that the text will often include
     NUL's.

     Another final note regarding performance: as mentioned above in the sec-
     tion HOW THE INPUT IS MATCHED, dynamically resizing yytext to accommodate
     huge tokens is a slow process because it presently requires that the
     (huge) token be rescanned from the beginning.  Thus if performance is vi-
     tal, it is better to attempt to match "large" quantities of text but not
     "huge" quantities, where the cutoff between the two is at about 8K char-
     acters/token.

GENERATING C++ SCANNERS
     flex provides two different ways to generate scanners for use with C++.
     The first way is to simply compile a scanner generated by flex using a
     C++ compiler instead of a C compiler.  This should not generate any com-
     pilation errors (please report any found to the email address given in
     the AUTHORS section below).  C++ code can then be used in rule actions
     instead of C code.  Note that the default input source for scanners re-
     mains yyin, and default echoing is still done to yyout.  Both of these
     remain FILE * variables and not C++ streams.

     flex can also be used to generate a C++ scanner class, using the -+ op-
     tion (or, equivalently, ``%option c++''), which is automatically speci-
     fied if the name of the flex executable ends in a `+', such as flex++.
     When using this option, flex defaults to generating the scanner to the
     file lex.yy.cc instead of lex.yy.c.  The generated scanner includes the
     header file <g++/FlexLexer.h>, which defines the interface to two C++
     classes.

     The first class, FlexLexer, provides an abstract base class defining the
     general scanner class interface.  It provides the following member func-
     tions:

     const char* YYText()
             Returns the text of the most recently matched token, the equiva-
             lent of yytext.

     int YYLeng()
             Returns the length of the most recently matched token, the equiv-
             alent of yyleng.

     int lineno() const
             Returns the current input line number (see ``%option yylineno''),
             or 1 if ``%option yylineno'' was not used.

     void set_debug(int flag)
             Sets the debugging flag for the scanner, equivalent to assigning
             to yy_flex_debug (see the OPTIONS section above).  Note that the
             scanner must be built using ``%option debug'' to include debug-
             ging information in it.

     int debug() const
             Returns the current setting of the debugging flag.

     Also provided are member functions equivalent to yy_switch_to_buffer(),
     yy_create_buffer() (though the first argument is an std::istream* object
     pointer and not a FILE*), yy_flush_buffer(), yy_delete_buffer(), and
     yyrestart() (again, the first argument is an std::istream* object point-
     er).

     The second class defined in <g++/FlexLexer.h> is yyFlexLexer, which is
     derived from FlexLexer.  It defines the following additional member func-
     tions:

     yyFlexLexer(std::istream* arg_yyin = 0, std::ostream* arg_yyout = 0)
             Constructs a yyFlexLexer object using the given streams for input
             and output.  If not specified, the streams default to cin and
             cout, respectively.

     virtual int yylex()
             Performs the same role as yylex() does for ordinary flex scan-
             ners: it scans the input stream, consuming tokens, until a rule's
             action returns a value.  If subclass `S' is derived from
             yyFlexLexer, in order to access the member functions and vari-
             ables of `S' inside yylex(), use ``%option yyclass="S"'' to in-
             form flex that the `S' subclass will be used instead of
             yyFlexLexer.  In this case, rather than generating
             ``yyFlexLexer::yylex()'', flex generates ``S::yylex()'' (and also
             generates a dummy ``yyFlexLexer::yylex()'' that calls
             ``yyFlexLexer::LexerError()'' if called).

     virtual void switch_streams(std::istream* new_in = 0, std::ostream*
             new_out = 0)
             Reassigns yyin to new_in (if non-nil) and yyout to new_out
             (ditto), deleting the previous input buffer if yyin is reas-
             signed.

     int yylex(std::istream* new_in, std::ostream* new_out = 0)
             First switches the input streams via ``switch_streams(new_in,
             new_out)'' and then returns the value of yylex().

     In addition, yyFlexLexer defines the following protected virtual func-
     tions which can be redefined in derived classes to tailor the scanner:

     virtual int LexerInput(char* buf, int max_size)
             Reads up to max_size characters into buf and returns the number
             of characters read.  To indicate end-of-input, return 0 charac-
             ters.  Note that "interactive" scanners (see the -B and -I flags)
             define the macro YY_INTERACTIVE.  If LexerInput() has been rede-
             fined, and it's necessary to take different actions depending on
             whether or not the scanner might be scanning an interactive input
             source, it's possible to test for the presence of this name via
             ``#ifdef''.

     virtual void LexerOutput(const char* buf, int size)
             Writes out size characters from the buffer buf, which, while NUL-
             terminated, may also contain "internal" NUL's if the scanner's
             rules can match text with NUL's in them.

     virtual void LexerError(const char* msg)
             Reports a fatal error message.  The default version of this func-
             tion writes the message to the stream cerr and exits.

     Note that a yyFlexLexer object contains its entire scanning state.  Thus
     such objects can be used to create reentrant scanners.  Multiple in-
     stances of the same yyFlexLexer class can be instantiated, and multiple
     C++ scanner classes can be combined in the same program using the -P op-
     tion discussed above.

     Finally, note that the ``%array'' feature is not available to C++ scanner
     classes; ``%pointer'' must be used (the default).

     Here is an example of a simple C++ scanner:

           // An example of using the flex C++ scanner class.

           %{
           #include <errno.h>
           int mylineno = 0;
           %}

           string  \"[^\n"]+\"

           ws      [ \t]+

           alpha   [A-Za-z]
           dig     [0-9]
           name    ({alpha}|{dig}|\$)({alpha}|{dig}|[_.\-/$])*
           num1    [-+]?{dig}+\.?([eE][-+]?{dig}+)?
           num2    [-+]?{dig}*\.{dig}+([eE][-+]?{dig}+)?
           number  {num1}|{num2}

           %%

           {ws}    /* skip blanks and tabs */

           "/*" {
                   int c;

                   while ((c = yyinput()) != 0) {
                           if(c == '\n')
                               ++mylineno;
                           else if(c == '*') {
                               if ((c = yyinput()) == '/')
                                   break;
                               else
                                   unput(c);
                           }
                   }
           }

           {number}  cout << "number " << YYText() << '\n';

           \n        mylineno++;

           {name}    cout << "name " << YYText() << '\n';

           {string}  cout << "string " << YYText() << '\n';

           %%

           int main(int /* argc */, char** /* argv */)
           {
                   FlexLexer* lexer = new yyFlexLexer;
                   while(lexer->yylex() != 0)
                       ;
                   return 0;
           }

     To create multiple (different) lexer classes, use the -P flag (or the
     ``prefix='' option) to rename each yyFlexLexer to some other xxFlexLexer.
     <g++/FlexLexer.h> can then be included in other sources once per lexer
     class, first renaming yyFlexLexer as follows:

           #undef yyFlexLexer
           #define yyFlexLexer xxFlexLexer
           #include <g++/FlexLexer.h>

           #undef yyFlexLexer
           #define yyFlexLexer zzFlexLexer
           #include <g++/FlexLexer.h>

     If, for example, ``%option prefix="xx"'' is used for one scanner and
     ``%option prefix="zz"'' is used for the other.

     IMPORTANT: the present form of the scanning class is experimental and may
     change considerably between major releases.

INCOMPATIBILITIES WITH LEX AND POSIX
     flex is a rewrite of the AT&T UNIX lex tool (the two implementations do
     not share any code, though), with some extensions and incompatibilities,
     both of which are of concern to those who wish to write scanners accept-
     able to either implementation.  flex is fully compliant with the POSIX
     lex specification, except that when using ``%pointer'' (the default), a
     call to unput() destroys the contents of yytext, which is counter to the
     POSIX specification.

     In this section we discuss all of the known areas of incompatibility be-
     tween flex, AT&T lex, and the POSIX specification.

     flex's -l option turns on maximum compatibility with the original AT&T
     lex implementation, at the cost of a major loss in the generated scan-
     ner's performance.  We note below which incompatibilities can be overcome
     using the -l option.

     flex is fully compatible with lex with the following exceptions:

     -   The undocumented lex scanner internal variable yylineno is not sup-
         ported unless -l or ``%option yylineno'' is used.

         yylineno should be maintained on a per-buffer basis, rather than a
         per-scanner (single global variable) basis.

         yylineno is not part of the POSIX specification.

     -   The input() routine is not redefinable, though it may be called to
         read characters following whatever has been matched by a rule.  If
         input() encounters an end-of-file, the normal yywrap() processing is
         done.  A ``real'' end-of-file is returned by input() as EOF.

         Input is instead controlled by defining the YY_INPUT macro.

         The flex restriction that input() cannot be redefined is in accor-
         dance with the POSIX specification, which simply does not specify any
         way of controlling the scanner's input other than by making an ini-
         tial assignment to yyin.

     -   The unput() routine is not redefinable.  This restriction is in ac-
         cordance with POSIX.

     -   flex scanners are not as reentrant as lex scanners.  In particular,
         if a scanner is interactive and an interrupt handler long-jumps out
         of the scanner, and the scanner is subsequently called again, the
         following error message may be displayed:

               fatal flex scanner internal error--end of buffer missed

         To reenter the scanner, first use

               yyrestart(yyin);

         Note that this call will throw away any buffered input; usually this
         isn't a problem with an interactive scanner.

         Also note that flex C++ scanner classes are reentrant, so if using
         C++ is an option , they should be used instead.  See GENERATING C++
         SCANNERS above for details.

     -   output() is not supported.  Output from the ECHO macro is done to the
         file-pointer yyout (default stdout).

         output() is not part of the POSIX specification.

     -   lex does not support exclusive start conditions (%x), though they are
         in the POSIX specification.

     -   When definitions are expanded, flex encloses them in parentheses.
         With lex, the following:

               NAME    [A-Z][A-Z0-9]*
               %%
               foo{NAME}?      printf("Found it\n");
               %%

         will not match the string "foo" because when the macro is expanded
         the rule is equivalent to "foo[A-Z][A-Z0-9]*?" and the precedence is
         such that the `?' is associated with "[A-Z0-9]*".  With flex, the
         rule will be expanded to "foo([A-Z][A-Z0-9]*)?" and so the string
         "foo" will match.

         Note that if the definition begins with `^' or ends with `$' then it
         is not expanded with parentheses, to allow these operators to appear
         in definitions without losing their special meanings.  But the `<s>',
         `/', and <<EOF>> operators cannot be used in a flex definition.

         Using -l results in the lex behavior of no parentheses around the
         definition.

         The POSIX specification is that the definition be enclosed in paren-
         theses.

     -   Some implementations of lex allow a rule's action to begin on a sepa-
         rate line, if the rule's pattern has trailing whitespace:

               %%
               foo|bar<space here>
                 { foobar_action(); }

         flex does not support this feature.

     -   The lex `%r' (generate a Ratfor scanner) option is not supported.  It
         is not part of the POSIX specification.

     -   After a call to unput(), yytext is undefined until the next token is
         matched, unless the scanner was built using ``%array''.  This is not
         the case with lex or the POSIX specification.  The -l option does
         away with this incompatibility.

     -   The precedence of the `{}' (numeric range) operator is different.
         lex interprets "abc{1,3}" as match one, two, or three occurrences of
         `abc', whereas flex interprets it as match `ab' followed by one, two,
         or three occurrences of `c'.  The latter is in agreement with the
         POSIX specification.

     -   The precedence of the `^' operator is different.  lex interprets
         "^foo|bar" as match either `foo' at the beginning of a line, or `bar'
         anywhere, whereas flex interprets it as match either `foo' or `bar'
         if they come at the beginning of a line.  The latter is in agreement
         with the POSIX specification.

     -   The special table-size declarations such as `%a' supported by lex are
         not required by flex scanners; flex ignores them.

     -   The name FLEX_SCANNER is #define'd so scanners may be written for use
         with either flex or lex.  Scanners also include YY_FLEX_MAJOR_VERSION
         and YY_FLEX_MINOR_VERSION indicating which version of flex generated
         the scanner (for example, for the 2.5 release, these defines would be
         2 and 5, respectively).

     The following flex features are not included in lex or the POSIX specifi-
     cation:

           C++ scanners
           %option
           start condition scopes
           start condition stacks
           interactive/non-interactive scanners
           yy_scan_string() and friends
           yyterminate()
           yy_set_interactive()
           yy_set_bol()
           YY_AT_BOL()
           <<EOF>>
           <*>
           YY_DECL
           YY_START
           YY_USER_ACTION
           YY_USER_INIT
           #line directives
           %{}'s around actions
           multiple actions on a line

     plus almost all of the flex flags.  The last feature in the list refers
     to the fact that with flex Multiple actions ican be placed on the same
     line, separated with semi-colons, while with lex, the following

           foo handle_foo(); ++num_foos_seen;

     is (rather surprisingly) truncated to

           foo handle_foo();

     flex does not truncate the action.  Actions that are not enclosed in
     braces are simply terminated at the end of the line.

FILES
     flex.skl           Skeleton scanner.  This file is only used when build-
                        ing flex, not when flex executes.

     lex.backup         Backing-up information for the -b flag (called lex.bck
                        on some systems).

     lex.yy.c           Generated scanner (called lexyy.c on some systems).

     lex.yy.cc          Generated C++ scanner class, when using -+.

     <g++/FlexLexer.h>  Header file defining the C++ scanner base class,
                        FlexLexer, and its derived class, yyFlexLexer.

     /usr/lib/libl.*    flex libraries.  The /usr/lib/libfl.* libraries are
                        links to these.  Scanners must be linked using either
                        -ll or -lfl.

DIAGNOSTICS
     warning, rule cannot be matched  Indicates that the given rule cannot be
     matched because it follows other rules that will always match the same
     text as it.  For example, in the following ``foo'' cannot be matched be-
     cause it comes after an identifier "catch-all" rule:

           [a-z]+    got_identifier();
           foo       got_foo();

     Using REJECT in a scanner suppresses this warning.

     warning, -s option given but default rule can be matched  Means that it
     is possible (perhaps only in a particular start condition) that the de-
     fault rule (match any single character) is the only one that will match a
     particular input.  Since -s was given, presumably this is not intended.

     reject_used_but_not_detected undefined
     yymore_used_but_not_detected undefined  These errors can occur at compile
     time.  They indicate that the scanner uses REJECT or yymore() but that
     flex failed to notice the fact, meaning that flex scanned the first two
     sections looking for occurrences of these actions and failed to find any,
     but somehow they snuck in (via an #include file, for example).  Use
     ``%option reject'' or ``%option yymore'' to indicate to flex that these
     features are really needed.

     flex scanner jammed  A scanner compiled with -s has encountered an input
     string which wasn't matched by any of its rules.  This error can also oc-
     cur due to internal problems.

     token too large, exceeds YYLMAX  The scanner uses ``%array'' and one of
     its rules matched a string longer than the YYLMAX constant (8K bytes by
     default).  The value can be increased by #define'ing YYLMAX in the defi-
     nitions section of flex input.

     scanner requires -8 flag to use the character 'x'  The scanner specifica-
     tion includes recognizing the 8-bit character `x' and the -8 flag was not
     specified, and defaulted to 7-bit because the -Cf or -CF table compres-
     sion options were used.  See the discussion of the -7 flag for details.

     flex scanner push-back overflow  unput() was used to push back so much
     text that the scanner's buffer could not hold both the pushed-back text
     and the current token in yytext.  Ideally the scanner should dynamically
     resize the buffer in this case, but at present it does not.

     input buffer overflow, can't enlarge buffer because scanner uses
     REJECT  The scanner was working on matching an extremely large token and
     needed to expand the input buffer.  This doesn't work with scanners that
     use REJECT.

     fatal flex scanner internal error--end of buffer missed  This can occur
     in an scanner which is reentered after a long-jump has jumped out (or
     over) the scanner's activation frame.  Before reentering the scanner,
     use:

           yyrestart(yyin);

     or, as noted above, switch to using the C++ scanner class.

     too many start conditions in <> construct!  More start conditions than
     exist were listed in a <> construct (so at least one of them must have
     been listed twice).

SEE ALSO
     awk(1), lex(1), sed(1), yacc(1)

     "Lex - A Lexical Analyzer Generator", /usr/share/doc/psd/16.lex/.

     John Levine, Tony Mason, and Doug Brown, Lex & Yacc, O'Reilly and
     Associates, 2nd edition.

     Alfred Aho, Ravi Sethi, and Jeffrey Ullman, Compilers: Principles,
     Techniques and Tools, Addison-Wesley, 1986, Describes the pattern-
     matching techniques used by flex (deterministic finite automata).

STANDARDS
     The lex utility is compliant with the IEEE Std 1003.1-2008 (``POSIX'')
     specification, though its presence is optional.

     The flags [-78BbCcdFfhIiLloPpSsTVw+?], [--help], and [--version] are ex-
     tensions to that specification.

AUTHORS
     Vern Paxson, with the help of many ideas and much inspiration from Van
     Jacobson.  Original version by Jef Poskanzer.  The fast table representa-
     tion is a partial implementation of a design done by Van Jacobson.  The
     implementation was done by Kevin Gong and Vern Paxson.

     Thanks to the many flex beta-testers, feedbackers, and contributors, es-
     pecially Francois Pinard, Casey Leedom, Robert Abramovitz, Stan Adermann,
     Terry Allen, David Barker-Plummer, John Basrai, Neal Becker, Nelson H.F.
     Beebe, benson@odi.com, Karl Berry, Peter A. Bigot, Simon Blanchard, Keith
     Bostic, Frederic Brehm, Ian Brockbank, Kin Cho, Nick Christopher, Brian
     Clapper, J.T. Conklin, Jason Coughlin, Bill Cox, Nick Cropper, Dave Cur-
     tis, Scott David Daniels, Chris G. Demetriou, Theo de Raadt, Mike Don-
     ahue, Chuck Doucette, Tom Epperly, Leo Eskin, Chris Faylor, Chris Flat-
     ters, Jon Forrest, Jeffrey Friedl, Joe Gayda, Kaveh R. Ghazi, Wolfgang
     Glunz, Eric Goldman, Christopher M. Gould, Ulrich Grepel, Peer Griebel,
     Jan Hajic, Charles Hemphill, NORO Hideo, Jarkko Hietaniemi, Scott Hof-
     mann, Jeff Honig, Dana Hudes, Eric Hughes, John Interrante, Ceriel Ja-
     cobs, Michal Jaegermann, Sakari Jalovaara, Jeffrey R. Jones, Henry
     Juengst, Klaus Kaempf, Jonathan I. Kamens, Terrence O Kane, Amir Katz,
     ken@ken.hilco.com, Kevin B. Kenny, Steve Kirsch, Winfried Koenig, Marq
     Kole, Ronald Lamprecht, Greg Lee, Rohan Lenard, Craig Leres, John Levine,
     Steve Liddle, David Loffredo, Mike Long, Mohamed el Lozy, Brian Madsen,
     Malte, Joe Marshall, Bengt Martensson, Chris Metcalf, Luke Mewburn, Jim
     Meyering, R. Alexander Milowski, Erik Naggum, G.T. Nicol, Landon Noll,
     James Nordby, Marc Nozell, Richard Ohnemus, Karsten Pahnke, Sven Panne,
     Roland Pesch, Walter Pelissero, Gaumond Pierre, Esmond Pitt, Jef Poskanz-
     er, Joe Rahmeh, Jarmo Raiha, Frederic Raimbault, Pat Rankin, Rick
     Richardson, Kevin Rodgers, Kai Uwe Rommel, Jim Roskind, Alberto Santini,
     Andreas Scherer, Darrell Schiebel, Raf Schietekat, Doug Schmidt, Philippe
     Schnoebelen, Andreas Schwab, Larry Schwimmer, Alex Siegel, Eckehard
     Stolz, Jan-Erik Strvmquist, Mike Stump, Paul Stuart, Dave Tallman, Ian
     Lance Taylor, Chris Thewalt, Richard M. Timoney, Jodi Tsai, Paul Tuinen-
     ga, Gary Weik, Frank Whaley, Gerhard Wilhelms, Kent Williams, Ken Yap,
     Ron Zellar, Nathan Zelle, David Zuhn, and those whose names have slipped
     my marginal mail-archiving skills but whose contributions are appreciated
     all the same.

     Thanks to Keith Bostic, Jon Forrest, Noah Friedman, John Gilmore, Craig
     Leres, John Levine, Bob Mulcahy, G.T.  Nicol, Francois Pinard, Rich Salz,
     and Richard Stallman for help with various distribution headaches.

     Thanks to Esmond Pitt and Earle Horton for 8-bit character support; to
     Benson Margulies and Fred Burke for C++ support; to Kent Williams and Tom
     Epperly for C++ class support; to Ove Ewerlid for support of NUL's; and
     to Eric Hughes for support of multiple buffers.

     This work was primarily done when I was with the Real Time Systems Group
     at the Lawrence Berkeley Laboratory in Berkeley, CA.  Many thanks to all
     there for the support I received.

     Send comments to <vern@ee.lbl.gov>.

BUGS
     Some trailing context patterns cannot be properly matched and generate
     warning messages (dangerous trailing context).  These are patterns where
     the ending of the first part of the rule matches the beginning of the
     second part, such as "zx*/xy*", where the `x*' matches the `x' at the be-
     ginning of the trailing context.  (Note that the POSIX draft states that
     the text matched by such patterns is undefined.)

     For some trailing context rules, parts which are actually fixed-length
     are not recognized as such, leading to the above mentioned performance
     loss.  In particular, parts using `|' or `{n}' (such as "foo{3}") are al-
     ways considered variable-length.

     Combining trailing context with the special `|' action can result in
     fixed trailing context being turned into the more expensive variable
     trailing context.  For example, in the following:

           %%
           abc      |
           xyz/def

     Use of unput() invalidates yytext and yyleng, unless the ``%array'' di-
     rective or the -l option has been used.

     Pattern-matching of NUL's is substantially slower than matching other
     characters.

     Dynamic resizing of the input buffer is slow, as it entails rescanning
     all the text matched so far by the current (generally huge) token.

     Due to both buffering of input and read-ahead, it is not possible to in-
     termix calls to <stdio.h> routines, such as, for example, getchar(), with
     flex rules and expect it to work.  Call input() instead.

     The total table entries listed by the -v flag excludes the number of
     table entries needed to determine what rule has been matched.  The number
     of entries is equal to the number of DFA states if the scanner does not
     use REJECT, and somewhat greater than the number of states if it does.

     REJECT cannot be used with the -f or -F options.

     The flex internal algorithms need documentation.

OpenBSD 4.7                    October 22, 2009                             41
