10  FILES *,*
20  DIM A$[72],T$[72],B$[72]
30  CREATE R9,"0TEMP",1
32  IF R9=0 THEN 40
33  PRINT "UNABLE TO CREATE '0TEMP' FILE. CODE:"R9
34  STOP 
40  ASSIGN "0TEMP",2,R9
50  PRINT "DIRECTORY FILE: ";
60  LINPUT T$
70  ASSIGN T$,1,R9
80  IF R9>2 THEN 50
90  IF  END #1 THEN 410
100  PRINT 
110  PRINT "SEARCH FOR DISC ADDRESS: ";
120  LINPUT T$
130  IF T$="" THEN 190
135  L2=LEN(T$)
140  IF L2 <= 6 THEN 165
150  PRINT " <?> DISC ADDRESS MUST BE 6 NUMBERS"
160  GOTO 100
165  A$="000000"
166  A$[7-L2 MAX 1,6]=T$
167  T$=A$
170  PRINT #2;T$
180  GOTO 110
190  READ #2,1
200  PRINT LIN(1)
210  PRINT "WE ARE SEARCHING FOR THE FOLLOWING DISC ADDRESSES:"LIN(1)
220  FOR J=1 TO 100
230  IF TYP(2)=3 THEN 270
240  READ #2;A$
250  PRINT TAB(4);A$
260  NEXT J
270  PRINT LIN(1)
280  FOR J=1 TO 999999.
290  LINPUT #1;T$
300  IF T$[1,4]="    " THEN 320
310  B$[1,4]=T$[1,4]
320  READ #2,1
330  FOR K=1 TO 100
340  IF TYP(2)=3 THEN 390
350  READ #2;A$
360  IF A$[1,6]#T$[49,54] THEN 380
370  PRINT "DISC ADDR: "A$"   FOUND IN ACC'T: "B$"    PROGRAM: "T$[10,15]
380  NEXT K
390  NEXT J
400  END 
410  PURGE R9,"0TEMP"
420  END 
