8990  REM ***  HP TIME-SHARED BASIC PROGRAM LIBRARY  **********************
8991  REM
8992  REM         UNITS:  CAI IN INTERPRETATION OF EE UNITS
8993  REM
8994  REM         36157 (A820) REV A -- 7/71
8995  REM
8996  REM ***  CONTRIBUTED PROGRAM  ***************************************
8997  REM
9000  PRINT '10'10
9001  PRINT " A PROGRAM FOR COMPUTER AIDED PRACTICE IN CHOOSING"
9002  PRINT "NEW UNITS TO AVOID LARGE - OR + POWERS OF 10;"
9003  PRINT "PREPARED BY C.M. SIEGEL AND E. DIXON, JULY 1,1970"
9004  PRINT 
9005  PRINT "IF AT ANY TIME YOU WANT A NEW SET OF C AND L"
9006  PRINT "UNITS, ANSWER QUESTIONS WITH ANY NEGATIVE NUMBER"
9007  PRINT 
9008  PRINT "(YOU NEED TO KNOW THAT THE SQUARE ROOT OF 10 IS 3.16)"
9009  PRINT '10'10'10
9010  PRINT "TO SATISFY THE RELATIONS V=ZI, I=YV,"
9011  PRINT "X=OMEGA TIMES L, B=OMEGA TIMES C,"
9012  PRINT "OMEGA =1/SQR(LC), ETC."
9013  PRINT 
9014  DIM B$[10],A$[10]
9015  GOSUB 9045
9016  A1=10^K
9017  GOSUB 9045
9018  K=K+6
9019  A2=10^K
9020  PRINT "IF WE USE  "A1"  FARADS AS UNIT OF CAPACITANCE AND "
9021  PRINT A2"  HENRIES AS UNIT OF INDUCTANCE, THEN"
9022  B9=1/SQR(A1*A2)
9023  FOR J=1 TO 8
9024  PRINT 
9025  GOSUB J OF 9047,9051,9055,9059,9063,9066,9069,9066
9026  IF J=5 THEN 9029
9027  IF J=7 THEN 9031
9028  GOTO 9032
9029  PRINT "IF, FURTHERMORE, P.D. IS EXPRESSED IN VOLTS,"
9030  GOTO 9032
9031  PRINT "IF, HOWEVER, CURRENT IS EXPRESSED IN AMPERES,"
9032  PRINT "THE UNIT OF  "A$"  WILL B"'16"E HOW MANY  "B$"  ?"
9033  INPUT B1
9034  IF B1<0 THEN 9015
9035  IF ABS(B1/B2-1)<.01 THEN 9038
9036  PRINT "WRONG,TRY AGAIN"
9037  GOTO 9033
9038  PRINT "CORRECT"
9039  NEXT J
9040  PRINT "IF YOU WANT A NEW PROBLEM, TYPE 1, OTHERWISE 0"
9041  INPUT K
9042  PRINT '10'10'10
9043  IF K=1 THEN 9015
9044  GOTO 9073
9045  K=INT(6.99*RND(8)-11)
9046  RETURN 
9047  A$="OMEGA"
9048  B$="RAD/SEC"
9049  B2=B9
9050  RETURN 
9051  A$="TIME"
9052  B$="SECONDS"
9053  B2=1/B9
9054  RETURN 
9055  A$="IMPEDANCE"
9056  B$="OHMS"
9057  B2=B9*A2
9058  RETURN 
9059  A$="ADMITTANCE"
9060  B$="MHOS"
9061  B2=1/B2
9062  RETURN 
9063  A$="CURRENT"
9064  B$="AMPERES"
9065  RETURN 
9066  A$="POWER"
9067  B$="WATTS"
9068  RETURN 
9069  A$="P.D."
9070  B$="VOLTS"
9071  B2=1/B2
9072  RETURN 
9073  END 
