10  REM  LEVEL2:  MATH DRILL AND PRACTICE FOR SATURDAY CLASSES;
20  REM  PROGRAMMED BY WILLIAM K. CHAR, OCTOBER 18, 1975.
30  REM
40  DIM A[3],A$[4],B$[10]
50  REM
60  DEF FNR()=INT(*RND(1))+1
70  A$="+-*/"
80  PRINT "LEVEL TWO MATH DRILL"
90  FOR J=1 TO 999999.
100  R=W=0
110  PRINT 
120  PRINT "HOW MANY MINUTES DO YOU WANT TO WORK (1, 3, OR 5)";
130  INPUT T
140  IF T=1 OR T=3 OR T=5 THEN 200
150  PRINT 
160  PRINT "// "'7"ERROR:  YOU ARE MAKING ONE OF THE MOST UNACCEPTABLE"
170  PRINT "   MISTAKES IN DATA PROCESSING--YOU ARE NOT READING"
180  PRINT "   THE INSTRUCTIONS.  TRY ANSWERING CORRECTLY AGAIN."
190  GOTO 110
200  T=T*60
210  FOR I=1 TO 999999.
220  A[1]=FNR(100)
230  A[2]=FNR(10)
240  K=FNR(4)
250  GOTO K OF 260,260,280,280
260  A[3]=A[1]+A[2]
270  GOTO 320
280  A[3]=A[1]*A[2]
290  IF A[3]>144 THEN 220
300  REM  ===== PRINT PROBLEM =====
310  IMAGE #,5DX,A,3D," = "
320  B$=A$[K,K]
330  GOTO K OF 340,360,340,360
340  PRINT  USING 310;A[1],B$,A[2]
350  GOTO 370
360  PRINT  USING 310;A[3],B$,A[2]
370  T1=8
380  IF K<4 THEN 400
390  T1=16
400  ENTER T1,T2,B
410  IF T2<-255 THEN 580
420  IF T2<0 THEN 540
430  GOTO K OF 440,460,440,460
440  IF B=A[3] THEN 490
450  GOTO 540
460  IF B=A[1] THEN 490
470  GOTO 540
480  REM  (CORRECT)
490  PRINT "C"
500  R=R+1
510  T=T-T2
520  GOTO 610
530  REM  (NO ANSWER)
540  PRINT "X"
550  T=T+T2
560  GOTO 600
570  REM  (TIME OUT)
580  PRINT "*"
590  T=T-T1
600  W=W+1
610  IF T<0 THEN 630
620  NEXT I
630  PRINT 
640  PRINT "ATTEMPTS"R+W
650  PRINT "RIGHT"R
660  PRINT "WRONG"W
670  PRINT 
680  PRINT "WANT TO TRY AGAIN (Y/N)";
690  INPUT B$
700  IF B$[1,1]="N" THEN 720
710  NEXT J
720  PRINT 
730  PRINT "HAVE A NICE DAY."
740  END 
