1  REM  ****  HP BASIC PROGRAM LIBRARY  *******************************
2  REM
3  REM        STAT17:   COMPUTES AN ANALYSIS OF VARIANCE TABLE FOR A
4  REM                  BALANCED INCOMPLETE BLOCK DESIGN
5  REM        36728 REV  A   10/73
6  REM
7  REM  ****  CONTRIBUTED PROGRAM  ************************************
9000  REM  STAT17--ANALYSIS OF VARIANCE, BALANCED INCOMPLETE BLOCK
9002  PRINT "ANALYSIS OF VARIANCE TABLE"
9004  PRINT 
9006  PRINT "ITEM","SUM-SQR","DEG. FREE.","MEAN-SQR"
9008  PRINT 
9010  READ B,T,K,R
9012  LET L=R*(K-1)/(T-1)
9014  LET L1=INT(L)
9016  FOR I=1 TO B
9018  FOR J=1 TO T
9020  READ N[I,J]
9022  LET Q[J]=0
9024  LET P[J]=0
9026  LET S[J]=0
9028  NEXT J
9030  LET G[I]=0
9032  NEXT I
9034  LET A3=0
9036  LET U=0
9038  FOR I=1 TO B
9040  FOR J=1 TO T
9042  READ X[I,J]
9044  LET A3=A3+X[I,J]^2
9046  LET U=U+X[I,J]
9048  LET G[I]=G[I]+X[I,J]
9050  NEXT J
9052  NEXT I
9054  FOR J=1 TO T
9056  FOR I=1 TO B
9058  LET S[J]=S[J]+X[I,J]
9060  LET P[J]=P[J]+N[I,J]*G[I]
9062  NEXT I
9064  NEXT J
9066  LET C=(U^2)/B/K
9068  LET W=0
9070  FOR J=1 TO T
9072  LET Q[J]=K*S[J]-P[J]
9074  LET W=W+Q[J]^2
9076  NEXT J
9078  LET A=W/K/T/L
9080  LET W1=0
9082  FOR I=1 TO B
9084  LET W1=W1+G[I]^2
9086  NEXT I
9088  LET A1=(W1/K)-C
9090  LET A2=A3-A1-A-C
9092  LET D=B*K-(B-1)-(T-1)-1
9094  PRINT "GRAND TOTAL",A3,B*K
9096  PRINT "GRAND MEAN",C," 1"
9098  PRINT "TREATMENTS",A,T-1,A/(T-1)
9100  PRINT "BLOCKS",A1,B-1" ...BLOCK MEAN-SQR NOT ADJUSTED..."
9102  PRINT "ERROR",A2,D,A2/D
9104  PRINT 
9106  PRINT 
9108  LET F=A*D/(T-1)/A2
9110  PRINT "F-RATIO ="F", ON"T-1"AND"D"DEGREES OF FREEDOM."
9112  STOP 
9900  DATA 4,4,3,3
9901  DATA 1,0,1,1
9902  DATA 0,1,1,1
9903  DATA 1,1,1,0
9904  DATA 1,1,0,1
9905  DATA 2,0,20,7
9906  DATA 0,32,14,3
9907  DATA 4,13,31,0
9908  DATA 0,23,0,11
9998  PRINT "YOUR EXPERIMENT IS NOT BALANCED"
9999  END 
