10  COM X$[72],Z
20  REM**CL5-1**BASIC C.A.I.**GEOGRAPHY**CHAIN TO CL5-2**JUNE 20, 1972
25  REM CLIMAT, HP 36760A, 6/74
30  DIM R$[72],G$[72],S$[72]
40  FILES SCRA
50  PRINT "HELLO AND WELCOME TO THE 5TH LESSON ON CLIMATOLOGY"
60  PRINT 
70  PRINT "YOU KNOW WHO I AM BUT I DON'T KNOW WHO YOU ARE. WHAT MAY"
80  PRINT "I CALL YOU";
90  INPUT X$
100  PRINT 
110  PRINT "HELLO, ";X$;". I WILL GIVE YOU SOME INFORMATION AND THEN ASK"
120  PRINT "A QUESTION OR TWO. YOU RESPOND BRIEFLY AND IN YOUR OWN WORDS."
130  PRINT 
140  PRINT "IN THE FOLLOWING CLIMATE DATA MONTHLY AVERAGE TEMPERATURES"
150  PRINT "AND THE MONTHLY AVERAGE RAINFALL FOR A SPECIFIC STATION ARE"
160  PRINT "GIVEN IN FAHRENHEIT AND INCHES.  YOU WILL ANSWER A NUMBER OF"
170  PRINT "QUESTIONS ABOUT THIS STATION AND OTHER PLACES WITH SIMILAR"
180  PRINT "RAINFALL AND TEMPERATURE PATTERNS.  IF YOU ARE STUCK ON THE"
190  PRINT "ANSWER TO A QUESTION, JUST TELL ME OR ASK FOR HELP."
200  PRINT 
210  PRINT 
220  PRINT "  J., F.,  M.,  A.,  M.,  J.,  J.,  A.,  S.,  O.,  N.,  D."
230  PRINT 
240  PRINT "  74,  74,  70,  64,  58,  54,  52,  54,  57,  61,  67,  71"
250  PRINT " 0.7, 0.8, 1.0, 1.7, 2.7, 3.1, 2.6, 2.4, 2.1, 1.7, 1.1, 0.9"
260  PRINT 
270  PRINT 
280  PRINT "         YEARLY AVERAGE TEMP.  60.5 DEGREES F."
290  PRINT "         YEARLY RAINFALL TOTAL 20.8 INCHES"
300  PRINT 
310  PRINT "STUDY VERY CAREFULLY THE TEMPERATURE RANGE - NOTE THE MONTH"
320  PRINT "OF MINIMUM TEMP. AND THE PERIOD OF MAXIMUM TEMP.  NOTE"
330  PRINT "ALSO THE SEASONAL DISTRIBUTION OF RAINFALL.  THIS IS A REAL"
340  PRINT "PLACE, AT AN ELEVATION OF LESS THAN 500 FEET."
350  PRINT 
360  PRINT "DO YOU JUDGE THIS STATION TO BE NORTH OR SOUTH OF THE EQUATOR"
370  LET Z=0
380  INPUT G$
390  PRINT 
400  J=10
410  GOSUB 2040
420  IF F=1 THEN 440
430  GOTO 460
440  GOSUB 2300
450  PRINT 
460  J=9
470  GOSUB 2040
480  IF F=1 THEN 540
490  LET Z=Z+1
500  PRINT 
510  PRINT "THIS IS THE EASIEST OF ALL CLIMATE QUESTIONS.  LOOK AT THE"
520  PRINT "JAN. AND JULY TEMPERATURES. THIS SHOULD CLUE YOU. TRY AGAIN"
530  GOTO 380
540  PRINT "RIGHT - BUT THAT WASN'T HARD - NOW GIVE ME THE APPROXIMATE"
550  PRINT "LATITUDE OF THE STATION.   (PLEASE USE DIGITS ONLY)"
560  INPUT B
570  IF B=35 THEN 640
580  IF B<30 THEN 670
590  IF B>40 THEN 720
600  PRINT "YOU ARE IN THE BALL PARK - THE STATION IS INDEED BETWEEN 30"
610  PRINT "AND 40 SOUTH LAT.  IN THIS CASE IT IS AT ALMOST EXACTLY"
620  PRINT "35 DEGREES.  ";X$;", YOU ARE DOING WELL SO FAR."
630  GOTO 770
640  PRINT "YOU HIT IT ON THE HEAD, THIS STATION IS BISCETED BY THE PARALLEL"
650  PRINT "35 SOUTH.  EXCELLENT!!!!"
660  GOTO 770
670  PRINT "EQUATORWARD OF LAT. 30 I WOULD NOT EXPECT TO FIND A COMBINATION"
680  PRINT "OF COOL WINTERS AND WINTER CONCENTRATION OF RAINFALL.AGAIN"
690  LET Z=Z+1
700  GOSUB 1890
710  GOTO 560
720  PRINT "POLEWARD OF LAT. 40 I WOULD NOT EXPECT TO FIND SUCH DRY"
730  PRINT "SUMMERS AT A STATION WITH 21 INCHES OF RAINFALL. TRY AGAIN"
740  LET Z=Z+1
750  GOSUB 1890
760  GOTO 560
770  PRINT 
780  PRINT "WHICH OF THE FOLLOWING AMERICAN CITIES IS THE BEST ANALOGUE"
790  PRINT "TO THE STATION GIVEN ABOVE?"
800  PRINT "     ATLANTA, EL PASO, OR SANTA BARBARA"
810  INPUT G$
820  PRINT 
830  J=12
840  GOSUB 2040
850  IF F=1 THEN 1100
860  J=1
870  GOSUB 2040
880  IF F=1 THEN 1080
890  LET Z=Z+1
900  GOSUB 1890
910  J=13
920  GOSUB 2040
930  IF F=1 THEN 1020
940  J=14
950  GOSUB 2040
960  IF F=1 THEN 1050
970  PRINT "ONE OF THE CITIES LISTED IS AN APPROPIATE ANALOGUE. TYPE ITS"
980  PRINT "NAME CORRECTLY.  I WILL ASSUME POOR SPELLING AND NOT COUNT A"
990  PRINT "MISTAKE.  TRY AGAIN."
1000  LET Z=Z-1
1010  GOTO 810
1020  PRINT "EL PASO, IN A CONTINENTAL INTERIOR LOCATION, HAS FAR LESS"
1030  PRINT "RAINFALL AND A SUMMER MAXIMUM. TRY AGAIN."
1040  GOTO 810
1050  PRINT "ATLANTA, NEAR THE EAST COAST, HAS FAR MORE RAIN WITH EVEN"
1060  PRINT "DISTRIBUTION. TRY AGAIN."
1070  GOTO 810
1080  PRINT "ANALOGUE MEANS 'CORRESPONDS TO'. WHICH IS THE BEST MATCH?"
1090  GOTO 800
1100  PRINT "EXCELLENT, ";X$;", THIS IS CLEARLY A WEST COAST LOCATION."
1110  PRINT 
1120  PRINT "NOW, ";X$;", IF YOU WERE TO TAKE A SWIM IN THE OCEAN AT OUR "
1130  PRINT "STATION YOU WOULD DISCOVER THE WATER TEMPERATURE TO BE"
1140  PRINT "RELATIVELY           (FILL IN AN APPROPIATE WORD)"
1150  INPUT G$
1160  PRINT 
1170  J=11
1180  GOSUB 2040
1190  IF F=1 THEN 1320
1200  J=10
1210  GOSUB 2040
1220  IF F=1 THEN 1240
1230  GOTO 1260
1240  GOSUB 2300
1250  PRINT 
1260  PRINT "ONE OF THE CHARACTERISTICS OF THIS CLIMATE TYPE IS THAT THE"
1270  PRINT "ADJACENT OCEAN CURRENT IS COOL. THIS HELPS TO ACCOUNT FOR "
1280  PRINT "THE LOW SUMMER RAINFALL."
1290  LET Z=Z+1
1300  GOSUB 1890
1310  GOTO 1340
1320  PRINT "HOW RIGHT YOU ARE - THIS FACT HELPS TO ACCOUNT FOR THE LOW"
1330  PRINT "SUMMER RAINFALL."
1340  PRINT 
1350  PRINT "NOW, ";X$;", DURING THE WINTER SEASON (MAY, JUNE, JULY, AUG.)"
1360  PRINT "THE PREVAILING WIND AT OUR STATION IS FROM WHICH DIRECTION"
1370  INPUT G$
1380  PRINT 
1390  J=6
1400  GOSUB 2040
1410  IF F=1 THEN 1500
1420  PRINT "SORRY ";X$;", THINK ABOUT THE WIND AND PRESSURE DIAGRAM. FROM"
1430  PRINT "WHICH DIRECTION DOES THE WIND BLOW AT LATITUDE 35 "
1440  LET Z=Z+1
1450  GOSUB 1890
1460  PRINT 
1470  PRINT "BACK TO THE QUESTION OF WIND - FROM WHICH DIRECTION?"
1480  GOTO 1370
1490  PRINT 
1500  PRINT "YES, FROM WEST, NORTHWEST OR SOUTHWEST.  THIS IS THE QUITE"
1510  PRINT "WELL DEFINED BELT OF THE WESTERLIES."
1520  PRINT 
1530  PRINT "WITHIN THE WESTERLIES LOCAL LOW PRESSURE CENTERS MIGRATE FROM"
1540  PRINT "WEST TO EAST AND CAUSE PRECIPITATION.  THESE ARE KNOWN AS "
1550  INPUT G$
1560  PRINT 
1570  J=10
1580  GOSUB 2040
1590  IF F=1 THEN 1800
1600  J=7
1610  GOSUB 2040
1620  IF F=1 THEN 1820
1630  J=1
1640  GOSUB 2040
1650  IF F=1 THEN 1740
1660  J=8
1670  GOSUB 2040
1680  IF F=1 THEN 1770
1690  LET Z=Z+1
1700  GOSUB 1890
1710  PRINT "THE ANSWER I AM LOOKING FOR REFERS TO MID-LATITUDE DEPRESSIONS"
1720  PRINT "WITH WARM AND COLD FRONTS.  TRY AGAIN."
1730  GOTO 1550
1740  PRINT "A REGION OF LOW ATMOSPHERIC PRESSURE SOMETIMES CALLED A"
1750  PRINT "DEPRESSION IS MORE OFTEN KNOWN AS A (            )?"
1760  GOTO 1550
1770  PRINT "TOUCHE - A LOW PRESSURE CENTER IS OFTEN CALLED A LOW - BUT"
1780  PRINT "IS MORE PROPERLY KNOWN AS A 'CYCLONIC STORM'"
1790  GOTO 1830
1800  GOSUB 2300
1810  GOTO 1710
1820  PRINT "IT IS EASY TO SEE THAT YOU, ";X$;" KNOW YOUR CONTROLS"
1830  PRINT 
1840  PRINT "CYCLONIC STORMS ARE IMPORTANT DURING THE WINTER, BUT,"
1850  PRINT "BY CONTRAST, DURING THE SUMMER THE WIND IS LIGHT AND VARIABLE"
1860  PRINT "WITH A COMPONENT PARALLEL TO THE SHORE. THE PATHS OF CYCLONIC"
1870  PRINT "STORMS ARE THEN WELL POLEWARD OF THIS STATION."
1880  CHAIN "$CL5-2"
1890  PRINT 
1900  IF Z=2 THEN 1940
1910  IF Z=3 THEN 1980
1920  IF Z=4 THEN 2010
1930  IF Z<2 THEN 1970
1940  PRINT "THAT IS YOUR SECOND MISTAKE. IF YOU HAVE DONE THE FIRST FOUR"
1950  PRINT "LESSONS CAREFULLY AND HAVE COMPLETED THE READING, YOU SHOULD"
1960  PRINT "DO BETTER. KEEP TRYING."
1970  RETURN 
1980  PRINT "WOW! YOU THIRD MISTAKE! ONE MORE AND I WILL QUIT TRYING"
1990  PRINT "TO HELP YOU. TRY AGAIN BUT BE CAREFUL."
2000  RETURN 
2010  PRINT "TOO BAD - YOUR FOURTH MISTAKE - I QUIT!  YOU BETTER START"
2020  PRINT "AGAIN WITH ONE OF THE EASIER LESSONS."
2030  STOP 
2040  RESTORE 
2050  READ R$
2060  IF R$#"DICTIONARY" THEN 2050
2070  READ T,N
2080  IF T=9999 THEN 2040
2090  READ #1,1
2100  FOR I=1 TO N
2110  READ R$
2120  IF T#J THEN 2140
2130  PRINT #1;R$, END 
2140  NEXT I
2150  IF T#J THEN 2070
2160  READ #1,1
2170  IF  END #1 THEN 2260
2180  READ #1;S$
2190  FOR L=1 TO LEN(G$)-LEN(S$)+1
2200  FOR K=1 TO LEN(S$)
2210  IF G$[L+K-1,L+K-1]#S$[K,K] THEN 2240
2220  NEXT K
2230  GOTO 2280
2240  NEXT L
2250  GOTO 2180
2260  F=0
2270  GOTO 2290
2280  F=1
2290  RETURN 
2300  PRINT 
2310  PRINT "   $%&%%$**#$#   GOODNESS - SHAME ON YOU ! !! !!!"
2320  PRINT "WATCH YOUR LANGUAGE OR I'LL CUSS BACK AT YOUR"
2330  RETURN 
2340  PRINT 
2350  PRINT "I AM SORRY BUT I DON'T UNDERSTAND YOUR ANSWER. HAVE YOU"
2360  PRINT "MISSPELLED AN IMPT. WORD? PLEAS CHECK AND REPHRASE YOUR"
2370  PRINT "ANSWER."
2380  RETURN 
2390  DATA "DICTIONARY"
2400  DATA 1,10
2410  DATA "QUERY","ASK","WHAT DO","KNOW HOW","DONT KNOW","DON'T KNOW"
2420  DATA "HOW","DON'T UNDER","DONT UNDER","HELP"
2430  DATA 6,2
2440  DATA "WESTERLY","WEST"
2450  DATA 7,3
2460  DATA "DEPRESS","CYCLO","FRONT"
2470  DATA 8,1
2480  DATA "LOW"
2490  DATA 9,1
2500  DATA "SOUTH"
2510  DATA 10,10
2520  DATA "HELL","SCREW","UCK","BASTA","BITCH","SHIT","BALLS","FART"
2530  DATA "PISS","CRAP"
2540  DATA 11,6
2550  DATA "COOL","COLD","BRISK","FRIGID","ICY","CHILLY"
2560  DATA 12,3
2570  DATA "SANTA BARBARA","STA","CALFORN"
2580  DATA 13,3
2590  DATA "PASO","PASSO","PAASO"
2600  DATA 14,2
2610  DATA "ATLANTA","ALTANTA"
2620  DATA 9999,0
2630  END 
