1  REM  ****  HP BASIC PROGRAM LIBRARY  *******************************
2  REM
3  REM        MOLAR:   ACID-BASE TITRATION
4  REM
5  REM        36616 REV  A   6/73
6  REM
7  REM  ****  CONTRIBUTED PROGRAM  ************************************
50  REM MOLAR - COPYRIGHT 1971, POLYTECHNIC INSTITUTE OF BROOKLYN
100  REM HARRY DORFMAN 7/16/68 JOHN GLENN H.S. ( REV. 7/10/69 ) 
105  REM  REVISED BY C.LOSIK  7-23-70 
110  PRINT "THIS PROGRAM IS DESIGNED TO CALCULATE THE UNKNOWN MOLARITY"
120  PRINT "IN AN ACID-BASE TITRATION."
130  PRINT 
140  PRINT 
150  PRINT " WHAT IS THE SUBSCRIPT OF THE H+ IN THE ACID FORMULA,"
160  PRINT " AND THE SUBSCRIPT OF THE OH- IN THE BASE FORMULA";
165  REM  D,C= # OF H+,  # OF OH- 
170  INPUT D,C
180  PRINT 
190  PRINT " HOW MANY ML OF ACID, AND HOW MANY ML OF BASE"
200  PRINT " WERE USED";
205  REM  E,F= ML ACID, ML BASE 
210  INPUT E,F
220  PRINT 
230  PRINT " IS THE KNOWN MOLARITY FOR THE ACID OR THE BASE?"
240  PRINT " ANSWER 1 FOR ACID OR 2 FOR BASE";
250  INPUT Z
260  PRINT 
270  IF Z=2 THEN 360
280  IF Z <> 1 THEN 240
290  PRINT " WHAT IS THE MOLARITY OF THE ACID";
300  INPUT A
310  LET B=(E*A*D)/(C*F)
320  PRINT 
330  PRINT 
340  PRINT " ANSWER: THE BASE IS "INT(100*B+.5)/100"M."
350  GOTO 420
360  PRINT " WHAT IS THE MOLARITY OF THE BASE";
370  INPUT B
380  LET A=(C*F*B)/(D*E)
390  PRINT 
400  PRINT 
410  PRINT " ANSWER: THE ACID IS "INT(100*A+.5)/100"M."
420  PRINT 
430  PRINT 
440  PRINT " DO YOU WANT TO WORK ANOTHER PROBLEM?  ANSWER 1 FOR YES"
450  PRINT " OR 0 FOR NO";
460  INPUT X
462  PRINT 
464  PRINT " ***************"
470  IF X=1 THEN 130
480  IF X <> 0 THEN 430
490  END 
