10  REM ** SYSFUN * SYSTEM FUNCTION CONTROLLER * HP-2000 ACCESS **
20  REM ** P.VIXIE * 342/77 * EDP RESOURCE CENTER,S.F.,CA.,94134 *
30  DIM C$[10],E$[6],F$[31],N$[72],S$[6],X$[72]
40  F$="   SWA-MWA-UNR-PRO-PRI-LOC-CAT-"
50  C$="CAT-"
60  S$=S$[2,1]
70  E$=E$[2,1]
80  A0=F=X=Y=0
90  PRINT '10"FUNCTION [1-8, 9 FOR LIST] ";
100  INPUT F
110  IF F=8 THEN 680
120  IF F>0 AND F<8 AND F=INT(F) THEN 200
130  PRINT 
140  PRINT " [1]  SWA-   [5]  PRI-"
150  PRINT " [2]  MWA-   [6]  LOC-"
160  PRINT " [3]  UNR-   [7]  CAT-"
170  PRINT " [4]  PRO-   [8]  EXIT"
180  PRINT 
190  GOTO 90
200  F$=F$[F*4,F*4+3]
210  PRINT '10"FIRST ENTRY ? ";
220  LINPUT S$
230  IF LEN(S$) THEN 250
240  S$="0"
250  PRINT '10"LAST ENTRY ? ";
260  LINPUT E$
270  IF LEN(E$) THEN 290
280  E$="ZZZZZZ"
290  IF E$ >= S$ THEN 320
300  PRINT "NON-SEQUENTIAL ITEMS"'10
310  GOTO 210
320  C$[5,10]=S$
330  IF F=7 THEN 520
340  SYSTEM N$,C$
350  IF F>2 THEN 390
360  X=NUM(N$[8,8])
370  Y=NUM(N$[9,9])
380  IF X#70 AND X#77 AND Y#70 AND Y#77 THEN 460
390  F$[5,10]=N$[1,6]
400  IF N$[1,6]>E$[1,6] THEN 500
410  SYSTEM A0,F$
420  IF  NOT A0 THEN 450
430  PRINT '13'10"UNABLE TO "F$
440  STOP 
450  PRINT F$,
460  IF N$[1,6]=E$ THEN 500
470  IF N$[25,30]="      " THEN 500
480  C$[5,10]=N$[25,30]
490  GOTO 340
500  PRINT '13'10
510  GOTO 40
520  PRINT 
530  PRINT " NAME    LENGTH RECORD   NAME    LENGTH RECORD   NAME    LENGTH RECORD"
540  FOR A0=1 TO 3
550  SYSTEM N$,C$
560  IF N$[1,6]>E$[1,6] THEN 650
570  X$[LEN(X$)+1]=N$[1,24]
580  IF N$[1,6]=E$ THEN 650
590  IF N$[25,30]="      " THEN 650
600  C$[5,10]=N$[25,30]
610  NEXT A0
620  PRINT X$[1,LEN(X$)-1]
630  X$=X$[2,1]
640  GOTO 540
650  PRINT X$
660  X$=X$[2,1]
670  GOTO 40
680  END 
