9000  REM ***** PROGRAM TO ENTER STRINGS INTO FILE(S) *****
9001  REM ***** VERSION 1 *******
9002  REM ***** MAY 10, 1971     R. TAYLOR *****
9003  DIM A$[72]
9004  PRINT "HAVE YOU ENTERED THE FILES STATEMENT ('YES' OR 'NO')";
9005  INPUT A$
9006  IF A$="YES" THEN 9013
9007  IF A$="NO" THEN 9010
9008  PRINT "PLEASE TYPE 'YES' OR 'NO'";
9009  GOTO 9005
9010  PRINT "THIS PROGRAM REQUIRES THE ENTERING OF A FILES STATEMENT BEFORE"
9011  PRINT "RUNNING. PLEASE CONSULT PROGRAM DOCUMENTATION."
9012  GOTO 9048
9013  PRINT "ARE YOU CERTAIN THE FILES ARE IN THE ORDER YOU DESIRE AND"
9014  PRINT "THAT THEY ARE OF SUFFICIENT LENGTH TO ACCOMODATE ALL YOUR DATA"
9015  INPUT A$
9016  IF A$="YES" THEN 9023
9017  IF A$="NO" THEN 9020
9018  PRINT "PLEASE TYPE 'YES' OF 'NO'";
9019  GOTO 9015
9020  PRINT "PLEASE MAKE CERTAIN AND THEN RESTART THIS PROGRAM."
9021  PRINT ""
9022  GOTO 9048
9023  PRINT "HOW MANY FILES HAVE YOU DECLARED";
9024  INPUT N
9025  IF N <= 16 THEN 9030
9026  PRINT "A BASIC PROGRAM MAY ACCESS ONLY 16 FILES AT ONE TIME, PERHAPS"
9027  PRINT "YOU ARE CONFUSING THE NUMBER OF FILES WITH THE NUMBER OF RECORDS."
9028  PRINT "PLEASE CHECK PROGRAM DOCUMENTATION BEFORE CONTINUING."
9029  GOTO 9023
9030  PRINT 
9031  PRINT "MOUNT PAPER TAPE AND MOVER TAPE READER CONTROL TO 'START'."
9032  FOR J1=1 TO N
9033  READ #J1,1
9034  NEXT J1
9035  R=1
9036  INPUT A$
9037  IF  END #R THEN 9039
9038  GOTO 9044
9039  R=R+1
9040  IF R <= N THEN 9037
9041  PRINT "YOUR DATA REQUIRES MORE FILE SPACE THAN YOU HAVE ALLOTTED."
9042  PRINT "PLEASE CONSULT PROGRAM DOCUMENTATION BEFORE STARTING AGAIN."
9043  GOTO 9048
9044  PRINT #R;A$
9045  IF A$[1,3]="EQT" THEN 9047
9046  GOTO 9036
9047  PRINT "DATA STORED IN FILE."
9048  END 
