10  COM N5,B$[72]
20  GOTO 60
30  CHAIN "$FORCE2"
40  REM PROGRAM NAME = FORCE1, APPLY FORCE TO STOP MOVING MASS
50  REM CHAINED TO FORCE, FORCE2
60  DIM A$[72]
70  LET P=0
80  K2=240
90  K1=2
100  LET T=1
110  LET M=INT(1000*RND(1)+1000)
120  IF INT(M/10)#M/10 THEN 110
130  LET F=INT(1000*RND(1)+2000)
140  IF INT(F/10)#F/10 THEN 130
150  LET V=INT(100*RND(1)+10)
160  LET V1=V
170  LET A=INT(((F/M)+.05)*10)/10
180  PRINT '10"--------APPLYING A FORCE TO STOP A MOVING MASS:"'10
190  PRINT "YOU ARE THE PILOT OF A SPACE VEHICLE THAT HAS A MASS OF"
200  PRINT M"KILOGRAMS AND AN INITIAL VELOCITY OF"V1"METERS/SECOND."
210  PRINT "THE VEHICLE IS BEING ACCELERATED AT"A"(M/S/S) "
220  PRINT "BY A FORCE OF"F"NEWTONS."
230  PRINT 
240  PRINT "YOUR TASK IS TO ACCELERATE TO ZERO VELOCITY IN FIVE SECONDS."
250  PRINT 
260  PRINT "----HOW MUCH FORCE(NEWTONS) DO YOU WANT TO APPLY?  ";
270  ENTER K2,K3,F1
280  PRINT '10;
290  IF K3<0 THEN 260
300  LET A=F/M
310  LET A1=F1/M
320  FOR X=1 TO 5
330  LET D[X]=V+A+A1
340  LET V=D[X]
350  NEXT X
360  PRINT '10"-----TABLE OF RESULTING VELOCITIES:"'10
370  PRINT "          TIME(SECONDS)     VELOCITY(METERS/SECOND)"
380  PRINT 
390  PRINT TAB(13);"0";TAB(32);V1
400  PRINT 
410  FOR X=1 TO 5
420  ENTER K1,K3,K4
430  IF D[X]>0 THEN 450
440  GOTO 510
450  IF D[X]>.5 THEN 470
460  IF X=5 THEN 590
470  IF X=5 THEN 550
480  PRINT TAB(12);X;TAB(32);D[X]
490  PRINT 
500  NEXT X
510  PRINT "YOU HAVE JUST REVERSED YOUR DIRECTION.YOU ARE NOW ACCELERATING"
520  PRINT "IN THE OPPOSITE DIRECTION."
530  PRINT "FINAL STATE OF TRANSPORT AFTER 5 SECONDS IS"D[5]"METERS/SEC."
540  GOTO 620
550  PRINT "YOU HAVE USED YOUR 5 SECONDS AND YOUR FINAL VELOCITY IS"
560  PRINT D[5]"METERS/SEC."
570  IF P=1 THEN 920
580  GOTO 620
590  PRINT '7'7'7'7'7'7'7'7'7'7"CONGRATULATIONS! AT 5 SECONDS FROM THE STARTING TIME YOU HAVE"
600  PRINT "REDUCED YOUR VELOCITY TO VERY NEARLY ZERO."
610  GOTO 740
620  IF T<2 THEN 640
630  GOTO 790
640  PRINT '10"DO YOU WANT TO TRY THE SAME PROBLEM AGAIN?  ";
650  ENTER K2,K3,A$
660  PRINT '10;
670  IF K3<0 THEN 640
680  LET T=T+1
690  LET V=V1
700  IF A$="NO" THEN 740
710  IF A$#"YES" THEN 640
720  PRINT '10'10
730  GOTO 260
740  PRINT 
750  PRINT "LET'S TRY A TWO DIMENSIONAL PROBLEM."
760  PRINT 
770  LET N5=2
780  GOTO 30
790  PRINT 
800  PRINT "HAVE YOU TRIED A FORCE THAT IS EQUAL IN MAGNITUDE, BUT OPPOSITE"
810  PRINT "IN DIRECTION TO THE INITIAL FORCE?  ";
820  ENTER K2,K3,A$
830  PRINT '10;
840  IF K3<0 THEN 810
850  IF A$="YES" THEN 920
860  IF A$#"NO" THEN 800
870  LET P=1
880  LET F=-F
890  PRINT '10"HERE IS WHAT HAPPENS IF YOU DO:"
900  PRINT '10"----FORCE APPLIED ="F"NEWTONS"'10
910  GOTO 300
920  PRINT 
930  PRINT "WHEN THE APPLIED FORCE IS EQUAL AND OPPOSITE TO THE INITIAL"
940  PRINT "FORCE, THE ACCELERATION OF THE MASS BECOMES ZERO."
950  PRINT "THE MASS THEN MOVES AT A UNIFORM VELOCITY."
960  PRINT 
970  PRINT "TO STOP, THE MASS MUST THEN BE ACCELERATED FROM THAT VELOCITY TO ZERO."
980  PRINT "YOU MUST CALCULATE THE ADDITIONAL FORCE NEEDED TO ACCELERATE THE MASS"
990  PRINT "FROM ITS INITIAL VELOCITY"V1"METERS/SEC. TO 0 METERS/SEC."
1000  PRINT "IN 5 SECONDS."
1010  PRINT 
1020  PRINT "  1. ACCELERATION = CHAINGE IN VELOCITY DIVIDED BY TIME"
1030  PRINT "            A     = (FINAL V - INITIAL V)/T"
1040  PRINT "            A * T =  FINAL V - INITIAL V"
1050  PRINT "     FINAL V = INITIAL V  +  (A * T)"
1060  PRINT 
1070  PRINT "  2. WE KNOW THAT FINAL VELOCITY = 0 METERS/SECOND,"
1080  PRINT "                            TIME = 5 SECONDS, AND"
1090  PRINT "                INITIAL VELOCITY ="V1"METERS/SECOND."
1100  PRINT 
1110  PRINT "  3. SUBSTITUTING THESE VALUES INTO THE EQUATION,"
1120  PRINT "     0(M/SEC) ="V1"(M/SEC)  + (A * 5 SEC)"
1130  PRINT 
1140  PRINT "  4. SOLVING THE EQUATION FOR THE ACCELERATION A,"
1150  PRINT "         A   ="-V1"(M/SEC)/5(SEC)"
1160  PRINT "     ACCELERATION ="-V1/5"(M/SEC)/SEC"
1170  PRINT 
1180  PRINT "  5. CALCULATING THE FORCE NEEDED TO CAUSE THIS ACCELERATION,"
1190  PRINT "     FORCE = MASS(OF OBJECT) TIMES ACCELERATION"
1200  PRINT "     FORCE ="M"(KG) * ("-V1/5"(M/SEC)/SEC)"
1210  PRINT "     FORCE ="-M*V1/5"NEWTONS"
1220  PRINT "     THIS IS THE FORCE NECESSARY TO CHANGE THE VELOCITY "
1230  PRINT "     OF A"M"KG MASS FROM"V1"M/SEC TO ZERO M/SEC."
1240  PRINT 
1250  PRINT "  6. NOW WE CAN CALCULATE THE TOTAL FORCE NECESSARY,"
1260  PRINT "     TOTAL FORCE = FORCE TO STOP ACCELERATION  PLUS"
1270  PRINT "                   FORCE TO REDUCE THE VELOCITY TO ZERO"
1280  PRINT "     TOTAL FORCE = ("-F"NEWTONS)  + ("-M*V1/5"NEWTONS)"
1290  PRINT "     TOTAL FORCE ="-F-M*V1/5"NEWTONS"
1300  PRINT 
1310  PRINT "LET'S TRY ANOTHER PROBLEM."
1320  PRINT '10'10'10'10
1330  GOTO 60
1340  END 
