5  REM ORG1, HP 36826A, 6/74
10  DIM A$[30]
20  PRINT "THIS IS A PROGRAM FOR TEACHING YOU HOW TO NAME ORGANIC"
30  PRINT "CHEMICALS OF VARIOUS TYPES.  NOW SINCE I'VE TOLD YOU"
40  PRINT "WHAT THIS PROGRAM IS ABOUT, WHAT IS YOUR NAME?"
50  INPUT A$
60  PRINT "HELLO, ";A$;".  LET'S GET STARTED THEN."
70  PRINT 
80  PRINT "CARBON COMPOUNDS MAKE UP QUITE A LARGE PART OF OUR WORLD."
90  LET A=0
100  PRINT "I (A COMPUTER) AM NOT MADE OF CARBON BUT YOU ARE, ";A$;"."
110  PRINT "THE CHEMISTRY OF CARBON COMPOUNDS IS CALLED 'ORGANIC CHEMISTRY'."
120  PRINT "ONE FACET OF THIS LARGE AREA OF STUDY IS 'HYDROCARBONS.'"
130  PRINT "HYDROCARBONS ARE CHEMICAL COMPOUNDS WHICH CONTAIN CARBON"
140  PRINT "AND HYDROGEN ATOMS ONLY."
150  PRINT "WHICH OF THE COMPOUNDS BELOW DO YOU THINK IS A HYDROCARBON?"
160  PRINT "(USE THE NUMBER OF YOUR CHOICE)"
170  PRINT 
180  IF A <> 0 THEN 270
190  PRINT "     1.            2.            3."
200  PRINT 
210  PRINT 
220  PRINT "   H H H        H H H H      H H   H"
230  PRINT "  HC-C-C-OH    HC-C-C-C-H   HC-C-O-CH"
240  PRINT "   H H H        H H H H      H H   H"
250  PRINT 
260  PRINT 
270  INPUT A
280  IF A=2 THEN 310
290  PRINT "NO THAT'S NOT CORRECT.  TRY AGAIN.    REMEMBER,"
300  GOTO 130
310  PRINT "THAT'S THE ONE.  YOU SAW THE OTHER TWO HAD OXYGEN IN THEM."
320  LET C=0
330  PRINT "HOW MANY CARBONS ARE THERE IN #1, #2, & #3";
340  INPUT B,B1,B2
350  LET C=C+1
360  IF B <> 3 THEN 400
370  IF B1 <> 4 THEN 400
380  IF B2 <> 3 THEN 400
390  GOTO 530
400  IF C=3 THEN 500
410  PRINT "NO, THAT'S NOT RIGHT.  YOU MISSED ";
420  IF B=3 THEN 440
430  PRINT "#1 ";
440  IF B1=4 THEN 460
450  PRINT "#2 ";
460  IF B2=3 THEN 480
470  PRINT "#3 ";
480  PRINT "COUNT AGAIN!"
490  GOTO 330
500  PRINT "THAT'S ALL THE CHANCES I CAN GIVE YOU."
510  PRINT "THE PROPER SEQUENCE IS '3,4,3'"
520  GOTO 540
530  PRINT "THAT'S RIGHT.  GOOD FOR YOU, ";A$;"!"
540  PRINT 
550  LET C=0
560  PRINT "A CERTAIN CLASS OF HYDROCARBONS IS CALLED"
570  PRINT "'THE ALKANE FAMILY.'  THEY ALL HAVE A CERTAIN RATIO OF"
580  PRINT "CARBON TO HYDROGEN SUCH THAT IF THERE ARE 'N' CARBONS,"
590  PRINT "THERE WILL BE 2N+2 HYDROGENS."
600  LET N=INT(RND(1)*5)+1
610  LET C=C+1
620  PRINT "HOW MANY HYDROGENS WOULD AN ALKANE OF";N;"CARBONS HAVE";
630  INPUT H
640  IF H=2*N+2 THEN 670
650  PRINT "NO, THAT'S NOT RIGHT. TRY AGAIN. REMEMBER: HYDROGENS=2N+2"
660  GOTO 620
670  PRINT "THAT'S THE ANSWER.";
680  IF C=4 THEN 710
690  PRINT " LET'S DO ANOTHER ONE.   NOW"
700  GOTO 600
710  PRINT 
720  PRINT "NOW YOU SHOULD LEARN HOW TO NAME HYDROCARBONS."
730  PRINT "ALL THE ALKANES END IN '-ANE.'  THE PREFIXES ARE AS FOLLOWS:"
740  PRINT 
750  PRINT " FOR ONE CARBON THE PREFIX IS'METH-'"
760  LET T=31
770  PRINT "     TWO";TAB(T);"'ETH-'"
780  PRINT "    THREE";TAB(T);"'PROP-'"
790  PRINT "     FOUR";TAB(T);"'BUT-'"
800  PRINT "     FIVE";TAB(T);"'PENT-'"
810  PRINT "     SIX";TAB(T)"'HEX-'"
820  PRINT 
830  PRINT "FOR EXAMPLE"
840  LET T=26
850  PRINT "      H";TAB(T);"H H"
860  PRINT "     HCH IS METHANE AND  HC-CH"
870  PRINT "      H";TAB(T);"H H"
880  PRINT 
890  PRINT TAB(T-5);"IS ETHANE."
900  PRINT 
910  PRINT "WHAT DO YOU THINK THIS COMPOUND IS:"
920  LET T=10
930  PRINT TAB(T);" H H H H"
940  PRINT TAB(T);"HC-C-C-CH"
950  PRINT TAB(T);" H H H H"
960  PRINT 
970  PRINT "   1. PROPANE?   2. BUTANE?   3. PENTANE?"
980  PRINT "(TYPE NUMBER OF YOUR ANSWER)";
990  INPUT A2
1000  IF A2=2 THEN 1090
1010  IF A2=1 THEN 1070
1020  IF A2=3 THEN 1050
1030  PRINT "YOU HAVE TO USE NUMBER 1,2, OR 3,  TRY AGAIN."
1040  GOTO 980
1050  PRINT "PENTANE HAS FIVE CARBONS.  TRY AGAIN."
1060  GOTO 980
1070  PRINT "PROPANE HAS THREE CARBONS.  COUNT AGAIN."
1080  GOTO 980
1090  PRINT "RIGHT!  BUTANE HAS FOUR CARBONS."
1100  LET C=0
1110  PRINT 
1120  PRINT "HERE ARE SOME MORE NAMES FOR NUMBERS OF CARBONS."
1130  PRINT "MOST OF THEM ARE GREEK SO THEY'RE A LITTLE WEIRD."
1140  PRINT 
1150  PRINT "  7 HEPT  10 DEC    13 TRISKEDEC  16 HEXADEC"
1160  PRINT "  8 OCT   11 UNDEC  14 TETRADEC   ............."
1170  PRINT "  9 NON   12 DODEC  15 PENTADEC   20 EICOS"
1180  PRINT 
1190  PRINT "HOW MANY CARBONS DO YOU THINK THERE ARE IN"
1200  PRINT "HEPTADECANE, OCTADECANE, AND NONADECANE? (USE COMMAS)";
1210  LET C=C+1
1220  INPUT A3,A4,A5
1230  IF A3 <> 17 THEN 1270
1240  IF A4 <> 18 THEN 1270
1250  IF A5 <> 19 THEN 1270
1260  GOTO 1330
1270  IF C=3 THEN 1310
1280  PRINT "THAT'S NOT RIGHT.  BUT HERE'S A CLUE*  'OCTADECANE'"
1290  PRINT "HAS 18 CARBONS.  TRY AGAIN."
1300  GOTO 1180
1310  PRINT "WRONG AGAIN.  WELL, THE CORRECT SEQUENCE IS 17,18,19."
1320  GOTO 1340
1330  PRINT "THAT'S RIGHT, ";A$;"."
1340  PRINT 
1350  PRINT 
1360  PRINT "WHEN YOU'RE READY FOR THE"
1370  PRINT "NEXT LESSON, TYPE 'GET-ORG2'."
1380  END 
