#!/bin/csh -f

set nonomatch

set margs = ()
set iargs = ()
set template = (-TCCC)
set pkgroot = (/proj/m3/pkg)

while ($#argv > 0)
  switch ("$1")
    case -f:
      shift
      set m = "$1";
      shift
      breaksw
    case -D*:
    case -U*:
      set iargs = ($iargs:q "$1")
      shift
      breaksw
    case -T*:
      shift
      set template = (-T"$1")
      shift
      breaksw
    case -R*:
      shift
      set pkgroot = "$1"
      shift
      breaksw
    default:
      set margs = ($margs:q "$1")
      shift
      breaksw
    endsw
  end

if ($?m) then
  set iargs = (-DFROM_DIR=`dirname $m` $iargs:q)
else
  if (-r ./m3makefile) then
    set m = m3makefile
    set iargs = (-DFROM_DIR=. $iargs:q)
  else
    if (-r ../src/m3makefile) then
      set m = ../src/m3makefile
      set iargs = (-DFROM_DIR=../src $iargs:q)
    else
      echo "There is no BBB, *.BBB, BBB.* subdirectory, and"
      echo "no m3makefile in the current directory;"
      if (-r src/m3makefile) then
        echo "There is a src/m3makefile; you probably want to mkdir BBB."
      else
        echo "There is no src/m3makefile; I don't know what to suggest."
      endif
      exit 1
    endif
  endif 
endif

sed -f AAA/prepass.sed $m > .makefile.0
rm -f .EXPORT*
AAA/imake -IAAA -I$pkgroot -DPKGROOT=$pkgroot -I. $template -f .makefile.0 -s.makefile.1 $iargs:q
awk -f AAA/mklist.awk .makefile.1 > .makefile
rm -f .makefile.0 .makefile.1
exec DDD -f .makefile PACKAGE=$cwd:t M3MAKEFILE=$m $margs:q
