10  FILES *,*
20  DIM A$[255],B$[255],C$[255],D$[255],Z$[255]
30  PRINT "** I/O PROCESSOR MEMORY MAP **"LIN(2)
40  PRINT 
50  PRINT "  1) PRINT OUT I/O MAP FROM 'I/O' TAPE"
60  PRINT "  2) COPY I/O MAP INTO AN 'ASCII' FILE AND LIST."
70  PRINT "  3) PRINT FORMATED I/O P MAP FROM FILE IN OPTION 2."
80  PRINT "OPTION ";
90  LINPUT C$
100  CONVERT C$ TO O,121
110  GOTO O OF 390,490,590
120  GOTO 40
121  IF C$[1,1]="S" THEN 124
123  GOTO 40
124  STOP 
125  REM *********************************************
390  GOSUB 970
400  IF  END #1 THEN 480
410  LINPUT #1;A$
420  IF A$[1,2]='10'10 THEN 460
430  PRINT #1;CTL(21)
440  GOTO 410
450  LINPUT #1;A$
460  PRINT A$;
470  GOTO 450
480  GOTO 40
485  REM *******************************************
490  GOSUB 970
495  GOSUB 980
500  IF  END #1 THEN 580
510  LINPUT #1;A$
520  IF A$[1,2]='10'10 THEN 555
530  PRINT #1;CTL(21)
540  GOTO 510
550  LINPUT #1;A$
555  PRINT #2;A$
560  PRINT A$
570  GOTO 550
580  GOTO 40
585  REM *********************************************
590  GOSUB 980
600  C=1
610  P=0
620  PRINT LIN(1)"REVISION NUMBER:  ";
630  LINPUT C$
631  PRINT "                              APPROX: 43"
632  PRINT "END NUMBER OF I/OP MAP LINES, PAGE 1 ";
634  INPUT C1
640  IF  END #2 THEN 950
650  PRINT "ADJUST PAPER, HIT 'RETURN'"LIN(2)
660  ENTER 240,R,A$
670  REM +*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+
680  LINPUT #2;A$
690  IF A$[1,2]='10'10 THEN 800
700  PRINT #1;CTL(21)
710  GOTO 680
720  GOTO 760
730  PRINT '12
740  GOSUB 840
750  PRINT 
755  PRINT A$;
757  C=C+1
760  LINPUT #2;A$
765  IF POS(A$,"ENTRY POINT") THEN 730
770  C=C+1
780  PRINT A$;
790  GOTO 720
800  P0=POS(A$,"=")
810  D$=A$[P0+1]
820  GOSUB 840
830  GOTO 720
840  P=P+1
850  CONVERT P TO B$
860  Z$="***************************************************************"
865  PRINT LIN(1)
870  PRINT Z$
888  PRINT "  HP 2000 System   I/O Processor Memory Map   Date: "D$[1,8]
890  PRINT 
900  PRINT "  UNIVERSITY of SAN FRANCISCO,   COLLEGE OF BUSINESS"
910  PRINT "   McLAREN CENTER, Mc 103,  SAN FRANCISCO, CA. 94117"
920  PRINT Z$;LIN(1)"  REVISION: "C$;TAB(25)"                   ";
930  PRINT TAB(53)"P."B$" of 2";
935  PRINT 
940  RETURN 
950  PRINT '12
960  GOTO 40
965  REM ****************************************************
970  PRINT LIN(1)"MAGTAPE FILE: ";
972  LINPUT C$
973  IF C$="" THEN 1000
974  ASSIGN C$,1,R9
976  IF R9=0 THEN 990
977  PRINT " <?> FILE NOT ACCESSIBLE OR NOT AVAILABLE"
978  GOTO 970
980  PRINT LIN(1)"ASCII FILE FOR I/O P MAP: ";
982  LINPUT C$
983  IF C$="" THEN 1000
984  ASSIGN C$,2,R9
986  IF R9=0 THEN 990
987  PRINT LIN(1)" <?> FILE NOT ACCESSIBLE OR NOT AVAILABLE"
988  GOTO 980
990  RETURN 
1000  END 
