10  REM ** THIS PRAGRAM DUPLICATES THE MCP TAPE EXCEPT FOR FILE 15 **
20  REM ** FILE 5 IS THE CONFIGURED VERSION OF THE IOP **
30  REM ** THIS PROGRAM MODIFIED 011/77 BY GARY PAULSON; NEELY-S.C.(HP) **
40  FILES *,*
50  DIM A$[255],G$[6],H$[6]
60  G$="MCPFIL"
70  H$="MT"
80  PRINT "MOUNT MASTER MCP TAPE. PRESS RETURN";
90  LINPUT A$
100  ASSIGN H$,1,I
110  IF I=0 THEN 140
120  PRINT "ERROR IN LINE 50; RETURN VARIABLE = ";I
130  STOP 
140  CREATE J,G$,1000
150  IF J=0 THEN 210
160  IF J=1 THEN 180
170  STOP 
180  PRINT "FILE IN EXISTANCE; A NEW DISC FILE NAME IS -- ";
190  LINPUT G$
200  GOTO 140
210  ASSIGN G$,2,J
220  IF J=0 THEN 250
230  PRINT "ERROR IN LINE 70, RETURN VARIABLE IS ";J
240  STOP 
250  IF  END #1 THEN 370
260  IF  END #2 THEN 350
270  LINPUT #1;A$
280  IF A$[5,6]#'253'232 THEN 330
290  PRINT #2;'2'0'4'1'253'232'128'0'129'233, END 
300  PRINT #2,REC(2)+1; END 
310  GOTO 410
320  LINPUT #1;A$
330  PRINT #2;A$
340  GOTO 320
350  PRINT "THE FILE '";G$;"' IS TO SHORT. MAKE IT LONGER AND RERUN PROGRAM"
360  STOP 
370  PRINT #2; END 
380  PRINT #1;CTL(21)
390  READ #2,REC(2)+1
400  GOTO 270
410  ASSIGN *,1
420  PRINT LIN(1);"WANT TO MAKE A COPY";
430  INPUT A$
440  A$=UOS$(A$[1,1])
450  IF A$="Y" THEN 490
460  IF A$#"N" THEN 420
470  PURGE J,G$
471  IF J=0 THEN 480
472  PRINT "CAN NOT PURGE ";G$
480  STOP 
490  PRINT "MOUNT A SCRATCH TAPE. PRESS RETURN";
500  LINPUT A$
510  ASSIGN H$,1,I
520  IF  END #2 THEN 580
530  IF  END #1 THEN 680
540  READ #2,1
550  READ #2;A$
560  PRINT #1;A$
570  GOTO 550
580  PRINT #1;CTL(21)
590  READ #2,REC(2)+1
600  IF TYP(2)=2 THEN 550
610  PRINT #1;CTL(24)
620  PRINT "DO YOU WANT ANOTHER COPY";
630  INPUT A$
640  A$=UOS$(A$[1,1])
650  IF A$="Y" THEN 490
660  IF A$#"N" THEN 620
665  ASSIGN *,2
670  GOTO 470
680  PRINT "TAPE IS TOO SHORT. CAN'T WRITE MCP ON IT"
690  GOTO 490
700  END 
