1  REM ****  HP BASIC PROGRAM LIBRARY  ******************************
2  REM
3  REM       GSPMG: STANFORD PORTFOLIO MANAGEMENT GAME
4  REM       GQUOTE, PART 2 OF 7 (OBTAINS QUOTATION FROM SECURITY
5  REM                            PRICES ON FILE SPRDIV)
6  REM       36502 REV A
7  REM ****  CONTRIBUTED PROGRAM  ***********************************
50  FILES *SPRDIV
100  DIM X$[27],A$[10],T[500],P[500]
110  X$="ABCDEFGHIJKLMNOPQRSTUVWXYZ "
140  READ #1;T3,T2,T1,T0
150  READ #1;N
160  FOR I=1 TO N
165  READ #1;T[I],P[I],X,X
170  NEXT I
200  PRINT "WHEN ASKED, TYPE TICKER SYMBOL, 'ALL' OR 'DONE'."
300  PRINT "SYMBOL";
310  INPUT A$
320  IF A$="DONE" THEN 900
321  IF A$="ALL" THEN 700
330  GOSUB 500
350  FOR I=1 TO N
355  IF T[I]=A9 THEN 370
360  NEXT I
365  PRINT "TICKER SYMBOL NOT ON ELIGIBLE LIST"
366  PRINT 
367  GOTO 300
370  PRINT  USING 371;P[I]
371  IMAGE "PRICE: ",8D.3D
380  PRINT 
382  GOTO 300
500  REM ------------------------
501  REM -- CONVERT SYMBOL IN A$ TO NUMBER IN A9
510  A$[LEN(A$)+1]="    "
512  A$=A$[1,4]
520  A9=0
530  FOR K=1 TO 4
540  FOR L=1 TO 27
542  IF A$[K,K]=X$[L,L] THEN 550
544  NEXT L
546  L=27
550  A9=(A9*30)+L
560  NEXT K
570  RETURN 
600  REM ------------------------
601  REM -- CONVERT SYMBOL IN A9 TO A$
610  A1=INT(A9/(30^3))
612  A8=A9-(30^3)*A1
614  A2=INT(A8/(30^2))
616  A8=A8-A2*(30^2)
618  A3=INT(A8/30)
620  A4=A8-A3*30
625  A$="    "
630  A$[1,1]=X$[A1,A1]
632  A$[2,2]=X$[A2,A2]
634  A$[3,3]=X$[A3,A3]
636  A$[4,4]=X$[A4,A4]
650  RETURN 
700  PRINT 
705  FOR I=1 TO N
710  A9=T[I]
715  GOSUB 600
720  PRINT  USING 721;A$,P[I]
721  IMAGE 4A,9D.3D
730  NEXT I
750  STOP 
900  END 
