10  DIM A$[20],B$[20],C$[10],D$[72],C[50],X[50]
20  REM
30  REM  STATES:  A PROGRAM TO TEST YOUR ABBV. OF STATES.
40  REM  PROGRAMMED BY RODERIC LANCE HOM, JULY 28, 1975
50  REM  400  MANSELL STREET  SAN FRAN. CA 94135 (415) 239-6460
60  REM  REV. 3/21/77  F.SCHICKEL.
65  IF  ERROR  THEN 830
70  IF TIM(1)>12 THEN 100
80  PRINT "GOOD MORNING, ";
90  GOTO 140
100  IF TIM(1)>17 THEN 130
110  PRINT "GOOD AFTERNOON, ";
120  GOTO 140
130  PRINT "GOOD EVENING, ";
140  PRINT "I'M SHORT...WHAT'S YOUR NAME";
150  INPUT D$
160  PRINT "THIS PROGRAM IS A SMALL QUIZ TO SEE HOW WELL YOU KNOW"
170  PRINT "POST OFFICE ABBREVIATIONS OF THE STATES."
180  PRINT 
190  PRINT "THE HIGHER THE SCORE THE BETTER."
200  PRINT "A SCORE OF 8 OR MORE OUT OF 10 IS BEST."
210  PRINT 
220  PRINT "====="
230  PRINT LIN(-3)
240  MAT C=ZER
250  MAT X=ZER
260  C=K=T=0
270  FOR A=1 TO 5
280  FOR I=1 TO 10
290  R=INT(50*RND(0)+1)
300  FOR J=1 TO 50
310  IF X[J]=R THEN 290
320  NEXT J
330  X[R]=R
340  RESTORE 
350  FOR N=1 TO R
360  READ A$,B$,B
370  NEXT N
380  PRINT "   ";A$;TAB(20);
390  ENTER 255,C1,C$
400  L=LEN(C$)
410  IF L=2 THEN 460
420  T=T+1
430  IF T=2 THEN 470
440  PRINT TAB(30);"ALL ABBV ARE TWO LETTERS"
450  GOTO 380
460  IF C$=B$ THEN 520
470  PRINT "X";TAB(30);B$
480  T=0
490  C[R]=1
500  C[R]=-1
510  GOTO 540
520  C=C+1
530  PRINT "C"
540  NEXT I
550  IMAGE #,"YOU GOT ",DD," CORRECT OUT OF 10 POSSIBLE FOR A SCORE OF"
560  IMAGE X,DDD,"%."
570  PRINT 
580  PRINT  USING 550;C
590  PRINT  USING 560;C*10
600  IF C<8 THEN 630
610  PRINT "VERY GOOD."
620  PRINT 
630  PRINT "WOULD YOU LIKE TO TRY SOME MORE";
640  INPUT A$
650  IF A$[1,1]="N" THEN 700
660  C=0
670  PRINT LIN(-2)
680  NEXT A
690  PRINT "THAT'S ALL I HAVE, HOPE YOU HAD FUN"
700  PRINT 
710  RESTORE 
720  PRINT "HERE IS YOUR LIST TO STUDY, "D$"."LIN(1)
730  PRINT "STATE"TAB(14)"ABBV"
740  PRINT "-----"TAB(14)"----"
750  FOR I=1 TO 50
760  READ A$,B$,B
770  IF  NOT C[I] THEN 800
780  PRINT A$;TAB(15);B$
790  K=1
800  NEXT I
810  IF K THEN 830
820  PRINT "CONGRADULATIONS, YOU GOT THEM ALL RIGHT!"
830  CHAIN R,"*HELP"
835  SYSTEM X,"BYE"
840  DATA "ALABAMA","AL",6,"ALASKA","AK",8,"ARIZONA","AZ",4,"ARKANSAS","AR",6
850  DATA "CALIFORNIA","CA",3,"COLORADO","CO",5,"CONNECTICUT","CT",5
860  DATA "DELAWARE","DE",5,"FLORIDA","FL",6,"GEORGIA","GA",5,"HAWAII","HI",5
870  DATA "IDAHO","ID",6,"ILLINOIS","IL",6,"INDIANA","IN",6,"IOWA","IA",5
880  DATA "KANSAS","KS",5,"KENTUCKY","KY",5,"LOUISIANA","LA",5,"MAINE","ME",5
890  DATA "MARYLAND","MD",5,"MASSACHUSETTS","MA",6,"MICHIGAN","MI",6
900  DATA "MINNESOTA","MN",7,"MISSISSIPPI","MS",7,"MISSOURI","MO",9
910  DATA "MONTANA","MT",8,"NEBRASKA","NE",6,"NEVADA","NV",7,"NEW HAMPSHIRE","NH",3
920  DATA "NEW JERSEY","NJ",3,"NEW MEXICO","NM",3,"NEW YORK","NY",3,"NORTH CAROLINA","NC",3
930  DATA "NORTH DAKOTA","ND",3,"OHIO","OH",6,"OKLAHOMA","OK",6,"OREGON","OR",6
940  DATA "PENNSYLVANIA","PA",5,"RHODE ISLAND","RI",3,"SOUTH CAROLINA","SC",3
950  DATA "SOUTH DAKOTA","SD",3,"TENNESSEE","TN",8,"TEXAS","TX",3,"UTAH","UT",3
960  DATA "VERMONT","VT",5,"VIRGINIA","VA",5,"WASHINGTON","WA",6,"WEST VIRGINIA","WV",3
970  DATA "WISCONSIN","WI",6,"WYOMING","WY",6
980  END 
