1000  COM T$[30],B,B$[42],M,P[6],C[3],D$[9],N,T[7,141]
1001  COM C$[6],O$[6],K,W[6],F,N$[9]
1500  REM
1510  REM      GPAC-COMMAND
1515  REM
1520  PRINT '10"COMMAND ";
1540  INPUT C$[1,6]
1550  PRINT 
1600  IF C$[1,3]="CHE" THEN 1750
1610  IF C$[1,3]="HEL" THEN 8030
1620  IF C$[1,3]="HIS" THEN 1790
1630  IF C$[1,3]="LIS" THEN 1810
1640  IF C$[1,3]="MOD" THEN 1830
1650  IF C$[1,3]="OUT" THEN 1850
1660  IF C$[1,3]="SOR" THEN 1870
1670  IF C$[1,3]="STA" THEN 1890
1680  IF C$[1,3]="STO" THEN 1910
1690  IF C$[1,3]="UPD" THEN 1930
1700  PRINT "ILLEGAL COMMAND:  ";C$
1720  GOTO 1520
1750  CHAIN "$GPACS"
1790  PRINT " ","HISTOGRAM SECTION"
1800  CHAIN "$GPACH"
1810  CHAIN "$GPACL"
1830  PRINT " ","MODIFICATION SECTION"
1840  CHAIN "$GPACM"
1850  CHAIN "$GPACO"
1870  PRINT " ","SORT SECTION"
1880  CHAIN "$GPACT"
1890  PRINT " ","STAT SORT SECTION"
1900  CHAIN "$GPACZ"
1910  PRINT " ","GPAC EXIT"
1920  STOP 
1930  CHAIN "$GPACU"
8000  REM
8030  PRINT " ","GPAC CONTROL COMMANDS"
8040  PRINT 
8050  PRINT "CHECK:   PRINT OUT CLASS PARAMETERS AND OTHER CLASS";
8060  PRINT " INFORMATION."
8070  PRINT "HELP:    OBTAIN A LISTING OF ALL COMMANDS."
8080  PRINT "HISTO:   MAKE A TTY HISTOGRAM OF ANY USEABLE BIN ";
8085  PRINT "OR THE SCORE."
8090  PRINT "LIST:    LIST THE STUDENT'S RAW TOTAL BY S.N."
8100  PRINT "MODIFY:  CHANGE THE USEABLE BINS AND OTHER CLASS ";
8110  PRINT "PARAMETERS."
8120  PRINT "OUT:     OBTAIN A SHORT INDIVIDUAL SUMMARY GIVING ";
8130  PRINT "THE RAW TOTALS"
8140  PRINT "         AND THE TOTAL POSSIBLE FOR EACH STUDENT."
8150  PRINT "SORT:    SORT AND LIST IN DECREASING ORDER ALL RAW ";
8160  PRINT "TOTALS AND"
8170  PRINT "         THE SCORE,  THE KEY FOR THE SORT MAY BE ANY ";
8180  PRINT "USEABLE BIN."
8190  PRINT "STAT:    COMPUTES THE Z-SCORE AND SORTS FOR ANY USEABLE";
8195  PRINT " BIN OR THE"
8197  PRINT "         SCORE."
8210  PRINT "STOP:    PERFORMS A NORMAL EXIT FROM GPAC."
8220  PRINT "UPDATE:  ALLOWS ENTERING OF NEW DATA INTO THE ARRAYS."
8480  PRINT 
8490  GOTO 1520
9999  END 
