10  REM  TAX DRILL BY WILLIAM K. CHAR, REVISED APRIL 19, 1974.
20  REM
30  DIM A[10],A$[72]
40  REM
45  IF  ERROR  THEN 1020
50  IF TIM(1)>11 THEN 80
60  PRINT "GOOD MORNING, ";
70  GOTO 120
80  IF TIM(1)>15 THEN 110
90  PRINT "GOOD AFTERNOON, ";
100  GOTO 120
110  PRINT "GOOD EVENING, ";
120  PRINT "THIS IS A TAX DRILL.  NEED THE INSTRUCTIONS";
130  INPUT A$
140  IF A$[1,1]="N" THEN 310
150  PRINT 
160  PRINT "     WITH THIS PROGRAM, YOU WILL LEARN HOW TO LOOK AT A TAX"
170  PRINT "TABLE AND QUICKLY FIND THE TAX AMOUNT TO ANY TRANSACTION--"
180  PRINT "JUST AS DO CASHIERS AT LUCKY'S OR SEARS.  YOU WILL NEED A"
190  PRINT "STATE OF CALIFORNIA 5-1/2%, 6%, OR 6-1/2% SALES TAX TABLE,"
200  PRINT "AVAILIABLE AT WOODROW WILSON H. S. UPON DEMAND."
210  PRINT 
220  PRINT "     THE MACHINE WILL TYPE A RANDOM TRANSACTION.  YOU TYPE"
230  PRINT "THE CORRECT TAX NEXT TO IT.  DO NOT TYPE THE DECIMAL POINT!"'7'7
240  PRINT "(FOR EXAMPLE, .61=61, 1.21=121, ETC.)  THE MACHINE WILL TYPE"
250  PRINT "AN ASTERISK (*) AND THE NUMBER OF SECONDS USED IF CORRECT, AN"
260  PRINT "'X' IF INCORRECT, OR A 'T' IF YOU WERE TIMED OUT."
270  PRINT 
280  PRINT "     YOUR SCORE WILL DEPEND ON HOW MANY SECONDS YOU USED AND"
290  PRINT "BY THE NUMBER OF SECONDS YOU GAVE YOURSELF PER PROBLEM, SO"
300  PRINT "THINK FAST!"
310  PRINT 
320  PRINT "HOW MANY SECONDS DO YOU WANT TO GIVE YOURSELF PER PROBLEM";
330  INPUT T
340  IF T>2 AND T<30 THEN 370
350  PRINT "YOU ARE GIVING YOURSELF TOO LITTLE OR TOO MUCH TIME."
360  GOTO 320
370  PRINT "ARE YOU USING A 5.5%, 6%, OR 6.5% TAX TABLE";
380  INPUT Q
390  IF Q <> 5.5 AND Q <> 6 AND Q <> 6.5 THEN 370
400  PRINT "WHAT'S THE HIGHEST TRANSACTION AMOUNT ON YOUR TAX TABLE";
410  INPUT S
420  IF S >= 1 THEN 450
430  PRINT "YOUR TABLE MUST GO UP TO AT LEAST $1.  TRY AGAIN."
440  GOTO 400
450  IF S<30 THEN 480
460  PRINT "I DON'T THINK YOUR TAX TABLE GOES THAT HIGH.  TRY AGAIN."
470  GOTO 400
480  RESTORE 
490  READ J
500  MAT  READ A[J]
510  IF Q=5.5 THEN 570
520  READ J
530  MAT  READ A[J]
540  IF Q=6 THEN 570
550  READ J
560  MAT  READ A[J]
570  PRINT 
580  PRINT "TRANSACTION TAX?"
590  C=T1=T2=0
600  PRINT 
610  FOR I=1 TO 10
620  X=INT(RND(1)*S*100)/100
630  PRINT  USING "#,5X,DD.DDXX";X
640  ENTER T,R,A
650  PRINT LIN(0);
660  IF R<0 THEN 770
670  IF X <= .1 AND A=0 THEN 820
680  IF X>A[J] THEN 730
690  FOR B=1 TO J
700  IF X <= A[B] THEN 740
710  NEXT B
720  GOTO 750
730  B=INT(X*Q+.5)
740  IF A=B THEN 820
750  PRINT "X"
760  GOTO 790
770  PRINT "T"
780  T2=T2+1
790  T1=T1+T
800  GOTO 850
810  IMAGE "*",DD
820  PRINT  USING 810;R
830  T1=T1+R
840  C=C+1
850  NEXT I
860  PRINT 
870  PRINT "   # RIGHT:  "C
880  PRINT "TIMED OUTS:  "T2
890  PRINT "   SECONDS: "T1
900  PRINT 
910  IF T2<3 THEN 940
920  PRINT "YOU NEED TO GIVE YOURSELF MORE TIME."
930  PRINT 
940  PRINT "ANOTHER TRY";
950  INPUT A$
960  IF A$[1,1]="Y" THEN 310
970  PRINT 
980  PRINT "BYE"
990  DATA 7,.25,.45,.62,.79,.97,1.15,1.36
1000  DATA 6,.22,.39,.56,.73,.9,1.08
1010  DATA 6,.2,.35,.51,.67,.83,.99
1020  CHAIN R,"*HELP"
1030  SYSTEM X,"BYE"
1040  END 
