5  REM CHEM1, HP 36878A, 6/74
10  REM**INPUT**C.A.I.**INPUT ROUTINE FOR CHEM1 & CHEM2**MAY 19, 1972
20  PRINT "THIS PROGRAM WRITES THE FILES FOR USE WITH CHEM1 AND CHEM2"
30  PRINT "MAKE SURE A FILE HAS BEEN OPENED AND DECLARED IN STATEMENT"
40  PRINT "FIVE OF THIS PROGRAM."
50  READ #1,1
60  DIM A$[72],B$[72]
70  PRINT "IS THERE ORDER";
80  INPUT A$
90  IF A$="YES" THEN 120
100  PRINT #1;"NONE"
110  GOTO 180
120  PRINT #1;"ORDER"
130  PRINT "WHAT IS THE FIRST ITEM";
140  INPUT A$
150  PRINT "AND THE SECOND";
160  INPUT B$
170  PRINT #1;A$,B$
180  PRINT "HOW MANY LEVELS ARE THERE";
190  INPUT N
200  IF INT(N)=N AND N>0 AND N<11 THEN 230
210  PRINT "MUST BE INTEGER BETWEEN 1 AND 10 INCLUSIVE."
220  GOTO 180
230  PRINT #1;N
240  S=0
250  FOR I=1 TO N
260  PRINT "HOW MANY QUESTIONS IN LEVEL";I;
270  INPUT M
280  IF M=INT(M) AND M>0 THEN 300
290  GOTO 260
300  S=S+M
310  PRINT #1;S
320  A[I]=M
330  NEXT I
340  FOR I=1 TO N
350  PRINT "INPUT TO LEVEL";I
360  FOR J=1 TO A[I]
370  PRINT "FIRST ITEM"
380  INPUT A$
390  PRINT #1;A$
400  PRINT "# ANSWERS";
410  INPUT M
420  PRINT #1;M
430  FOR K=1 TO M
440  PRINT "#"K;
450  INPUT A$
460  PRINT #1;A$
470  NEXT K
480  NEXT J
490  NEXT I
500  PRINT "INPUT TO THE FILE IS COMPLETE"
510  END 
