10  REM     RADIOACTIVE DECAY SIMULATION, REVISED 1/9/73 BY
20  REM     RON HIPSCHMAN, EXPORATORIUM, PALACE OF FINE ARTS
30  REM
40  DIM A$[72],B$[72]
50  REM
60  PRINT "ENTER YOUR FIRST AND LAST NAME PLEASE";
70  INPUT A$
71  IF TIM(1)>11 THEN 74
72  PRINT "GOOD MORNING, ";
73  GOTO 80
74  IF TIM(1)>15 THEN 77
75  PRINT "GOOD AFTERNOON, ";
76  GOTO 80
77  PRINT "GOOD EVENING, ";
80  PRINT "RULES??";
90  IF B$[1,1]="N" THEN 330
100  PRINT 
110  PRINT "               ---THE NEW CLEA CASINO---"
120  PRINT 
130  PRINT "  MR. A. TOM MICK, GENERAL MANAGER OF THE NEW CLEA CASINO,"
140  PRINT "HAS, AT TIME  T-0,  DISCOVERED  100,000 RADIOACTIVE PLAYING"
150  PRINT "CHIPS AT HIS TABLE.  THEIR HALF-LIFE IS 10 MINUTES.  EACH CHIP"
160  PRINT "TRANSMUTES SPONTANEOUSLY AND COMPLETELY IN A RANDOM FASHION."
170  PRINT 
180  PRINT "    AT VARIOUS TIMES T, AFTER T-0, YOU MUST DETERMINE WITH",
190  PRINT "A CERTAIN PERCENTAGE, HOW MANY CHIPS ARE LEFT."
200  PRINT 
210  PRINT "    TO FURTHER THE INTEREST OF THE GAME, YOU WILL START WITH"
220  PRINT "$1,000 AND THE HOUSEWITH AN UNSPECIFIED AMOUNT.  HALF THE"
230  PRINT " MONEY YOU HAVE WILL RIDE ON EACH GUESS YOU TAKE.  LET'S SEE"
240  PRINT " IF YOU CAN BREAK THE HOUSE BEFORE THE CHIPS RUN OUT."
250  PRINT 
260  PRINT "THE HOUSE OFFERS THE FOLLOWING ODDS:"
270  PRINT "    2) 2 TO 1 ODDS FOR GUESSING WITHIN 20 PERCENT"
280  PRINT "    4) 4 TO 1 ODDS FOR GUESSING WITHIN 10 PERCENT"
290  PRINT "    8) 8 TO 1 ODDS FOR GUESSING WITHIN  5 PERCENT."
300  PRINT 
310  PRINT " ENTER THE NUMBER 2, 4, OR 8 FOR THE ODDS YOU WANT AFTER THE"
320  PRINT "QUESTION MARK IN THE COLUMN LABELLED ODDS."
330  PRINT 
340  PRINT "YOUR $","HOUSE $","TIME  (MIN)","ODDS"
350  A=0
360  B=0
370  T=0
380  Y=1000
390  G=100000.
400  D=0
410  C=0
420  PRINT 
430  IF ABS(G-D)<1500 THEN 460
440  G=5
450  D=2
460  B=B+1
470  FOR I=1 TO 3+A+ABS(G-D)
480  T3=INT(100*RND(-Y))/10
490  NEXT I
500  T=T+T3
510  D=INT(100000.*EXP(-.0693*T))
520  IF D=0 THEN 870
530  PRINT Y,1.001E+06-Y,T,
540  INPUT A
550  IF A=2 THEN 620
560  IF A=4 THEN 620
570  IF A=8 THEN 620
580  PRINT "SORRY PAL, WE DON'T OFFER THOSE ODDS."
590  IF C=1 THEN 830
600  C=1
610  GOTO 540
620  PRINT "HOW MANY CHIPS LEFT ";
630  INPUT G
640  PRINT "ACTUAL NUMBER LEFT IS ";D
650  IF A=2 THEN 710
660  IF A=4 THEN 690
670  P=.05
680  GOTO 720
690  P=.1
700  GOTO 720
710  P=.2
720  T=10*B
730  IF ABS(D-G) <= P*D THEN 780
740  Y=INT(Y-Y/2)
750  IF Y <= 50 THEN 830
760  PRINT "TOO BAD, YOU LOST. TRY AGAIN."
770  GOTO 410
780  Y=INT(Y+A*Y/2)
790  IF 1.E+06-Y<1 THEN 900
800  IF Y>200000. THEN 850
810  PRINT "YOU WON. TRY AGAIN."
820  GOTO 410
830  PRINT "IT SEEMS THAT YOU JUST CAN'T GET THE HANG OF IT. SAVE YOUR BREAD."
840  GOTO 980
850  PRINT "YOU CAN BREAK THE HOUSE IF YOU TRY A LONG SHOT."
860  GOTO 410
870  PRINT "OOOOPS... SORRY PAL, THE LAST CHIP JUST DISINTEGRATED."
880  PRINT "THE HOUSE IS CLOSED."
890  GOTO 980
900  PRINT "YOU BROKE THE HOUSE. YOU NEEDED ONLY ";
910  Y=1.001E+06
920  IF B>5 THEN 950
930  PRINT "THE MINIMUM NUMBER OF GUESSES."
940  GOTO 960
950  PRINT B;"GUESSES."
960  PRINT "CONGRADULATIONS."
970  PRINT "YOU MUST KNOW A LOT ABOUT RADIOACTIVITY AND THINGS."
980  PRINT "THANKS FOR PLAYING."
990  PRINT 
1000  PRINT "--------------------------------------------------------------"
1010  PRINT 
1020  PRINT "                                     CHECK NO.";B+D
1030  PRINT 
1040  PRINT "                                DATE: ";
1050  PRINT "-------------19--"
1060  PRINT 
1070  PRINT 
1080  PRINT " PAY TO THE ORDER OF "A$;
1090  PRINT " $";Y
1100  PRINT 
1110  PRINT 
1120  PRINT "THE NEW CLEA CASINO                      A. TOM MICK"
1130  PRINT "                                         GENERAL MANAGER"
1140  PRINT 
1150  PRINT "--------------------------------------------------------------"
1160  PRINT 
1170  PRINT "DON'T SPEND IT ALL IN ONE PLACE."
1180  END 
