##### prepare strings from data files ###########

message( STATUS "Prepare to extract strings from quanta data files..." )

## extra resources
unset( _resources_l10n )
file( GLOB_RECURSE _resources_files
      RELATIVE ${CMAKE_CURRENT_SOURCE_DIR}
      ${CMAKE_CURRENT_SOURCE_DIR}/data/toolbars/*.actions
      ${CMAKE_CURRENT_SOURCE_DIR}/data/toolbars/*.toolbar
      ${CMAKE_CURRENT_SOURCE_DIR}/*.kmdr
)
list( SORT _resources_files )
foreach( _resource_file ${_resources_files} )
    tde_l10n_prepare_xml( "${_resource_file}" )
    list( APPEND _resources_l10n "${_resource_file}.tde_l10n" )
endforeach( )

## chars
file( READ "${CMAKE_CURRENT_SOURCE_DIR}/data/chars" _chars_file )
string( REPLACE "\"" "\\\"" _chars_l10n "${_chars_file}" )
string( REGEX REPLACE
    "(^|\n)([^\n]+)"
    "\\1i18n(\"\\2\");"
    _chars_l10n "${_chars_l10n}"
)
file( WRITE "${CMAKE_CURRENT_SOURCE_DIR}/data/chars.tde_l10n" "${_chars_l10n}" )


##### create translation templates ##############

tde_l10n_create_template(
    CATALOG "quanta"
    SOURCES
        "."
        "../lib"
        ${_resources_l10n}
        "data/chars.tde_l10n"
        "data/tips"
    ATTRIBUTES
        "data/toolbars/*.actions:action,text"
        "data/toolbars/*.toolbar:action,text"
        "data/config/actions.rc:action,text"
        "*.tag:tag,comment"
)

tde_l10n_create_template(
    CATALOG "desktop_files/quanta-desktops/"
    SOURCES *.desktop
    DESTINATION "${CMAKE_SOURCE_DIR}/translations"
)
