5  IF  ERROR  THEN 1615
10  DIM A$[72],X[51],W[51]
20  PRINT " ","WATER POLLUTION STUDY"
30  PRINT 
31  IF TIM(1)>11 THEN 34
32  PRINT "GOOD MORNING, ";
33  GOTO 40
34  IF TIM(1)>15 THEN 37
35  PRINT "GOOD AFTERNOON, ";
36  GOTO 40
37  PRINT "GOOD EVENING, ";
40  PRINT "NEED INSTRUCTIONS";
50  INPUT A$
60  IF A$[1,1]="N" THEN 340
70  IF A$[1,1] <> "Y" THEN 40
80  PRINT 
90  PRINT "IN THIS STUDY YOU CAN SPECIFY ";
100  PRINT "THE FOLLOWING CHARACTERISTICS:"
110  PRINT 
120  PRINT "A. THE KIND OF BODY OF WATER:"
130  PRINT "   1. LARGE POND"
140  PRINT "   2. LARGE LAKE"
150  PRINT "   3. SLOW-MOVING RIVER"
160  PRINT "   4. FAST-MOVING RIVER"
170  PRINT 
180  PRINT "B. THE WATER TEMPERATURE IN DEGREES FAHRENHEIT:"
190  PRINT 
200  PRINT "C. THE KIND OF WASTE DUMPED INTO THE WATER:"
210  PRINT "   1. INDUSTRIAL"
220  PRINT "   2. SEWAGE"
230  PRINT 
240  PRINT "D. THE RATE OF DUMPING OF WASTE,";
250  PRINT " IN PARTS PER MILLION (PPM)/DAY."
260  PRINT 
270  PRINT "E. THE TYPE OF TREATMENT OF THE WASTE:"
280  PRINT "   0. NONE "
290  PRINT "   1. PRIMARY (SEDIMENTATION OR PASSAGE THROUGH FINE"
300  PRINT "               SCREENS TO REMOVE GROSS SOLIDS)"
310  PRINT "   2. SECONDARY (SAND FILTERS OR THE ACTIVATED SLUDGE"
320  PRINT "                 METHOD TO REMOVE DISSOLVED AND COLLOIDAL"
330  PRINT "                 ORGANIC MATTER)"
340  PRINT 
350  PRINT "***********"
360  PRINT 
370  PRINT "BODY OF WATER";
380  INPUT Q
390  PRINT 
400  LET D1=2
410  LET N=.75
420  REM
430  REM
440  GOTO Q OF 460,480,500,520
450  GOTO 370
460  LET C=.4
470  GOTO 530
480  LET C=1
490  GOTO 530
500  LET C=1.5
510  GOTO 530
520  LET C=3
530  PRINT "TEMPERATURE (FAHRENHEIT)";
540  INPUT T
550  PRINT 
560  IF T>90 THEN 1650
570  IF T <= 32 THEN 1670
580  IF T>50 THEN 610
590  LET X9=15-2*(T-32)/9
600  GOTO 620
610  LET X9=11-(T-50)/9
620  PRINT "WASTE";
630  INPUT Q
640  PRINT 
650  GOTO Q OF 670,690
660  GOTO 620
670  LET H=.25
680  GOTO 700
690  LET H=.75
700  PRINT "DUMPING RATE";
710  INPUT D2
720  PRINT 
730  IF ABS(D2-7)>7 THEN 1630
740  LET W1=D1/N
750  LET W2=0
760  LET X=X9-D1/C
770  LET T2=0
780  LET T9=0
790  LET K=0
800  LET T1=.1
810  LET W[1]=W1+W2
820  LET X[1]=X
830  LET M=31
840  PRINT "TREATMENT";
850  INPUT Q
860  PRINT 
870  GOTO Q+1 OF 920,910
880  IF Q <> 2 THEN 840
890  LET D2=.1*D2
900  GOTO 920
910  LET D2=.5*D2
920  PRINT 
930  PRINT 
940  FOR J=2 TO M
950  FOR I=1 TO 10
960  LET T9=T9+T1
970  LET X=X+T1*(C*(X9-X)-N*W1-H*W2)
980  IF X>0 THEN 1000
990  LET X=0
1000  LET W1=W1+T1*(D1-N*W1)
1010  LET W2=W2+T1*(D2-H*W2)
1020  IF X>5 THEN 1060
1030  LET K=K+1
1040  IF K>1 THEN 1060
1050  LET T2=INT(T9)
1060  NEXT I
1070  LET X[J]=X
1080  LET W[J]=W1+W2
1090  NEXT J
1100  PRINT "DO YOU WANT  A GRAPH(1), A TABLE(2), OR BOTH(3) ";
1110  INPUT Q
1120  PRINT 
1130  IF (Q-1)*(Q-2)*(Q-3) <> 0 THEN 1100
1140  PRINT 
1150  PRINT 
1160  IF K<1 THEN 1200
1170  PRINT 
1180  PRINT "AFTER DAY   "T2"THE FISH BEGIN TO DIE, BECAUSE"
1190  PRINT "THE OXYGEN CONTENT OF THE WATER DROPPED BELOW 5 PPM."
1200  PRINT 
1210  IF Q<2 THEN 1300
1220  PRINT 
1230  PRINT "TIME","OXY. CONTENT","WASTE CONTENT"
1240  PRINT "DAYS","     PPM    ","     PPM     "
1250  PRINT "----","------------","-------------"
1260  FOR J=1 TO M
1270  PRINT J-1,INT(100*X[J]+.5)/100,INT(100*W[J]+.5)/100
1280  NEXT J
1290  IF Q=2 THEN 1570
1300  PRINT 
1310  PRINT "       0...OXYGEN-SCALE....5...OXYGEN-SCALE...10";
1320  PRINT "...OXYGEN-SCALE...15"
1330  PRINT "       0..WASTE.10..SCALE.20..WASTE.30..SCALE.40";
1340  PRINT "..WASTE.50..SCALE.60"
1350  PRINT "DAY    ";
1360  PRINT "I";
1370  FOR J=1 TO 6
1380  PRINT "---------I";
1390  NEXT J
1400  PRINT 
1410  FOR J=1 TO M
1420  PRINT J-1;TAB(6);"I";
1430  IF 4*X[J]>W[J] THEN 1460
1440  PRINT TAB(7+INT(4*X[J]+.5));"0";TAB(7+INT(W[J]+.5));"W"
1450  GOTO 1470
1460  PRINT TAB(7+INT(W[J]+.5));"W";TAB(7+INT(4*X[J]+.5));"O"
1470  IF J<5 THEN 1530
1480  FOR K=1 TO 4
1490  IF INT(W[J]+.5) <> INT(W[J+K]+.5) THEN 1530
1500  IF INT(4*W[J]+.5) <> INT(4*W[J-K]+.5) THEN 1530
1510  NEXT K
1520  GOTO 1540
1530  NEXT J
1540  PRINT 
1550  PRINT "THE WASTE CONTENT AND OXYGEN CONTENT WILL REMAIN AT"
1560  PRINT "THESE LEVELS UNTIL ONE OF THE VARIABLES CHANGES."
1570  PRINT 
1580  PRINT "ANOTHER RUN (1=YES, 0=NO)";
1590  INPUT Q
1600  PRINT 
1610  IF Q <> 0 THEN 1580
1615  CHAIN R,"*HELP"
1620  SYSTEM X,"BYE"
1630  PRINT "NEW YORK POLLUTES AT 14 PPM. TRY A RATE FROM 1 TO 14."
1640  GOTO 700
1650  PRINT "TEMPERATURE DESTROYS ALL LIFE. TRY NEW TEMPERATURE."
1660  GOTO 530
1670  PRINT "BODY OF WATER IS ICE. TRY NEW TEMPERATURE."
1680  GOTO 530
1690  END 
