10  REM WRITTEN BY  JEFF BROWN  /  ARAGON H.S.  /  10-23-75
20  REM *  HP 2000/ACCESS   'HANG' = HANGMAN   -  5374 WORDS=21 BLK  *
30  DIM Z$[26],G$[21],A$[21],B$[21],W$[21]
40  Z$="ABCDEFGHIJKLMNOPQRSTUVWXYZ"
50  DIM S[26]
60  DATA 604
70  DATA "CAPTAIN","THERAPIST","BALANCE","FOUND"
80  DATA "NAME","ACUMEN","ACTUALITY","SPOTTED"
90  DATA "SUBSCRIPTION","WHEREWITHAL","NEUTRAL","ZEALOUS"
100  DATA "SYSNTHESIS","AMERICAN","DUBIOUS","ORGIASTIC"
110  DATA "MONOTHEISM","VISUALIZED","TERRIFIC","STUPENDOUS"
120  DATA "STUPIFY","TURKEY","QUOTIENT","REJECTION"
130  DATA "STOMACHACHE","DEPRESSED","EXPLANATION","TORPEDO"
140  DATA "CURRENTLY","CHEATING","INFORMATION","NUMERICAL"
150  DATA "REGIONAL","APPLICABLE","DYNASTY","HUMANITARIAN"
160  DATA "STEREOTYPE","GEOMETRY","ENVIRONMENTAL","OFFENSIVE"
170  DATA "RENAISSANCE","AUTOBIOGRAPHY","RANDOMIZE","SHIELD"
180  DATA "ELECTROENCEPHALOGRAPH","REGISTER","INCREDIBLE","MISSPELL"
190  DATA "INTEGER","COMPUTER","WASTE","POLLUTION"
200  DATA "TEACHER","TRADGEDY","ORIGINATE","ENGLISH"
210  DATA "LIBRARY","AUTOMOBILE","MISSISSIPPI","BOULEVARD"
220  DATA "PATTERN","CULTURE","FLYING","INTROSPECTIVE"
230  DATA "VARIABLE","CONSTANTLY","UNIVERSE","GLASSES"
240  DATA "CRYSTAL","XYLOPHONE","STEED","RECEIVER"
250  DATA "ELECTRICITY","CAFETERIA","BATTALLION","TRANSFER"
260  DATA "FRIEND","DESPICABLE","DISGUSTING","SYNONYMS"
270  DATA "TREK","STOCK","HANGMAN","NOOSE"
280  DATA "NORDIC","QUADRATIC","NOMAD","ESCAPADE"
290  DATA "NOTARIZE","STAR","RATS","CATEGORY"
300  DATA "YELLOW","TELETYPE","AUTOMATIC","SILENCE"
310  DATA "ANIMAL","LAWYER","RANDOM","CENTURY"
320  DATA "ACCEPT","DELUSION","ILLUSION","CONCLUSION"
330  DATA "RESPONSE","EXCITE","POTENT","IMPECCABLE"
340  DATA "EVENING","STRIKE","BACKGROUND","EXTREME"
350  DATA "ABRUPT","AQUIESCE","ANALYZE","ARCHITECT"
360  DATA "ARRAIGN","ASININE","ASTERISK","AUDIBLE"
370  DATA "AUCTIONEER","BANANA","BANQUET","BERSERK"
380  DATA "BUDGET","ALUMINUM","ASPHALT","ATHLETICS"
390  DATA "AFFECT","EFFECT","BUOYANCE","BUREAUS"
400  DATA "CAMPAIGN","LACQUER","JOURNEY","INVEIGLE"
410  DATA "FIERY","CONDEMN","CASHIER","CATASTROPHE"
420  DATA "COLLATERAL","HECTIC","HAPHAZARD","HANDKERCHIEF"
430  DATA "CRITICIZE","CRITICISM","COUNCIL","COUNSEL"
440  DATA "CORRUGATED","CONSCIENTIOUS","COLOSSAL","CHAUFFEUR"
450  DATA "DELINQUENT","DEUCE","ELIGIBLE","ENCYCLOPEDIA"
460  DATA "ALLOTMENT","ALIGNMENT","EMINENT","EXTEMPORANEOUS"
470  DATA "GAUGE","GROCERY","INTEGRATE","IDIOSYNCRASY"
480  DATA "INTERCEDE","INTERFERE","KHAKI","ANECDOTE"
490  DATA "ACCELERATE","ACCESSIBLE","INDELIBLE","LEGITIMATE"
500  DATA "GRAMMAR","GUARANTEE","CYNICAL","INSTALLATION"
510  DATA "IMMITATION","KIMONO","JUDGEMENT","JUSTIFIABLE"
520  DATA "RECONSTRUCTION","CHAIN","INCONSISTENT","HISTORY"
530  DATA "RELATION","BONDAGE","SEGREGATION","GRADUAL"
540  DATA "EQUALITY","PROGRESS","PROSPERITY","CONSTITUTION"
550  DATA "EMANCIPATION","SEPARATION","POPULAR","PROCLAMATION"
560  DATA "EDUCATION","OVERTURN","SUPREME","WARLORD"
570  DATA "PRESIDENT","PRINCIPLE","PRINCIPAL","COMPROMISE"
580  DATA "WITHDRAW","OPINION","POLITICAL","SEMANTICS"
590  DATA "ESTABLISH","DISSENT","SUFFICIENT","FACILITATE"
600  DATA "AMENDMENT","MAJORITY","ELOQUENT","ACCOMODATE"
610  DATA "PASSENGER","REASON","PRESERVE","RESERVED"
620  DATA "NAVEL","BLESS","CHILDREN","BUFFALO"
630  DATA "NIGHT","RIGHT","SIGHT","CARD"
640  DATA "AND","THE","PEW","HUE"
650  DATA "DUE","RUE","SUE","PICTURE"
660  DATA "RESTITUTION","DESTITUTION","CARPET","SURFACE"
670  DATA "NUCLEAR","SUBMARINE","SAILORS","PROUDEST"
680  DATA "CRAFT","OPERATE","BECAUSE","NOBODY"
690  DATA "SOMEONE","ACTION","MIGHT","FLASHCUBE"
700  DATA "MAGNIFIED","QUIVER","CHEMICAL","ALCOHOLIC"
710  DATA "JUICE","FERMENT","TELEVISION","TELEPHONE"
720  DATA "TELEGRAPH","REMARKABLE","FORTUNE","DISCOVERY"
730  DATA "BACTERIA","DISCOUNT","MISCOUNT","VIRUSES"
740  DATA "PRIMITIVE","PREDILECTION","CHAPTER","CHURCH"
750  DATA "NITROGEN","CELLULAR","MODIFY","GEOLOGIST"
760  DATA "POPULATION","ABUNDANT","THEORY","NUMEROUS"
770  DATA "MICROSCOPE","SPONTANEOUS","AROUSE","YEAST"
780  DATA "BRILLIANT","EXPLORE","TOWNSHIP","CADDY"
790  DATA "KINGDOM","THOUSAND","ADDITION","PUZZLE"
800  DATA "ZENITH","ELECTRON","PIZZA","KNIGHT"
810  DATA "FILAMENT","PLURALITY","GELATIN","CHARACTER"
820  DATA "CAPSULE","COLLISION","QUILT","WATERFALL"
830  DATA "RAGGED","SPANK","QUIZZICAL","QUIRK"
840  DATA "STRATOSPHERE","AQUAMARINE","SCUBA","TUXEDO"
850  DATA "DOLPHIN","DASHING","ACCURATE","ABSTINENCE"
860  DATA "MARTINI","BLONDE","OWL","COOKY"
870  DATA "COFFEE","LARGE","BLOUSE","FREEWAY"
880  DATA "FURNITURE","CHESS","CHECKMATE","GOLDEN"
890  DATA "GLOBE","AWARDS","EXECUTIVE","PRODUCER"
900  DATA "DIRECT","HARNESS","AWL","BARD"
910  DATA "CURTAIN","ADVERTISE","ASSASSINATE","TRAUMA"
920  DATA "GROWTH","NEWSPAPER","CLASSIFY","FOLLOW"
930  DATA "ATROPHY","METHANE","GASOLINE","OCTAVE"
940  DATA "OCTANE","SONAR","RADAR","OXYGEN"
950  DATA "PIGEONHOLE","BUTTON","BOXCAR","CHRYSANTHEMUM"
960  DATA "KARATE","AIKIDO","LURCH","TRUNK"
970  DATA "FOX","PHONOGRAPH","FURNACE","COUCH"
980  DATA "AMAZE","STRANGLE","NEIGH","HAZY"
990  DATA "BUCKET","TROWEL","CONFESS","THROAT"
1000  DATA "THOUGH","HEADACHE","BUNDLE","FLIMSY"
1010  DATA "WROUGHT","CAVALRY","CHIVALRY","HUSBAND"
1020  DATA "MERCY","TORNADO","TEMPERATURE","ADVERSE"
1030  DATA "MUCOUS","INHIBIT","PHOTOSYNTHESIS","ENGULF"
1040  DATA "JUXTAPOSITION","EULOGY","JURISPRUDENCE","ESSENTIAL"
1050  DATA "MUSTACHE","MUSTARD","EXTREMITY","GLIB"
1060  DATA "PANCAKE","CUPCAKE","CUBSCOUT","COMB"
1070  DATA "SMALLPOX","HOTEL","WALLET","HAMMOCK"
1080  DATA "COVER","AFFORD","READY","CATALOG"
1090  DATA "REMOVE","PROTECT","BRICK","SQUARE"
1100  DATA "HORSE","RACETRACK","REPORTER","BROADCAST"
1110  DATA "COUNTER","PROPHECY","EYELID","FINGER"
1120  DATA "ELBOW","KNEECAP","SKULL","VEHICLE"
1130  DATA "CHOKE","VASE","BROUGHT","SOUGHT"
1140  DATA "CAUGHT","LAUGHTER","SPLINTER","AUDIENCE"
1150  DATA "COVERALL","COCKTAIL","MILLIONAIRE","BOOKSTORE"
1160  DATA "OVERCOAT","SADDLE","MEDALLION","ROCKER"
1170  DATA "SIDELINE","TEEPEE","VOODOO","SCARF"
1180  DATA "CAVIAR","ENTOURAGE","STEERAGE","SPENDTHRIFT"
1190  DATA "PIPER","PHEASANT","PEASANT","BAZOOKA"
1200  DATA "BLOOD","SWEAT","TEARS","VIOLET"
1210  DATA "VINEGAR","CLOTHES","TRIPLE","UNDER"
1220  DATA "SKIING","BOOZE","MIDGET","JOB"
1230  DATA "BOLOGNA","PASTRAMI","ONION","DRY"
1240  DATA "FRESHEN","BOBBIN","BEG","MAYONNAISE"
1250  DATA "FAVORITE","GALAXY","DOORBELL","PALMISTRY"
1260  DATA "HAIRCUT","SHORTCUT","GAMBLING","STREAK"
1270  DATA "SECURITY","COLLAR","BUFFET","BUFFER"
1280  DATA "CAREFUL","ROMANTIC","PRIME","CONSULT"
1290  DATA "FEATURE","ASSIST","MUSIC","SCORE"
1300  DATA "MOUNTAIN","STALK","KILLER","DIGIT"
1310  DATA "URANIUM","BOUTIQUE","OBSTINATE","GUNNER"
1320  DATA "PROVEN","PROFANE","SHIFTY","BEAM"
1330  DATA "CORDLE","ASPHALT","STOREROOM","BEEF"
1340  DATA "SEAM","CABOOSE","VILLAGE","BEAD"
1350  DATA "FLAG","UNION","CIVIL","WAR"
1360  DATA "VACATION","ERASER","DISRESPECT","LOUD"
1370  DATA "SPECIOUS","PRECIOUS","GUEST","MARK"
1380  DATA "CAR","BAR","TAR","DART"
1390  DATA "SCHEDULE","GRADING","RULER","BENEVOLENT"
1400  DATA "TEXTILE","PINE","ISLAND","TREASURE"
1410  DATA "YEAR","ANNUAL","WEEK","EON"
1420  DATA "LEAVE","SWEATER","PLEDGE","REMAIN"
1430  DATA "SECTION","DAILY","PAGE","RESULT"
1440  DATA "BERET","PINUP","SKETCH","WEALTH"
1450  DATA "FRUIT","CEREAL","WEIRD","USED"
1460  DATA "EXIST","CRISP","SUPER","DOUBT"
1470  DATA "INTEREST","BATTERY","PEANUT","BUTTER"
1480  DATA "SKIP","KNIFE","FORK","SPOON"
1490  DATA "BRACE","EAGLE","HERO","CHARTER"
1500  DATA "SPREE","TENDER","POWER","SECRET"
1510  DATA "NOTEBOOK","TONIGHT","SOOT","CHIMNEY"
1520  DATA "THURSDAY","MONDAY","WEDNESDAY","ROUGHNECK"
1530  DATA "SCHOOL","WHEAT","INFINITE","ELEVATE"
1540  DATA "CAUCUS","ASPIRIN","LIONESS","BEASTS"
1550  DATA "EVENTUAL","EDITION","LANGUAGE","DICTION"
1560  DATA "GAMBOL","MAGAZINE","POWDER","DECORATE"
1570  READ N
1580  PRINT TAB(26);LIN(-2)"*** HANGMAN ***"LIN(2)
1590  PRINT "DO YOU WANT INSTRUCTIONS  ( YES OR NO )  ";
1600  INPUT Y$[1,1]
1610  IF Y$[1,1]="Y" THEN 2610
1620  IF Y$[1,1] <> "N" THEN 1590
1630  W=INT(RND(0)*N)+1
1640  W0=INT((W-1)/100)
1650  GOTO W0 OF 1680,1700,1720,1740,1760,1780
1660  RESTORE 70
1670  GOTO 1790
1680  RESTORE 310
1690  GOTO 1790
1700  RESTORE 560
1710  GOTO 1790
1720  RESTORE 810
1730  GOTO 1790
1740  RESTORE 1060
1750  GOTO 1790
1760  RESTORE 1310
1770  GOTO 1790
1780  RESTORE 1560
1790  FOR X=((W0*100)+1) TO W
1800  READ W$
1810  NEXT X
1820  B$=W$
1830  L=LEN(W$)
1840  G$=G$[2,1]
1850  FOR X=1 TO L
1860  G$[LEN(G$)+1]="-"
1870  NEXT X
1880  T=T1=T2=0
1890  PRINT "THE WORD HAS"L" LETTERS."
1900  MAT S=CON
1910  IF T2/3 <> INT(T2/3) OR T2=0 THEN 1980
1920  PRINT "SO FAR YOU HAVE USED :  ";
1930  FOR X=1 TO 26
1940  IF S[X] THEN 1960
1950  PRINT Z$[X,X];
1960  NEXT X
1970  PRINT LIN(2)
1980  T2=T2+1
1990  PRINT "CHOOSE A LETTER   ";
2000  INPUT A$
2010  IF A$=W$ THEN 2390
2020  IF LEN(A$)>1 THEN 2220
2030  IF A$ <> " " THEN 2060
2040  PRINT "YOU DON'T WANT TO WASTE A TURN WITH A BLANK. RIGHT !"
2050  GOTO 1990
2060  B4=POS(Z$,A$)
2070  IF B4=INT(B4) AND B4>0 THEN 2100
2080  PRINT "THAT LETTER  ( '"A$"' )  DOES NOT EXIST."
2090  GOTO 1990
2100  IF S[B4] THEN 2130
2110  PRINT "THAT LETTER HAS ALREADY BEEN USED."
2120  GOTO 1990
2130  S[B4]=0
2140  C=0
2150  B5=POS(B$,A$)
2160  IF B5<1 OR B5 <> INT(B5) THEN 2240
2170  C=C+1
2180  G$[B5,B5]=A$
2190  B$[B5,B5]=" "
2200  T1=T1+1
2210  GOTO 2150
2220  PRINT "BAD NEWS !   '"A$"'  IS NOT THE WORD."
2230  GOTO 2260
2240  IF C THEN 2320
2250  PRINT "I'M SORRY.  THERE ARE NO "A$"'S."
2260  T=T+1
2270  GOSUB 2450
2280  IF T<7 THEN 1910
2290  PRINT "GASP!   CHOKE !!!!     YOU HAVE BEEN HANGED !!!!"
2300  PRINT "THE WORD WAS "W$;LIN(3)
2310  GOTO 2400
2320  IF C>1 THEN 2360
2330  PRINT "THERE WAS ONE  "A$".  YOU NOW HAVE  "G$
2340  IF T1<L THEN 1910
2350  GOTO 2390
2360  PRINT "THERE WERE"C"  "A$"'S.  YOU NOW HAVE  "G$
2370  IF T1<L THEN 1910
2380  GOTO 2390
2390  PRINT "VERY GOOD !!"'7'7"!  YOU GUESSED THE WORD.  YOU HAVE WON !"'7"!"'7"!"'7'7LIN(3)
2400  PRINT "ANOTHER GAME  ( YES OR NO )  ";
2410  INPUT Y$[1,1]
2420  IF Y$[1,1]="Y" THEN 1630
2430  IF Y$[1,1] <> "N" THEN 2400
2440  STOP 
2450  PRINT LIN(2)"   )O("
2460  IF T<2 THEN 2590
2470  PRINT "    !"
2480  IF T<3 THEN 2590
2490  PRINT "*---@";
2500  IF T<4 THEN 2590
2510  PRINT "---*"
2520  IF T<5 THEN 2590
2530  PRINT "    @"LIN(1)"    @"
2540  IF T<6 THEN 2590
2550  IF T=7 THEN 2580
2560  PRINT "   *"LIN(1)"  *"LIN(1)" *"LIN(1)"*"
2570  GOTO 2590
2580  PRINT "   * *"LIN(1)"  *   *"LIN(1)" *     *"LIN(1)"*       *"
2590  PRINT LIN(2+(T=3))
2600  RETURN 
2610  PRINT LIN(3)"   I, THE COMPUTER, WILL CHOOSE A WORD AND I WILL TELL"
2620  PRINT "YOU THE NUMBER OF LETTERS IN THE WORD.  YOU MUST GUESS THE"
2630  PRINT "WORD LETTER BY LETTER.  YOU MUST NOT MAKE MORE THAN SIX MISTAKES,"
2640  PRINT "SINCE FOR EACH MISTAKE I WILL ADD A PIECE OF YOUR BODY.  THERE"
2650  PRINT "ARE SEVEN PARTS; WHEN ALL PARTS ARE ADDED YOU ARE HANGED.  IF"
2660  PRINT "YOU THINK YOU KNOW WHAT THE WORD IS YOU MAY INPUT YOUR GUESS"
2670  PRINT "INSTEAD OF A LETTER.  IF YOU ARE RIGHT YOU WIN AND IF YOU ARE"
2680  PRINT "WRONG A PIECE OF YOUR BODY IS ADDED.  DON'T WORRY ABOUT RE-"
2690  PRINT "MEMBERING WHAT LETTERS YOU HAVE USED, I WILL TELL YOU WHICH ONES"
2700  PRINT "YOU HAVE USED EVERY SO OFTEN."LIN(3)
2710  GOTO 1630
2720  END 
