1  REM  ****  HP BASIC PROGRAM LIBRARY  *******************************
2  REM
3  REM        MANDS:   CALCULATES BASIC STATISTICS FOR GROUPED 
4  REM                 AND/OR UNGROUPED DATA
5  REM        36748 REV  A   10/73
6  REM
7  REM  ****  CONTRIBUTED PROGRAM  ************************************
10  DATA 8,1,5,4,2,6,7,4,7,0,4,5,1,3,4,6,7,2,11
255  DIM A$[10]
260  PRINT "DO YOU WANT INSTRUCTIONS";
265  INPUT A$
270  IF A$[1,1]="Y" THEN 565
300  LET H=0
305  PRINT 
310  PRINT 
315  PRINT "ARITHMETIC MEAN, VARIANCE, AND"
320  PRINT "      STANDARD DEVIATION"
325  PRINT 
330  READ C
335  LET H=H+1
340  IF C=9.E+35 THEN 795
345  LET S1=0
350  LET S2=0
355  IF C <> 0 THEN 435
360  PRINT 
365  PRINT "FOR GROUPED DATA SET";H
370  PRINT 
375  READ Q
380  LET N=0
385  PRINT "X-VALUE","FREQUENCY"
390  PRINT 
395  FOR P=1 TO Q
400  READ X,M
405  LET N=N+M
410  LET S1=S1+M*X
415  LET S2=S2+M*X*X
420  PRINT X,M
425  NEXT P
430  GOTO 500
435  PRINT 
440  PRINT 
445  PRINT "INDIVIDUAL SET NUMBER";H
450  PRINT 
455  PRINT "INPUT VALUES:  ";
460  LET N=C
465  FOR P=1 TO N
470  READ X
475  LET S1=S1+X
480  LET S2=S2+X*X
485  PRINT X;
490  NEXT P
495  PRINT 
500  LET A=S1/N
505  LET V=(S2-A*S1)/N
510  LET V1=V*N/(N-1)
512  LET V2=V1/N
514  LET V3=SQR(V2)
515  LET D=SQR(V1)
520  PRINT 
525  PRINT "      NUMBER OF VALUES = ";N
530  PRINT "       ARITHMETIC MEAN = ";A
535  PRINT "    STANDARD DEVIATION = ";D
540  PRINT "       SAMPLE VARIANCE = ";V
545  PRINT "     EST TRUE VARIANCE = ";V1
546  PRINT "         ST ERROR MEAN = ";V3
550  PRINT 
555  PRINT 
560  GOTO 330
565  PRINT 
570  PRINT "THIS PROGRAM CALCULATES THE MEAN, VARIANCE, AND STANDARD"
575  PRINT "DEVIATION FOR EACH OF SEVERAL SETS OF INDIVIDUAL VALUES"
580  PRINT "OR FREQUENCY DISTRIBUTIONS."
585  PRINT 
590  PRINT "DATA FOR EACH SET OF INDIVIDUAL VALUES IS ENTERED INTO"
595  PRINT "THE PROGRAM AS FOLLOWS:"
600  PRINT 
605  PRINT "   1 DATA  N, X(1), X(2), X(3),....., X(N)"
610  PRINT 
615  PRINT "WHERE THE N VALUES OF THE SET ARE X(1) THRU X(N).  IF"
620  PRINT "NEEDED, ADDITIONAL DATA STATEMENTS MAY BE USED TO GIVE"
625  PRINT "THE ENTIRE LIST OF VALUES.   ADDITIONAL CASES MAY BE"
630  PRINT "GIVEN IN SUBSEQUENT DATA STATEMENTS IN THE SAME FORMAT."
635  PRINT 
640  PRINT "THE INPUT FOR GROUPED VALUES HAS THE FOLLOWING FORMAT:"
645  PRINT 
650  PRINT "   1 DATA 0, N, X(1), F(1), X(2), F(2),..., X(N), F(N)"
655  PRINT 
660  PRINT "WHERE THE INITIAL ZERO SIGNALS GROUPED DATA, THE N IS"
665  PRINT "THE NUMBER OF DIFFERENT VALUES TO BE GIVEN, AND THE F(I)"
670  PRINT "ARE THE NUMBER OF TIMES THE X(I) OCCUR.  DATA STATEMENTS"
675  PRINT "FOLLOWING MAY BE USED TO EXTEND THE LIST AS NECESSARY,"
680  PRINT "AND BLOCKS OF GROUPED DATA MAY BE INTERMIXED FREELY"
685  PRINT "WITH STRAIGHT LISTS DESCRIBED ABOVE."
690  PRINT 
695  PRINT "AS AN EXAMPLE, SUPPOSE WE WERE INTERESTED IN THE MEAN"
700  PRINT "AND STANDARD DEVIATION OF THE NUMBERS 1,5,4,2,6,7,4,7"
705  PRINT "AND ALSO FOR THE DISTRIBUTION CONSISTING OF 5-1'S,"
710  PRINT "3-4'S, 6-7'S, AND 2-11'S.  THESE TWO CASES COULD BE RUN"
715  PRINT "BY TYPING THE FOLLOWING:"
720  PRINT 
725  PRINT "   1 DATA 8,1,5,4,2"
730  PRINT "   2 DATA 6,7,4,7"
735  PRINT "   3 DATA 0,4,5,1,3,4"
740  PRINT "   4 DATA 6,7,2,11"
745  PRINT "   RUN"
750  PRINT 
755  PRINT "OR EQIVALENTLY:"
760  PRINT 
765  PRINT "   1 DATA 8,1,5,4,2,6,7,4,7,0,4,5,1,3,4,6,7,2,11"
770  PRINT "   RUN"
775  PRINT 
780  PRINT "NOTE THAT STATEMENT NUMBERS 1 THRU 250 ARE AVAILABLE"
785  PRINT "FOR CONTINUATION OF THE DATA FIELD."
790  DATA 9.E+35
795  END 
