1  REM  ****  HP BASIC PROGRAM LIBRARY  *******************************
2  REM
3  REM        PRJTL:   PROJECTILE MOTION
4  REM
5  REM        36631 REV  A   6/73
6  REM
7  REM  ****  CONTRIBUTED PROGRAM  ************************************
50  REM PRJTL-COPYRIGHT 1970, POLYTECHNIC INSTITUTE OF BROOKLYN
100  REM J.CARACCIOLO, LONGWOOD H.S., 10-26-68,   BASIC 
101  REM REVISED 8/25/70 (C. LOSIK) 
110  REM PHYSICS      PROJECTILE MOTION 
120  PRINT "SUPPOSE YOU ARE GOING TO FIRE A PROJECTILE INTO THE AIR."
130  PRINT "IF YOU ENTER A VALUE FOR ANGLE OF ELEVATION AND INITIAL"
140  PRINT "VELOCITY, THE RANGE AND HEIGHT WILL BE EVALUATED.  ENTER"
150  PRINT "YOUR INFORMATION IN THE FORM A,V AFTER THE QUESTION MARK."
160  PRINT "(REMEMBER, THE ANGLE IS IN DEGREES AND THE INITIAL"
170  PRINT "VELOCITY IS IN METERS/SECOND.)"
180  PRINT 
190  PRINT 
200  PRINT "WHAT ARE YOUR VALUES";
220  INPUT A,V0
230  IF V0=0 THEN 690
240  IF A=0 THEN 690
250  IF V0<0 THEN 720
260  IF A<0 THEN 720
270  IF A >= 90 THEN 750
280  LET A=A*3.14159/180
290  LET K=V0*SIN(A)
300  LET L=V0*COS(A)
310  LET T=2*K/9.80665
320  LET R=2*K*L/9.80665
330  LET H=(K^2)/19.6133
340  PRINT 
350  PRINT 
360  PRINT "THE TOTAL FLIGHT TIME WAS";T;"SECONDS"
370  PRINT "THE RANGE WAS";R;"METERS"
380  PRINT "THE MAXIMUM HEIGHT WAS";H;"METERS"
390  PRINT 
393  PRINT "BECAUSE THERE IS NO FRICTION, THE HORIZONTAL VELOCITY IS"
396  PRINT "CONSTANT.  HORIZONTAL VELOCITY ="L
400  PRINT 
410  PRINT "   THE FOLLOWING ARE POINTS ON THE CURVE AT VARIOUS ";
420  PRINT "TIME INTERVALS:"
430  PRINT 
440  PRINT 
445  PRINT " "," "," "," VERTICAL "
450  PRINT " TIME "," X-COORD "," Y-COORD "," VELOCITY "," SPEED "
460  PRINT " ---- "," ------- "," ------- "," -------- "," ----- "
470  LET N=T/11
480  LET T1=T
490  FOR T=0 TO T1 STEP N
491  LET Q=K*T-4.90333*T^2
492  IF Q>0 THEN 495
493  LET Q=0
495  LET V1=K-9.80665*T
500  PRINT T,L*T,Q,V1,SQR(V1*V1+L*L)
510  NEXT T
520  IF ABS(A-.785398)<.00001 THEN 610
530  PRINT 
540  PRINT 
550  PRINT "THE ANGLE AT WHICH YOU FIRED THE PROJECTILE DOES NOT ";
560  PRINT "YIELD THE MAXIMUM RANGE.  WHAT ANGLE DOES";
580  INPUT A
590  LET A=A*3.14159/180
600  GOTO 520
610  PRINT 
620  PRINT "45 DEGREES GIVES THE MAXIMUM RANGE OF"2*(V0^2)*(.707^2)/9.8066
640  PRINT 
642  PRINT "WOULD YOU LIKE ANOTHER RUN WITH DIFFERENT A AND V?"
644  PRINT "(1=YES, 0=NO) : ";
645  INPUT V1
646  IF V1=0 THEN 780
648  IF V1 <> 1 THEN 644
649  PRINT 
650  PRINT "ENTER NEW VALUES FOR A,V AFTER THE QUESTION MARK."
660  GOTO 180
690  PRINT "  DON'T ENTER VALUES OF ZERO.";
700  GOTO 180
720  PRINT "  NO NEGATIVE VALUES.  PLEASE ENTER THEM CORRECTLY";
730  GOTO 180
750  PRINT "  GREAT SHOT.  YOU COULD KILL YOURSELF THAT WAY, YOU KNOW."
760  PRINT "  TRY AGAIN (NOT TO KILL YOURSELF, THAT IS) ";
770  GOTO 180
780  END 
