10  REM *** PROGRAM TO READ CARDS AND STORE IN ASCII FILE ***
20  REM *** PROGRAM WILL CREATE A FILE AS REQUIRED ***
50  DIM A$[80],F$[6]
60  FILES *
70  PRINT "HOW MANY CARDS TO BE READ";
80  INPUT N1
120  REM***CREATE FILE***
130  PRINT "FILE NAME FOR CARDS";
150  INPUT F$
170  CREATE N3,F$,N1
180  IF N3 <> 0 THEN 9000
190  ASSIGN F$,1,N3
195  IF  END #1 THEN 9500
8410  FOR R=1 TO N1
8499  REM***GRAB A CARD***
8500  PRINT '10'25;
8510  SYSTEM X,"ECH-OFF"
8520  LINPUT A$
8530  SYSTEM X,"ECH-ON"
8540  IF A$='9 THEN 8700
8550  IF A$='7 THEN 8800
8560  IF A$='31 THEN 8900
8565  IF A$='18 THEN 8500
8570  PRINT #1,R;A$
8580  NEXT R
8699  REM***ERROR HANDLING ROUTINE FOR PICK FAIL***
8700  PRINT '10'9'17
8710  PRINT '7'7"PICK FAIL"'7'7
8720  PRINT "RELOAD CARDS THEN PRESS READY"
8730  GOTO 8510
8799  REM***ERROR HANDLING ROUTINE FOR HOPPERS EMPTY OR FULL**
8800  PRINT '10'9'17
8810  PRINT "HOPPERS EMPTY OR FULL"
8820  PRINT "MORE CARDS";
8830  INPUT A$
8840  IF A$[1,1]="Y" THEN 8870
8850  GOTO 9100
8860  RETURN 
8870  PRINT "ADD MORE CARDS THEN PRESS READY"
8880  GOTO 8510
8899  REM***ERROR HANDLING ROUTINE FOR NOT READY***
8900  PRINT "CARD READER IS NOT READY. PRESS READY"
8910  GOTO 8510
8999  REM***END ROUTINE FOR FILE NOT CREATED***
9000  GOTO N3 OF 9010,9030,9050,9070
9010  PRINT F$;" IS ALREADY PRESENT."
9020  PRINT F$;" IS AN ILLEGAL NAME"
9030  PRINT "PROGRAM HAS BEEN CLOBBERED, CALL COMPUTER CENTER"
9040  STOP 
9050  PRINT "THERE IS NOT ENOUGH EMPTY FILESPACE IN YOUR ACCOUNT."
9060  STOP 
9070  PRINT "THERE IS NOT ENOUGH EMPTY FILESPACE IN THE SYSTEM,"
9071  PRINT "OR AT LEAST NOT IN ONE SPACE."
9072  STOP 
9099  REM***END ROUTINE FOR END OF CARDS***
9100  PRINT '10'9'17
9110  PRINT "NORMAL END--";R;"CARDS READ"
9115  PRINT "FILE NAME IS ";F$
9120  END 
9499  REM***END ROUTINE FOR END OF FILE***
9500  PRINT '10'9'17
9505  PRINT "FILE NAME IS ";F$
9510  PRINT "E O F --";R;"CARDS READ"
9520  END 
