5  COM R$[72],G$[72],X$[72]
10  REM**CL1-2**BASIC C.A.I.**GEOGRAPHY**JUNE 7, 1972**CHAIN TO CL1-1
20  REM CLIMAT, HP 36760A, 6/74
30  FILES SCRA
40  DIM Z$[72],S$[72]
50  PRINT "NOW BACK TO THE ORIGINAL PROBLEM; OUR STATION IS:"
60  PRINT "     NORTHERN HEMISPHERE"
70  PRINT "     UPPER MID-LATITUDES"
80  PRINT 
90  PRINT "FROM YOUR KNOWLEDGE OF THE WORLD MAP YOU KNOW THAT A LARGE"
100  PRINT "CONTINENT IS INVOLVED."
110  PRINT "     PLEASE COMMENT ON THE RELATIVE LOCATION ON THIS CONTINENT"
120  PRINT "     OF OUR STATION"
130  INPUT G$
140  PRINT 
150  J=10
160  GOSUB 2390
170  IF F#1 THEN 190
180  GOSUB 1690
190  J=13
200  GOSUB 2390
210  IF F=1 THEN 460
220  J=16
230  GOSUB 2390
240  IF F=1 THEN 350
250  J=14
260  GOSUB 2390
270  IF F=1 THEN 420
280  J=15
290  GOSUB 2390
300  IF F=1 THEN 380
310  PRINT "YOUR ANSWER SHOULD TELL ME WHETHER THE STATION IS NEAR OCEANIC"
320  PRINT "INFLUENCE OR IN THE INTERIOR OF THE LAND MASS AND, IF NEAR THE"
330  PRINT "COAST, WHICH COAST";
340  GOTO 130
350  PRINT " TOUCHE - MARINE INFLUENCE IS INDICATED BY THE RAINFALL PATTERN"
360  PRINT "HOWEVER, YOU FORGOT TO TELL ME WHICH COAST"
370  GOTO 130
380  PRINT "IN A CONTINENTAL INTERIOR THE TEMP. RANGE WOULD BE EVEN GREATER"
390  PRINT "THAN AT OUR STATION AND THE RAIN WOULD BE LESS AND NOT SO EVEN"
400  PRINT "IN ITS DISTRIBUTION. MAYBE WITH A STRONG SUMMER MAX. TRY AGAIN"
410  GOTO 130
420  PRINT "AT A WEST COAST LOCATION IN THE MID-LATITUDES THE RAINFALL"
430  PRINT "ALWAYS SHOWS A MARKED CONCENTRATION IN THE WINTER MONTHS"
440  PRINT "IS THIS THE CASE AT OUR STATION?  TRY AGAIN"
450  GOTO 130
460  PRINT "EXCELLENT, ";X$;". I ASSUME YOU CHOSE AN EAST COAST LOCATION"
470  PRINT "BECAUSE OF THE FAIRLY HIGH RAINFALL AND ITS EVEN DISTRIBUTION"
480  PRINT "FROM SEASON TO SEASON."
490  PRINT 
500  PRINT "AS YOU STUDY THE MAP YOU WILL REALIZE THAT YOU HAVE LIMITED"
510  PRINT "THE POSSIBLE LOCATION OF OUR STATION TO NORTHEASTERN NORTH"
520  PRINT "AMERICA OR NORTHEASTERN ASIA.  WHICH OF THESE IS CORRECT"
530  INPUT G$
540  PRINT 
550  J=25
560  GOSUB 2390
570  IF F=1 THEN 630
580  PRINT "WELL, EASTERN ASIA IS CHARACTERIZED BY A MONSOON RHYTHM IN THE"
590  PRINT "RAINFALL. WINTERS ARE DRY AND SUMMERS VERY MOIST. FOR EXAMPLE"
600  PRINT "VLADIVOSTOK (AT ABOUT THE LAT. OF OUR STATION) HAS A JAN."
610  PRINT "AVERAGE OF 0.3 INCHES AND JULY AVERAGE OF 3.3 INCHES. TRY AGAIN"
620  GOTO 530
630  PRINT "I ASSUME THAT YOU CHOSE NORTH AMERICA BECAUSE OF THE LACK OF"
640  PRINT "MONSOON RHYTHM IN THE RAINFALL PATTERN. IF I'M RIGHT,";X$
650  PRINT "YOU ARE DOING BRILLIANTLY."
660  PRINT 
670  PRINT "NOW LET'S TRY GETTING THE CORRECT KOPPEN CLASSIFICATION"
680  PRINT "FOR THE STATION THE DATA FOR WHICH APPEARED ABOVE"
690  PRINT "IS THE STATION HUMID OR ARID"
700  INPUT G$
710  PRINT 
720  J=17
730  GOSUB 2390
740  IF F=1 THEN 780
750  PRINT "WITH 35 INCHES OF RAIN AND QUITE LOW TEMPS. THE ENVIRONMENT"
760  PRINT "AT OUR STATION CAN NOT BE CLASSED AS ARID"
770  PRINT 
780  PRINT "HUMID CLIMATES (IN THE KOPPEN SYSTEM) ARE:"
790  PRINT "   'A' (ALL MONTHS ABOVE 64.4 F.)"
800  PRINT "   'C' (ALL MONTHS WARMER THAN 26.6 F.)"
810  PRINT "   'D' (AT LEAST ONE MONTH BELOW 26.6 F.)"
820  PRINT "   'E' (ALL MONTHS 50 F. OR COLDER)"
830  PRINT 
840  PRINT "WHCIH IS THE CORRECT FIRST LETTER IN THIS CASE";
850  INPUT G$
860  PRINT 
870  IF G$[1,1]="D" THEN 910
880  PRINT "PLEASE STUDY THE LIST AND THE TEMPERATURE DATA FOR OUR STATION"
890  PRINT "- THEN TYPE THE CORRECT FIRST LETTER."
900  GOTO 850
910  PRINT "GOOD - CLEARLY OUR STATION HAS A SEVERE WINTER WITH TEMPS."
920  PRINT "WELL BELOW 26.6 DEGREES BUT WITH SUMMER TEMPS. ABOVE 50 F."
930  PRINT 
940  PRINT "SECOND LETTER CHOICES REFER TO THE RAINFALL PATTERN:"
950  PRINT "       'S' (SUMMER DROUGHT)"
960  PRINT "       'W' (WINTER DROUGHT)"
970  PRINT "       'F' (HUMID ALL YEAR WITH NO MARKED DROUGHT)"
980  PRINT 
990  PRINT "WHICH OF THESE CHOICES BEST FITS OUR STATION";
1000  INPUT G$
1010  PRINT 
1020  IF G$[1,1]="F" THEN 1060
1030  PRINT "SORRY, ";X$;", PLEASE STUDY THE CHOICES AGAIN, CHECK THE "
1040  PRINT "DATA AND TRY ONCE AGAIN."
1050  GOTO 1000
1060  PRINT "FINE, ";X$;" - YOU CHOSE 'F' BECAUSE OF THE VERY EVEN"
1070  PRINT "DISTRIBUTION OF THE RAINFALL AND THE LACK OF A MARKED DRY SEASON"
1080  PRINT 
1090  PRINT "THIRD LETTER CHOICES REFER TO TEMPERATURE EXTREMES:"
1100  PRINT "THIRD LETTER POSSIBILITIES FOR 'D' CLIMATES ARE:"
1110  PRINT "      'A' (AT LEAST ONE MONTH WARMER THAN 71.6 F.)"
1120  PRINT "      'B' (>3 MONTHS WARMER THAN 50 F. NONE ABOVE 71.6 F.)"
1130  PRINT "      'C' (<4 MONTHS WARMER THAN 50 F.)"
1140  PRINT "      'D' (AT LEAST I MONTH COLDER THAN -36.4 F.)"
1150  PRINT 
1160  PRINT "WHICH OF THESE IS MOST APPROPRIATE";
1170  INPUT G$
1180  PRINT 
1190  IF G$[1,1]="B" THEN 1230
1200  PRINT "      PLEASE, ONLY THE APPROPIATE LETTER!"
1210  PRINT "PLEASE STUDY THE DATA AND THE DEFINITIONS AGAIN."
1220  GOTO 1170
1230  PRINT "EXCELLENT,JULY, THE WARMEST MONTH,IS COOLER THAN 71.6 F. AND"
1240  PRINT "THERE ARE MORE THAN THREE MONTHS WARMER THAN 50 F."
1250  PRINT 
1260  PRINT "NOW, ";X$;" , YOU KNOW THE CLIMATE IS  'DFB'"
1270  PRINT "   YOU ALSO KNOW THAT THE LOCATION IS:"
1280  PRINT "        NORTHERN HEMISPHERE"
1290  PRINT "        UPPER MID-LATITUDES"
1300  PRINT "        NEAR THE EAST COAST    AND IN"
1310  PRINT "        NORTH AMERICA"
1320  PRINT 
1330  PRINT "NOW, ALL THAT IS LEFT IS TO NAME THE TOWN(OR CITY) AND THE"
1340  PRINT "STATE (OR PROVINCE)!"
1350  INPUT G$
1360  PRINT 
1370  J=10
1380  GOSUB 2390
1390  IF F#1 THEN 1410
1400  GOSUB 1690
1410  J=18
1420  GOSUB 2390
1430  F1=F
1440  J=19
1450  GOSUB 2390
1460  IF F1+F=2 THEN 1680
1470  FOR J=19 TO 26
1480  IF J=25 THEN 1520
1490  GOSUB 2390
1500  IF F#1 THEN 1520
1510  GOTO J-18 OF 1660,1650,1640,1620,1580,1670,1560,1560
1520  NEXT J
1530  PRINT "REVIEW WHAT YOU KNOW ABOUT THE LOCATION OF THE STATION AND"
1540  PRINT "MAKE A MORE REASONABLE GUESS."
1550  GOTO 1350
1560  PRINT "SORRY, CANADA IS NOT A CORRECT PROVINCE NAME. START AGAIN."
1570  GOTO 1350
1580  PRINT "WELL, MY MAP SAYS THAT YOUR GUESS IS NOT BAD - BUT JULY"
1590  PRINT "TEMPS. AT ";G$;" WOULD BE A BIT COOLER"
1600  PRINT "THAN AT OUR STATION.  MOVE SOUTH."
1610  GOTO 1350
1620  PRINT "THE DATA LOOKS VERY MUCH LIKE ";G$
1630  CHAIN "$CL1-1",1450
1640  CHAIN "$CL1-1",1470
1650  CHAIN "$CL1-1",1510
1660  CHAIN "$CL1-1",1540
1670  CHAIN "$CL1-1",1570
1680  CHAIN "$CL1-1",1670
1690  PRINT '7'7'7'7'7'7'7'7'7;
1700  PRINT "   $%$%%$**$#    GOODNESS - SHAME ON YOU ! !! !!!"
1710  PRINT "WATCH YOUR LANGUAGE OR I'LL CUSS BACK AT YOU"
1720  PRINT 
1730  RETURN 
1740  DATA "DICTIONARY"
1750  DATA 2,10
1760  DATA "MID-LAT","MIDLAT","MIDDLE","HALF WAY","MID WAY","MIDWAY"
1770  DATA "MID-WAY","CENTRAL"
1780  DATA "FORTY","MID LAT"
1790  DATA 1,10
1800  DATA "QUERY","ASK","WHAT DO","DON'T KNOW","DONT KNOW"
1810  DATA "HOW","DON'T UNDER","DONT UNDER","HELP"
1820  DATA "KNOW HOW"
1830  DATA 3,7
1840  DATA "POLAR","POLE","NORTH","ARCTIC","FIFTY","SIXTY","SEVENTY"
1850  DATA 4,4
1860  DATA "POLE","NORTH","ARCTIC","POLAR"
1870  DATA 5,5
1880  DATA "EQUAT","SOUTH","LOW","TWENTY","THIRTY"
1890  DATA 6,8
1900  DATA "WARM","HOT","HIGH","VERTIC","DIRECT","OVERHEAD","OVER HEAD"
1910  DATA "ABOVE"
1920  DATA 7,3
1930  DATA "HALF","SIX MONTHS","SIXMONTHS"
1940  DATA 8,1
1950  DATA "OCT"
1960  DATA 11,1
1970  DATA "MARCH"
1980  DATA 13,3
1990  DATA "EAST","ATLANT","GULT STREAM"
2000  DATA 14,1
2010  DATA "WEST"
2020  DATA 15,6
2030  DATA "INTERIOR","REMOTE","FAR","INLAND","CONTINENTAL","CENTRAL"
2040  DATA 16,8
2050  DATA "COAST","SHORE","SEA","OCEAN","CURRENT","WATER"
2060  DATA "MARIT","MARINE"
2070  DATA 10,11
2080  DATA "HELL","SCREW","UCK","BALLS","SHIT","PISS","FART","CRAP"
2090  DATA "BITCH"
2100  DATA "GOD","DAM"
2110  DATA 9,1
2120  DATA "NORTH"
2130  DATA 12,6
2140  DATA "EAST","WEST","ORIENT","OCCIDENT","LAND","WATER"
2150  DATA 17,4
2160  DATA "HUMID","WET","MOIST","RAINY"
2170  DATA 18,1
2180  DATA "HANOVER"
2190  DATA 19,3
2200  DATA "NEW HAMP","N.H.","N. H."
2210  DATA 20,4
2220  DATA "MASS","CONN","R.I.","R. I."
2230  DATA 21,9
2240  DATA "NEW YORK","N.Y.","N. Y.","NEW JERSEY","N.J.","N. J.","PA."
2250  DATA "PENN"
2260  DATA "PA"
2270  DATA 22,2
2280  DATA "MAINE","ME."
2290  DATA 23,5
2300  DATA "QUEB","BRUNSW","N.B.","N. B.","NOVA"
2310  DATA 24,2
2320  DATA "VERMONT","VT"
2330  DATA 25,4
2340  DATA "AMERICA","N.A.","N. A.","AMERI"
2350  DATA 26,1
2360  DATA "CANADA"
2370  DATA 9999,0
2380  GOTO 2650
2390  RESTORE 
2400  READ Z$
2410  IF Z$#"DICTIONARY" THEN 2400
2420  READ T,N
2430  IF T=9999 THEN 2390
2440  READ #1,1
2450  FOR I=1 TO N
2460  READ R$
2470  IF T#J THEN 2490
2480  PRINT #1;R$, END 
2490  NEXT I
2500  IF T#J THEN 2420
2510  READ #1,1
2520  IF  END #1 THEN 2610
2530  READ #1;S$
2540  FOR L=1 TO LEN(G$)-LEN(S$)+1
2550  FOR K=1 TO LEN(S$)
2560  IF G$[L+K-1,L+K-1]#S$[K,K] THEN 2590
2570  NEXT K
2580  GOTO 2630
2590  NEXT L
2600  GOTO 2530
2610  F=0
2620  GOTO 2640
2630  F=1
2640  RETURN 
2650  END 
