1  REM  ****  HP BASIC PROGRAM LIBRARY  *******************************
2  REM
3  REM        PHPOH:   PH,POH,PCT, DISSOCIATION
4  REM
5  REM        36617 REV  A   6/73
6  REM
7  REM  ****  CONTRIBUTED PROGRAM  ************************************
50  REM PHPOH - COPYRIGHT 1971, POLYTECHNIC INSTITUTE OF BROOKLYN
100  REM PHPOH*  JOHN MARCHISOTTO 7/10/69  CHEMISTRY BASIC
101  REM  REVISED BY C.LOSIK  7-22-70 
103  REM A IS THE KA, B IS THE MOLAR CONC.
110  REM  PROGRAM DOES ONE CALCULATION AT A TIME !
140  PRINT "THIS PROGRAM WILL FIND THE PH, POH, AND PCT DISSOCIATION"
150  PRINT "FOR ANY WEAK MONOPROTIC ACID."
170  PRINT 
180  PRINT "KA OF ACID =";
190  INPUT A
200  IF A <= .5 THEN 210
202  PRINT "ANSWER INVALID FOR WEAK ACID.  TRY AGAIN."
204  GOTO 190
210  PRINT " MOLAR CONCENTRATION OF ACID =";
220  INPUT B
230  PRINT 
240  LET S=A*B
250  IF S >= 1.E-12 THEN 280
260  LET H=SQR(S+1.E-14)
270  GOTO 290
280  LET H=-A/2+(SQR(A^2+(4*A*B)))/2
290  LET T=1.E-14/H
300  LET R=H-T
310  LET C=-LOG(H)/2.303
320  LET D=14-C
330  IF B<.00001 THEN 360
340  LET E=R/B*100
350  GOTO 370
360  LET E=100
370  PRINT "PH=";INT(100*C+.5)/100,"POH="INT(100*D+.5)/100;
380  PRINT TAB(35);"PCT. DISSOCIATION=";E
390  PRINT 
410  PRINT " ANY MORE PROBLEMS (1=YES, 0=NO)";
430  INPUT N
440  IF N=1 THEN 170
445  IF N <> 0 THEN 410
450  END 
