10  COM I,Z1,B[10],I$[10],I2
20  REM PROGRAM NAME = ACF-5, OF CIRMO, THE QUESTIONING
30  REM JEFFERSON COUNTY WRITING TEAM, LAKEWOOD, COLORADO
40  REM 9 AUGUST 1973
50  GOTO 70
60  CHAIN "$ACF-2"
70  DIM F$[72]
80  F$="--------------------------- TEAR HERE ---------------------------"
90  DIM B$[3],C$[50],D$[50]
100  PRINT 
110  PRINT "TEAR OFF THE OUTPUT AND:"
120  PRINT "   1) CONNECT THE PLOTTED POINTS WITH A SMOOTH LINE, AND"
130  PRINT "   2) MARK THE CENTER OF THE PLOTTED POINTS."
140  PRINT F$
150  PRINT '10'10'10'10'10'10'10'10
160  D$="EQUNCOSAINTOCEMI"
170  Z=240
180  D=E=F=30
190  ENTER D,E,F
200  D=D/6
210  N=B=I-I
220  PRINT "----- QUESTIONS ABOUT THE SKETCH OF THE ORBITTING MASS:"
230  PRINT 
240  PRINT "   1. WHICH OF THE FOLLOWING WORDS BEST DESCRIBES THE SPEED"
250  PRINT "      OF THE ORBITTING MASS AT EACH POINT ALONG THE CIRCULAR PATH:"
260  PRINT "          A. CONSTANT,"
270  PRINT "          B. IRREGULARLY CHANGING,"
280  PRINT "          C. UNIFORMLY CHANGING, OR"
290  PRINT "          D. RANDOM."
300  PRINT "      A,B,C,OR D?  ";
310  ENTER Z,D,C$
320  PRINT '13
330  IF C$="A" THEN 360
340  GOSUB 1020
350  GOTO 300
360  GOSUB 1000
370  PRINT 
380  PRINT "   2. WHICH OF THE WORDS IN QUESTION 1 BEST DESCRIBES THE"
390  PRINT "      DIRECTION OF THE MOTION OF THE MASS?  ";
400  ENTER Z,D,C$
410  PRINT '13
420  IF C$="C" THEN 450
430  GOSUB 1020
440  GOTO 380
450  GOSUB 1000
460  PRINT 
470  PRINT "   3. WHICH OF THE WORDS IN QUESTION 1 BEST DESCRIBES THE"
480  PRINT "      VELOCITY OF THE ORBITTING MASS?  ";
490  ENTER Z,D,C$
500  PRINT '13
510  IF C$="C" THEN 540
520  GOSUB 1020
530  GOTO 470
540  GOSUB 1000
550  PRINT 
560  PRINT "   4. WHICH OF THE FOLLOWING WORDS BEST DESCRIBES THE"
570  PRINT "      ACCELERATION OF THE MASS AS IT ORBITS:"
580  PRINT "          A. INWARD,"
590  PRINT "          B. OUTWARD,"
600  PRINT "          C. TANGENTIAL, OR"
610  PRINT "          D. RANDOM."
620  PRINT "      A,B,C,OR D?  ";
630  ENTER Z,D,C$
640  PRINT '13
650  IF C$="A" THEN 680
660  GOSUB 1020
670  GOTO 620
680  GOSUB 1000
690  PRINT 
700  PRINT "THE DIRECTION OF THE ACCELERATION AT ALL POINTS ALONG THIS PATH"
710  PRINT "IS INWARD, TOWARD THE POINT AT THE CENTER OF THE CIRULAR ORBIT."
720  PRINT 
730  PRINT "----- PROBLEMS TO SOLVE:"
740  PRINT 
750  PRINT "--------- PROBLEM 1:"
760  PRINT 
770  PRINT "GIVEN:"
780  X=INT(100*RND(0))
790  IF 2 <= X AND X <= 12 THEN 810
800  GOTO 780
810  PRINT TAB(11);"RADIUS OF PATH ="X"UNITS OF DISTANCE"
820  PRINT TAB(11);"SPEED OF ORBITTING MASS ="X"UNITS OF SPEED"
830  PRINT 
840  PRINT "CALCULATE THE MAGNITUDE OF THE ACCELERATION OF THE ORBITTING MASS."
850  PRINT "   YOUR ANSWER = ";
860  ENTER Z,D,G
870  PRINT '13
880  IF D<0 THEN 850
890  IF G=X THEN 950
900  PRINT 
910  PRINT "THE MAGNITUDE OF THE ACCELERATION CAN BE CALCULATED BY DIVIDING"
920  PRINT "THE SPEED SQUARED BY THE RADIUS;"
930  PRINT "     ACCELERATION = (SPEED)^2/RADIUS."
940  GOTO 960
950  GOSUB 1000
960  PRINT 
970  PRINT "--------- PROBLEM 2:"
980  Z1=3
990  GOTO 60
1000  PRINT "     RIGHT!"
1010  RETURN 
1020  PRINT "     PLEASE RE-EXAMINE THE QUESTION AND TRY AGAIN."
1030  RETURN 
1040  END 
