10  REM ****  HP TIME-SHARED BASIC PROGRAM LIBRARY  *******************
20  REM
30  REM          NZYM2:  ENZYME REACTION RATE
40  REM
50  REM          36304  (A833)  REV A -- 10/71
60  REM
70  REM ****  CONTRIBUTED PROGRAM  ***********************************
80  REM  NZYM2--COPYRIGHT 1970-- POLYTECHNIC INSTITUTE OF BROOKLYN
90  REM W. BLESSER, POLYTECH. INST. OF BKLYN. 
100  REM  REVISED BY C.LOSIK  7-16-70 
110  REM  A=PH, K=ENZ. CONC., T=TEMP
120  REM  FOR EFFICIENCY, ALL CALCULATIONS DONE VIA GOSUB CALLS 
130  PRINT "THIS PROGRAM WILL ENABLE YOU TO SEE THE EFFECTS ON THE RATE OF"
140  PRINT "REACTION WITHIN A SYSTEM CONTROLLED BY ENZYMES.  THE"
150  PRINT "REACTION RATE WILL VARY AS THE ENVIRONMENTAL CONDITIONS"
160  PRINT "VARY.  THESE CONDITIONS, PH, CONCENTRATION OF ENZYMES,"
170  PRINT "AND TEMPERATURE, IN A NATURAL SITUATION ARE NEVER CONSTANT."
180  PRINT "LET'S SEE WHAT CONTROLS THIS RATE IN THESE SYSTEMS."
190  PRINT 
200  PRINT "THE FOLLOWING ARE THE LIMITS WITHIN WHICH EACH OF OUR"
210  PRINT "ENVIRONMENTAL CONDITIONS CAN VARY."
220  PRINT " ","1)PH----------BETWEEN 4 AND 10"
230  PRINT " ","2)ENZ. CONC.--BETWEEN 10 AND 100 PERCENT"
240  PRINT " ","3)TEMP.-------BETWEEN 5 AND 47 DEGREES C."
250  GOSUB 1370
260  GOSUB 1060
270  PRINT 
280  PRINT "NOTE THE REACTION RATE WITH THE THREE VALUES WHICH YOU"
290  PRINT "SELECTED TO PROVIDE A BASIS FOR JUDGEMENT OF REACTION"
300  PRINT "RATE, CHOOSE ANOTHER SET OF VALUES FOR PH, CONC., AND"
310  PRINT "TEMP.  (SEE LIMITS ABOVE)."
320  PRINT 
330  GOSUB 1060
340  PRINT "IS THE RESULT A HIGHER OR LOWER REACTION RATE?  IS THE HIGHEST"
350  PRINT "VALUE OBTAINED A MAXIMUM VALUE?  DO YOU WANT TO TRY ANOTHER"
360  PRINT "SET OF VALUES (TYPE '1') OR WOULD YOU PREFER A MORE ORGANIZED"
370  PRINT "APPROACH TO DETERMINE MAXIMUM REACTION RATE (TYPE '2')"
380  INPUT X
390  IF X=2 THEN 460
400  IF X=1 THEN 430
410  PRINT "PLEASE TYPE 1 OR 2"
420  GOTO 380
430  PRINT "WHAT ARE YOUR NEW VALUES FOR PH, CONC., AND TEMP.";
440  GOSUB 1060
450  GOTO 340
460  PRINT 
470  PRINT "WE ARE NOW GOING TO PERFORM AN EXPERIMENT IN WHICH YOU ARE"
480  PRINT "TO TYPE IN THE VALUES FOR PH, CONC. AND TEMP. AS YOU DID"
490  PRINT "BEFORE. HOWEVER,NOW YOU ARE GOING TO BE ABLE TO CHOOSE THE"
500  PRINT "FACTOR WHICH WILL VARY. THE OTHER TWO FACTORS WILL REMAIN"
510  PRINT "CONSTANT. (USE DIFFERENT NUMERICAL VALUES FOR EACH FACTOR.)"
520  PRINT "TO OBTAIN THE MOST SIGNIFICANT DATA, START THE EXPERIMENT"
530  PRINT "USING LOW NUMERICAL VALUES FOR EACH FACTOR."
540  LET M=0
550  GOSUB 1370
560  GOSUB 1130
570  PRINT "TYPE THE NUMBER WHICH IS TO BE VARIED."
580  INPUT X
590  IF X=A THEN 720
600  IF X=K THEN 800
610  IF X=T THEN 640
620  PRINT "PLEASE TYPE THE VALUE FOR PH, CONC., OR TEMP.";
630  GOTO 580
640  GOSUB 1420
650  GOSUB 1260
660  GOSUB 1280
670  GOSUB 1300
680  GOSUB 1320
690  LET T=T+5
700  IF T >= 47 THEN 880
710  GOTO 670
720  GOSUB 1420
730  GOSUB 1280
740  GOSUB 1300
750  GOSUB 1260
760  GOSUB 1320
770  IF A>10 THEN 880
780  LET A=A+.5
790  GOTO 750
800  GOSUB 1420
810  GOSUB 1260
820  GOSUB 1300
830  GOSUB 1280
840  GOSUB 1320
850  LET K=K+10
860  IF K>100 THEN 880
870  GOTO 830
880  LET M=M+1
890  IF M >= 2 THEN 970
900  PRINT "YOU NOW HAVE A SET OF VALUES FOR REACTION RATE AS ONE OF"
910  PRINT "THE GOVERNING FACTORS IS VARIED AND THE OTHER TWO ARE HELD"
920  PRINT "CONSTANT. DOES THE REACTION RATE HAVE A MAXIMUM VALUE?"
930  PRINT "IS THIS THE MAXIMUM POSSIBLE REACTION RATE? TO DETERMINE THIS,"
940  PRINT "USE THE SAME INITIAL VALUE FOR THE VARYING FACTOR, BUT THIS"
950  PRINT "TIME TYPE IN DIFFERENT VALUES FOR THE CONSTANT FACTORS."
960  PRINT 
970  PRINT "IF YOU WANT ANOTHER SET OF VALUES FOR REACTION RATE,TYPE '1'"
980  PRINT "IF YOU ARE SATISFIED THAT YOU KNOW THE VALUES FOR EACH FACTOR'S"
990  PRINT "MAXIMUM REACTION RATE THEN TYPE '2'."
1000  INPUT B
1010  IF B=1 THEN 550
1020  IF B=2 THEN 1050
1030  PRINT "PLEASE TYPE 1 OR 2"
1040  GOTO 1000
1050  STOP 
1060  GOSUB 1130
1070  GOSUB 1260
1080  GOSUB 1280
1090  GOSUB 1300
1100  GOSUB 1420
1110  GOSUB 1320
1120  RETURN 
1130  INPUT A,K,T
1140  REM  INPUT AND CHECK BOUNDS
1150  IF A<4 THEN 1220
1160  IF A>10 THEN 1220
1170  IF K<10 THEN 1220
1180  IF K>100 THEN 1220
1190  IF T<5 THEN 1220
1200  IF T>47 THEN 1220
1210  GOTO 1250
1220  PRINT "AT LEAST ONE OF THE VARIABLES DOES NOT LIE WITHIN THE"
1230  PRINT "PRESCRIBED LIMITS. SEE LIMITS ABOVE AND TRY AGAIN."
1240  GOTO 1130
1250  RETURN 
1260  LET V1=EXP(-((.71*A-4.97)^2))
1270  RETURN 
1280  LET V2=EXP(-.08*K)-2*EXP(-.05*K)+1
1290  RETURN 
1300  LET V3=16.3*EXP(.074*T)-EXP(.133*T)
1310  RETURN 
1320  LET V=.88*V1*V2*V3
1330  LET V=INT(V*100+.5)/100
1340  PRINT A,K,T,V
1350  REM  PRINT REACTION RATE 
1360  RETURN 
1370  PRINT 
1380  PRINT "I AM GOING TO PRINT A '?'. YOU MUST THEN TYPE A NUMBER FOR PH,"
1390  PRINT "CONC., AND TEMP. (IN THAT ORDER), WHICH FALLS WITHIN EACH"
1400  PRINT "LIMIT STATED (SEE ABOVE.)"
1410  RETURN 
1420  PRINT "PH","CONC.","TEMP.","REACTION RATE"
1430  PRINT "--","-----","-----","-------- ----"
1440  RETURN 
1450  END 
