*CREATE COMMAND (FILE, DIRECTORY & MEM. PARTITION)      HEADER  FUPCRE  0001.000
         M.PGM     FUPCRE,MPX-32,3.6.1,00                               0002.000
         SPACE                                                          0003.000
*                                                                       0004.000
************************************************************************0005.000
*                                                                      *0006.000
*                    PROPRIETARY INFORMATION                           *0007.000
*                    -----------------------                           *0008.000
*   THE INFORMATION CONTAINED HEREIN IS PROPRIETARY TO ENCORE          *0009.000
*   COMPUTER CORPORATION AND/OR ITS VENDORS, AND ITS USE, DISCLOSURE,  *0010.000
*   OR DUPLICATION IS SUBJECT TO THE RESTRICTIONS STATED IN THE        *0011.000
*   STANDARD ENCORE COMPUTER CORPORATION LICENSE TERMS AND CONDITIONS  *0012.000
*   OR THE APPROPRIATE THIRD-PARTY SUBLICENSE AGREEMENT.               *0013.000
*                                                                      *0014.000
*                       RESTRICTED RIGHTS                              *0015.000
*                       -----------------                              *0016.000
*   USE, DUPLICATION, OR DISCLOSURE BY THE GOVERNMENT IS SUBJECT       *0017.000
*   TO RESTRICTIONS AS SET FOURTH IN SUBDIVISION (c) (1) (ii) OF       *0018.000
*   THE RIGHTS IN TECHNICAL DATA AND COMPUTER SOFTWARE CLAUSE AT       *0019.000
*   252.227.7013                                                       *0020.000
************************************************************************0021.000
* (C) COPYRIGHT 1989 ENCORE COMPUTER CORPORATION                       *0022.000
*     ALL RIGHTS RESERVED                                              *0023.000
************************************************************************0024.000
*                                                                       0025.000
*                                                                       0026.000
*    FUNCTIONAL DESCRIPTION:                                            0027.000
*                                                                       0028.000
*        THIS MODULE CONTAINS ONE OF THE COMMAND PROCESSING ROUTINES    0029.000
*        FOR THE FILE UTILITY PROGRAM FOR THE NEW FILE SYSTEM. THIS     0030.000
*        THIS MODULE HANDLES THE COMMANDS:                              0031.000
*                                                                       0032.000
*                  'CREATE COMMON'                                      0033.000
*                  'CREATE DIRECTORY'                                   0034.000
*                  'CREATE FILE'                                        0035.000
*                                                                       0036.000
*                                                                       0037.000
*    EXTERNAL REFERENCES:                                               0038.000
*                                                                       0039.000
         EXT       C.DERES2        DELETE RESOURCE (FOR REPLACE OPTION) 0040.000
         EXT       GETPROT2        GET NEXT PROTOTYPE BLOCK             0041.000
         EXT       AUDIT0          AUDIT CREATE COMMON LINE             0042.000
         EXT       ERROR           ERROR HANDLER                        0043.000
         EXT       BCOMRCB         BUILD COMMON RCB                     0044.000
         EXT       BDIRRCB         BUILD DIRECTORY RCB                  0045.000
         EXT       BFILRCB         BUILD FILE RCB                       0046.000
         EXT       BUILDPNB        BUILD PNB ROUTINE                    0047.000
         EXT       GETRD0          GET RESOURCE DESCRIPTOR VIA RID      0048.000
         EXT       RID.FUP         BUFFER CONTAINING RID FROM CREATE    0049.000
         EXT       RCB.BUF         HOLDS AN RCB                         0050.000
         EXT       PNB.BUF         HOLDS A PNB                          0051.000
         EXT       RD1.BUF         HOLDS AN RD                          0052.000
         EXT       F.CCOM          FUNCTION MESSAGE FOR AUDIT           0053.000
         EXT       F.CDIR          FUNCTION MESSAGE FOR AUDIT           0054.000
         EXT       F.CFIL          FUNCTION MESSAGE FOR AUDIT           0055.000
         EXT       F.ACCOM         FUNCT. MESSAGE FOR 'UNABLE TO AUDIT' 0056.000
         EXT       F.ACDIR                          "                   0057.000
         EXT       F.ACFIL                          "                   0058.000
         EXT       FUN.SAVE        ADDRESS OF FUNCTION STRING           0059.000
         EXT       CNP.BUF         CNP BUFFER                           0060.000
         EXT       BUILDCNP        BUILDS A CNP                         0061.000
         EXT       FLAGBITS                                    ! 32B02  0062.000
*                                                                       0063.000
         EXT       STACKPTR        FOR SAVING R1                        0064.000
         EXT       FORMATOT        FORMAT AND OUTPUT MESSAGE            0065.000
         EXT       COMDADDR        ADDRESS FOR COMMAND DISPATCH         0066.000
         EXT       FILERTN         RETURN ADDRESS FOR COMMAND DISPATCH  0067.000
         EXT       SS.PATNM        PARSE TABLE FOR PATHNAME             0068.000
         EXT       SS.DPATH        PARSE TABLE FOR DIRECTORY PATH       0069.000
         EXT       SS.CPTHN                                             0070.000
         EXT       SS.KWSYN        PARSE TABLE TO CK KEYWD SYNTAX       0071.000
         EXT       SS.SEGN         PARSE TABLE FOR SEGNUM OPT   EVOM-33 0072.000
         EXT       A.LOCAL1        ACTION TABLE FOR S.CREFIL    EVOM-33 0073.000
         EXT       A.GLOBAL        POSTION POINTER TO GLOBAL OPTION AREA0074.000
         EXT       A.LOCAL         POSTION TO A LOCAL OPTION AREA       0075.000
         EXT       INVKEY          ERROR MESSAGE                        0076.000
         EXT       PERR006         ERRVAL STATE   -- NO PATHNAME GIVEN  0077.000
*                                                                       0078.000
         EXT       SS.AUTO         STATE TABLES FOR AUTOMATIC EXTEND    0079.000
         EXT       SS.BRIE         STATE TABLES FOR BRIEF               0080.000
         EXT       SS.MANE         STATE TABLES FOR MANUAL EXTEND       0081.000
         EXT       SS.CONT         STATE TABLES FOR CONTIGUOUS BOOL. OPT0082.000
         EXT       SS.ACCEF        PARSE TABLE FOR ACCESS ATTRIBUTES    0083.000
         EXT       SS.ACCE         PARSE TABLE FOR ACCESS (DIRECTORY)   0084.000
         EXT       SS.ENTR         PARSE TABLE FOR # ENTRIES (DIRECTORY)0085.000
         EXT       SS.FAST         PARSE TABLE FOR FAST ID              0086.000
         EXT       SS.OWNE         PARSE TABLE FOR OWNER NAME           0087.000
         EXT       SS.SHAR         PARSE TABLE FOR SHARED ATTRIBUTE     0088.000
         EXT       SS.STAR         PARSE TABLE FOR "START" BLOCK #      0089.000
         EXT       SS.USER         PARSE TABLE FOR USER NAME            0090.000
         EXT       SS.ZERO         STATE TABLES FOR ZERO=BOOL OPTION    0091.000
         EXT       SS.INP          PARSE TABLE FOR PATHNAME= KEYWORD    0092.000
         EXT       SS.ALLO         PARSE TABLE FOR # BLOCKS TO ALLOCATE 0093.000
         EXT       SS.INCR         PARSE TABLE FOR FILE EXTENSION SIZE  0094.000
         EXT       SS.MAXS         PARSE TABLE FOR FILE AUTOMATIC       0095.000
*                                  EXTENSION -- MAXIMUM SIZE            0096.000
         EXT       SS.MINI         PARSE TABLE FOR FILE AUTOMATIC       0097.000
*                                  EXTENSION -- MINIMUM EXTENSION SIZE  0098.000
         EXT       SS.NOSA         PARSE TABLE FOR NOSAVE ATTRIBUTE     0099.000
         EXT       SS.RAND         PARSE TABLE FOR "RANDOM" ATTRIBUTE   0100.000
         EXT       SS.REPL         PARSE TABLE FOR "REPLACE" SPECIFIER  0101.000
*                                  IE., DELETE EXISTING FILE W/SAME NAME0102.000
         EXT       SS.PROT         PARSE TABLE FOR # PROTGRANS          0103.000
         EXT       SS.FIRS         PARSE TABLE FOR FIRSTPAGE            0104.000
         EXT       AS.PROT         ACTION ROUTINE FOR PROTGRAN          0105.000
         EXT       AS.FIRS         ACTION ROUTINE FOR FIRST             0106.000
         EXT       SS.NUMB         PARSE TABLE FOR A NUMBER             0107.000
         EXT       SS.CPATH        PARSE TABLE FOR COMMON PART. PATHNAME0108.000
         EXT       SS.MEMC         PARSE TABLE FOR MEMORY CLASS         0109.000
         EXT       ADR.MASK        MASK CC'S LEAVING ADDRESS            0110.000
*                                                                       0111.000
*    EXTERNAL DEFINITIONS                                               0112.000
*                                                                       0113.000
         DEF       C.CRECOM        TOP LEVEL ENTRY POINT                0114.000
         DEF       C.CREDIR             "      "                        0115.000
         DEF       C.CREFIL             "      "                        0116.000
*                                                                       0117.000
         DEF       CRECOM          LOW LEVEL ROUTINE                    0118.000
         DEF       CREDIR               "      "                        0119.000
         DEF       CREFIL               "      "                        0120.000
*                                                                       0121.000
         DEF       S.CRECOM        STATE TABLE FOR THE COMMAND          0122.000
         DEF       S.CREDIR             "      "                        0123.000
         DEF       S.CREFIL             "      "                        0124.000
         SPACE                                                          0125.000
*                                                                       0126.000
*    SYSTEM MACRO CALLS FOR DEFINITIONS AND EQUATES:                    0127.000
*                                                                       0128.000
         M.REQS                    REGISTER EQUATES                     0129.000
         M.CNP                                                          0130.000
         M.RCB                     RCB EQUATES                  EVOMA33 0131.000
*                                                                       0132.000
*    LOCAL DEFINITIONS:                                                 0133.000
*                                                                       0134.000
         STINIT                    TPARSE DEFINITIONS AND INIT          0135.000
*                                                                       0136.000
CRTYPE   DATAW     0               TO STORE CREATE TYPE INDEX           0137.000
*                                                                       0138.000
* THE FOLLOWING IS PURE DATA. THIS IS CONFIGURED INTO THE CSECT         0139.000
* ANY LOCAL DATA MUST PROCEED THIS CSECT DIRECTIVE                      0140.000
*                                                                       0141.000
         CSECT                                                          0142.000
         SPACE                                                          0143.000
*                                                                       0144.000
* THE FOLLOWING ARE VALUES USED IN COMMON CODE BELOW TO                 0145.000
* DISTINGUISH WHICH ENTRY POINT WAS USED SO THAT DIFFERENT              0146.000
* SVC'S CAN BE ISSUED.                                                  0147.000
*                                                                       0148.000
FL.COM   EQU       0               CREATE COMMON                        0149.000
FL.DIR   EQU       1               CREATE DIRECTORY                     0150.000
FL.FIL   EQU       2               CREATE FILE                          0151.000
*                                                                       0152.000
*    LOCAL STORAGE:                                                     0153.000
*                                                                       0154.000
* TABLE OF FUNCTION STRING ADDRESSES FOR 'UNABLE TO AUDIT' MESSAGES     0155.000
*                                                                       0156.000
FUNCTAB  EQU       $                                                    0157.000
         DATAW     F.ACCOM                                              0158.000
         DATAW     F.ACDIR                                              0159.000
         DATAW     F.ACFIL                                              0160.000
*                                                                       0161.000
* TABLE TO EXECUTE ONE OF THREE BUILD RCB ROUTINES                      0162.000
*                                                                       0163.000
RCBTAB   DATAW     BCOMRCB         MEMORY PARTITION                     0164.000
         DATAW     BDIRRCB         DIRECTORY                            0165.000
         DATAW     BFILRCB         FILE                                 0166.000
*                                                                       0167.000
* TABLE TO EXECUTE ONE OF THREE 'CREATE' SVC'S                          0168.000
*                                                                       0169.000
SVCTAB   DATAW     CMEM            MEMORY PARTITION                     0170.000
         DATAW     CDIR            DIRECTORY                            0171.000
         DATAW     CFIL            FILE                                 0172.000
*                                                                       0173.000
CMEM     SVC2.22                   H.VOMM,3                             0174.000
         BU        CRCOM4          RETURN TO POINT OF CALL              0175.000
*                                                                       0176.000
CDIR     SVC2.23                   H.VOMM,4                             0177.000
         BU        CRCOM4          RETURN TO POINT OF CALL              0178.000
*                                                                       0179.000
CFIL     SVC2.20                   H.VOMM,1                             0180.000
         BU        CRCOM4          RETURN TO POINT OF CALL              0181.000
************************************************************            0182.000
*                                                                       0183.000
* ERROR CODE FOR RESOURCE DOES NOT EXIST                                0184.000
*                                                                       0185.000
ERRCOD1  GEN       8/MOD.VOM,24/7  'RESOURCE DOES NOT EXIST'            0186.000
************************************************************            0187.000
         TITLE     'CREATE COMMON' FUP COMMAND                          0188.000
*                                                                       0189.000
* ROUTINE C.CRCOM1 - TOP LEVEL ENTRY FOR 'CREATE COMMON'.               0190.000
*                                                                       0191.000
*        THIS ROUTINE IS ENTERED BY THE FILE UTILITY MAIN               0192.000
*        COMMAND DISPATCHER AFTER THE 'CREATE COMMON' COMMAND           0193.000
*        HAS BEEN SUCCESSFULLY PARSED.                                  0194.000
*                                                                       0195.000
* IT SETS UP THE FUNCTION STRING ADDRESS AND ALSO R3 TO                 0196.000
* CONTAIN THE LOW LEVEL ROUTINE TO CALL TO ACTUALLY DO                  0197.000
* THE CREATE                                                            0198.000
*                                                                       0199.000
C.CRECOM EQU       $                                                    0200.000
         PUSH                      SAVE REGISTERS                       0201.000
         LA        R7,F.CCOM       FUNCTION STRING ADDRESS              0202.000
         STW       R7,FUN.SAVE                                          0203.000
         LA        R3,CRECOM       LOW LEVEL ROUTINE ADDRESS            0204.000
         BU        CRCOM2          COMMON CODE                          0205.000
*                                                                       0206.000
* ROUTINE C.CREDIR - TOP LEVEL ENTRY FOR 'CREATE DIRECTORY'.            0207.000
*                                                                       0208.000
*        THIS ROUTINE IS ENTERED BY THE FILE UTILITY MAIN               0209.000
*        COMMAND DISPATCHER AFTER THE 'CREATE DIRECTORY' COMMAND        0210.000
*        HAS BEEN SUCCESSFULLY PARSED.                                  0211.000
*                                                                       0212.000
C.CREDIR EQU       $                                                    0213.000
         PUSH                      SAVE REGISTERS                       0214.000
         LA        R7,F.CDIR       FUNCTION STRING ADDRESS              0215.000
         STW       R7,FUN.SAVE     SAVE IT FOR AUDIT/ERROR              0216.000
         LA        R3,CREDIR       LOW LEVEL ROUTINE ADDRESS            0217.000
         BU        CRCOM2          COMMON CODE                          0218.000
*                                                                       0219.000
* ROUTINE C.CREFIL - TOP LEVEL ENTRY FOR 'CREATE FILE'.                 0220.000
*                                                                       0221.000
*        THIS ROUTINE IS ENTERED BY THE FILE UTILITY MAIN               0222.000
*        COMMAND DISPATCHER AFTER THE 'CREATE FILE' COMMAND             0223.000
*        HAS BEEN SUCCESSFULLY PARSED.                                  0224.000
*                                                                       0225.000
C.CREFIL EQU       $                                                    0226.000
         PUSH                      SAVE REGISTERS                       0227.000
         LA        R7,F.CFIL       FUNCTION STRING ADDRESS              0228.000
         STW       R7,FUN.SAVE     SAVE FOR AUDIT/ERROR                 0229.000
         LA        R3,CREFIL       LOW LEVEL ROUTINE ADDRESS            0230.000
         BU        CRCOM2          COMMON CODE                          0231.000
         PAGE                                                           0232.000
*                                                                       0233.000
* COMMON CODE FOR ALL THREE TYPES OF CREATE STARTS HERE                 0234.000
*                                                                       0235.000
*                                                                       0236.000
* GET THE NEXT PROTOTYPE/OPTION BLOCK PAIR                              0237.000
* CC1 WILL BE ZERO IF THERE ARE MORE BLOCKS, ELSE 1                     0238.000
*                                                                       0239.000
CRCOM2   BL        GETPROT2                                             0240.000
         BCT       1,CRCOM0        BRANCH IF NO MORE BLOCKS             0241.000
*                                                                       0242.000
* THERE IS ANOTHER PROTOTYPE BLOCK, AND ITS ADDRESS IS IN R2.           0243.000
* CALL THE LOW LEVEL ENTRY POINT TO ACTUALLY PERFORM THE CREATE         0244.000
* R7 CONTAINS THE ERROR STATUS IF ANY (ELSE 0) ON EXIT.                 0245.000
*                                                                       0246.000
         BL        0,R3            R3 HOLDS THE ROUTINE ADDRESS         0247.000
*        BCT       1,CRCOM1        BRANCH IF ERRORS             EVOMA33 0248.000
         BCF       1,CRCOM2.1      IF NO ERROR, BRANCH          EVOMA33 0249.000
         CI        R7,53           IS IT VM53?                  EVOMA33 0250.000
         BNE       CRCOM1          IF NOT, REPORT ERROR         EVOMA33 0251.000
*                                                                       0252.000
* THE CREATE WAS SUCCESSFUL SO PRINT AN AUDIT TRAIL LINE.               0253.000
* OBTAIN THE RD FIRST OF ALL. THE DATA GETS SET IN GLOBAL               0254.000
* BUFFER RD1.BUF BY ROUTINE GETRD0.                                     0255.000
*                                                                       0256.000
CRCOM2.1 EQU       $               SUCCESSFUL                   EVOMA33 0257.000
         TRR       R2,R6           SAVE PROTOTYPE ADDRESS               0258.000
         LA        R2,RID.FUP      RID ADDR. RETURNED BY CREATE SERVICE 0259.000
         LA        R7,RD1.BUF      TO HOLD RD                           0260.000
         BL        GETRD0          GET RES. DESCR. VIA RID              0261.000
         TRR       R6,R2           REGAIN PROTOTYPE ADDRESS IN R2       0262.000
         TBR       R0,CC1          CHECK FOR ERROR(S)                   0263.000
         BNS       CRCOM1.1        GO FOR ERROR                         0264.000
         LW        R3,CRTYPE       INDEX INTO FUNCTION STRING TABLE     0265.000
         LA        R6,*FUNCTAB,R3   NEW FUNC. STRG. FOR 'UNABLE TO      0266.000
         STW       R6,FUN.SAVE     AUDIT CREATE' ERROR MESSAGE          0267.000
         BU        CRCOM1                                               0268.000
*                                                                       0269.000
CRCOM1.1 BL        AUDIT0                                               0270.000
         BU        CRCOM2          LOOP FOR NEXT PROTOTYPE BLOCK        0271.000
*                                                                       0272.000
* ERRORS WERE DETECTED DURING THE CREATE FUNCTION                       0273.000
* THE ERROR CODE IS IN R7                                               0274.000
* CALL AN ERROR ROUTINE WHICH USES R7 AND R2 (PROTOTYPE BLOCK           0275.000
* ADDRESS) TO PRINT AN ERROR MESSAGE.                                   0276.000
*                                                                       0277.000
CRCOM1   SBM       ABORT.F,FLAGBITS  SET ABORT FLAG            ! 32B02  0278.000
         BL        ERROR                                                0279.000
         BU        CRCOM2          LOOP FOR NEXT PROTOTYPE BLOCK        0280.000
*                                                                       0281.000
* THERE ARE NO MORE PROTOTYPE BLOCKS SO THE HANDLING OF THIS            0282.000
* COMMAND HAS FINISHED.                                                 0283.000
*                                                                       0284.000
CRCOM0   EQU       $                                                    0285.000
         POP                       RESTORE REGISTERS                    0286.000
         TRSW      R0                                                   0287.000
         TITLE     LOW LEVEL ROUTINE FOR 'CREATE COMMON'                0288.000
*                                                                       0289.000
* ROUTINE CRECOM - LOW LEVEL ENTRY FOR 'CREATE COMMON'.                 0290.000
*                                                                       0291.000
*        THIS ROUTINE IS ENTERED BY EITHER:                             0292.000
*                                                                       0293.000
*        (1) A CALL FROM THE TOP LEVEL ENTRY ROUTINE                    0294.000
*        (2) A CALL FROM ANOTHER FUP COMMAND.                           0295.000
*                                                                       0296.000
* THE ROUTINE SETS UP R3 TO CONTAIN AN INDICATION WHICH CREATE IS       0297.000
* BEING PERFORMED AND THEN JOINS COMMON CODE FOR ALL CREATES.           0298.000
*                                                                       0299.000
*        INPUT:                                                         0300.000
*                  R2 = ADDRESS OF PROTOTYPE TABLE ENTRY                0301.000
*                                                                       0302.000
*        OUTPUT:                                                        0303.000
*                  R7 = ERROR STATUS (ELSE 0)                           0304.000
*                                                                       0305.000
*                                                                       0306.000
CRECOM   EQU       $                                                    0307.000
         PUSH                      SAVE REGISTERS                       0308.000
*                                                                       0309.000
* IF THE REPLACE OPTION WAS SET, ATTEMPT TO DELETE THE EXISTING         0310.000
* RESOURCE BEFORE RECREATING IT.                                        0311.000
*                                                                       0312.000
         LW        R3,PROFOA.O,R2  OPTION BLOCK ADDRESS                 0313.000
         TBM       OPT.B.RE,OPT.FLGS,R3                                 0314.000
         BNS       CRECOM1         BRANCH IF NOT TO REPLACE             0315.000
*                                                                       0316.000
* ATTEMPT TO DELETE THE RESOURCE                                        0317.000
*                                                                       0318.000
         BL        C.DERES2                                             0319.000
         BCF       1,CRECOM1       BRANCH IF SUCCESSFUL                 0320.000
         CAMW      R7,ERRCOD1      'RESOURCE DOES NOT EXIST' ?          0321.000
         BEQ       CRECOM1         BRANCH IF YES                        0322.000
*                                                                       0323.000
* ELSE RETURN THE ERROR FOR LOGGING                                     0324.000
*                                                                       0325.000
         STW       R7,7W,R1        RETURN ERROR CODE TO CALLER          0326.000
         SBM       CC1,0W,R1       SET CC1                              0327.000
         POP                                                            0328.000
         TRSW      R0              AND RETURN                           0329.000
*                                                                       0330.000
CRECOM1  LI        R3,FL.COM                                            0331.000
         BU        CRCOM3                                               0332.000
         TITLE     LOW LEVEL ROUTINE FOR 'CREATE DIRECTORY'             0333.000
*                                                                       0334.000
* ROUTINE CREDIR - LOW LEVEL ENTRY FOR 'CREATE DIRECTORY'               0335.000
*                                                                       0336.000
*        THIS ROUTINE IS ENTERED BY EITHER:                             0337.000
*                                                                       0338.000
*        (1) A CALL FROM THE TOP LEVEL ENTRY ROUTINE                    0339.000
*        (2) A CALL FROM ANOTHER FUP COMMAND.                           0340.000
*                                                                       0341.000
* THE ROUTINE SETS UP R3 TO CONTAIN AN INDICATION WHICH CREATE IS       0342.000
* BEING PERFORMED AND THEN JOINS COMMON CODE FOR ALL CREATES.           0343.000
*                                                                       0344.000
*        INPUT:                                                         0345.000
*                  R2 = ADDRESS OF PROTOTYPE TABLE ENTRY                0346.000
*                                                                       0347.000
*        OUTPUT:                                                        0348.000
*                  R7 = ERROR STATUS (ELSE 0)                           0349.000
*                                                                       0350.000
***                                                                     0351.000
***      NOTE:  BE SURE OF PATHNAME BLOCK (PNB) NOTATION OF !DIR SYST   0352.000
***             THIS FORM IS NEEDED TO CREATE "THE ""SYSTEM"" DIRECTORY"0353.000
***                                                                     0354.000
*                                                                       0355.000
CREDIR   EQU       $                                                    0356.000
         PUSH                      SAVE REGISTERS                       0357.000
         LI        R3,FL.DIR                                            0358.000
         BU        CRCOM3                                               0359.000
         TITLE     LOW LEVEL ROUTINE FOR 'CREATE FILE'                  0360.000
*                                                                       0361.000
* ROUTINE CREFIL - LOW LEVEL ENTRY FOR 'CREATE FILE'                    0362.000
*                                                                       0363.000
*        THIS ROUTINE IS ENTERED BY EITHER:                             0364.000
*                                                                       0365.000
*        (1) A CALL FROM THE TOP LEVEL ENTRY ROUTINE                    0366.000
*        (2) A CALL FROM ANOTHER FUP COMMAND.                           0367.000
*                                                                       0368.000
* THE ROUTINE SETS UP R3 TO CONTAIN AN INDICATION WHICH CREATE IS       0369.000
* BEING PERFORMED AND THEN JOINS COMMON CODE FOR ALL CREATES.           0370.000
*                                                                       0371.000
*        INPUT:                                                         0372.000
*                  R2 = ADDRESS OF PROTOTYPE TABLE ENTRY                0373.000
*                                                                       0374.000
*        OUTPUT:                                                        0375.000
*                  R7 = ERROR STATUS (ELSE 0)                           0376.000
*                                                                       0377.000
*                                                                       0378.000
CREFIL   EQU       $                                                    0379.000
         PUSH                      SAVE REGISTERS                       0380.000
*                                                                       0381.000
* IF THE REPLACE OPTION WAS SET, ATTEMPT TO DELETE THE EXISTING         0382.000
* RESOURCE BEFORE RECREATING IT.                                        0383.000
*                                                                       0384.000
         LW        R3,PROFOA.O,R2  OPTION BLOCK ADDRESS                 0385.000
         TBM       OPT.B.RE,OPT.FLGS,R3                                 0386.000
         BNS       CREFIL1         BRANCH IF NOT TO REPLACE             0387.000
*                                                                       0388.000
* ATTEMPT TO DELETE THE RESOURCE                                        0389.000
*                                                                       0390.000
         BL        C.DERES2                                             0391.000
         BCF       1,CREFIL1       BRANCH IF SUCCESSFUL                 0392.000
         CAMW      R7,ERRCOD1      'RESOURCE DOES NOT EXIST' ?          0393.000
         BEQ       CREFIL1         BRANCH IF YES                        0394.000
*                                                                       0395.000
* ELSE RETURN THE ERROR FOR LOGGING                                     0396.000
*                                                                       0397.000
         STW       R7,7W,R1        RETURN ERROR CODE TO CALLER          0398.000
         SBM       CC1,0W,R1       SET CC1                              0399.000
         POP                                                            0400.000
         TRSW      R0              AND RETURN                           0401.000
*                                                                       0402.000
CREFIL1  LI        R3,FL.FIL                                            0403.000
         BU        CRCOM3                                               0404.000
         TITLE     COMMON CODE FOR ALL LOW LEVEL CREATE ROUTINES        0405.000
*                                                                       0406.000
* COMMON CODE TO ACTUALLY PERFORM THE CREATE FUNCTION.                  0407.000
*                                                                       0408.000
CRCOM3   EQU       $                                                    0409.000
         LW        R0,0W,X1        GET R0 FROM STACK                    0410.000
         ANMW      R0,ADR.MASK     INITIALIZE CC'S FOR RETURN           0411.000
         STW       R0,0W,X1        PLANT BACK ON STACK                  0412.000
*                                                                       0413.000
* CALL ONE OF THREE BUILD RCB ROUTINES                                  0414.000
* R2 CONTAINS THE ADDRESS OF THE PROTOTYPE BLOCK                        0415.000
* THE GLOBAL BUFFER RCB.BUF GETS FILLED                                 0416.000
*                                                                       0417.000
* SCALE R3 TO INDEX THE WORD ADDRESS TABLE                              0418.000
*                                                                       0419.000
         SLL       R3,2                                                 0420.000
         STW       R3,CRTYPE                                            0421.000
         BL        *RCBTAB,R3                                           0422.000
*                                                                       0423.000
* R3 INDICATES THE INDEX INTO A TABLE IN ORDER TO                       0424.000
* EXECUTE THE CORRECT SVC.                                              0425.000
*                                                                       0426.000
*                                                                       0427.000
* CALL THE ROUTINE BUILDCNP TO SET UP THE CALLER NOTIFICATION           0428.000
* PACKAGE.                                                              0429.000
* R7 CONTAINS THE OPTION HALF WORD FOR THE CNP.                         0430.000
* CNP.BUF IS SET UP ON EXIT                                             0431.000
*                                                                       0432.000
         ZR        R7                                                   0433.000
         BL        BUILDCNP                                             0434.000
*                                                                       0435.000
* CALL BUILDPNB FOR PATHNAME BLOCK                                      0436.000
* R2 CONTAINS THE ADDRESS OF THE PROTOTYPE BLOCK                        0437.000
* ON RETURN R7 CONTAINS THE PATHNAME DESCRIPTOR READY FOR               0438.000
* THE SERVICE CALL.                                                     0439.000
*                                                                       0440.000
         BL        BUILDPNB                                             0441.000
*                                                                       0442.000
* NOW CALL THE SYSTEM SERVICE H.VOMM,3 TO DO THE CREATE                 0443.000
*                                                                       0444.000
         PUSHSTP                   SAVE R1                              0445.000
         TRR       R7,R1           INTO R1 FOR SVC CALL                 0446.000
         LA        R2,RCB.BUF      ADDRESS OF RCB                       0447.000
         LB        R7,RCB.OPTS+2B,R2  GET SEGNUM VAL            EVOMA33 0448.000
         LA        R2,CNP.BUF      GET CNP ADDR                 EVOMA33 0449.000
         SLL       R7,24           MOVE SEGNUM TO BYTE 0 OF R7  EVOMA33 0450.000
         STW       R7,CP.OPTS,R2   MERGE INTO CNP               EVOMA33 0451.000
         LA        R2,RCB.BUF      RESTORE RCB ADDR TO R2       EVOMA33 0452.000
         LA        R7,CNP.BUF                                           0453.000
         BU        *SVCTAB,R3      PERFORM THE SVC                      0454.000
CRCOM4   POPSTP                    RESTORE R1                           0455.000
*                                                                       0456.000
* SET CC1 IF ERROR FROM SVC, AND RETURN R7 TO CALLER                    0457.000
*                                                                       0458.000
         CHECKERR  MOD.VOM                                              0459.000
         POP                       RESTORE REGISTERS                    0460.000
         TRSW      R0                                                   0461.000
         TITLE     CREATE COMMON COMMAND STATE TABLES                   0462.000
*                                                                       0463.000
* C.CMD    - ACTION WHEN VALID CREATE FILE(S) COMMAND IS PARSED         0464.000
*                                                                       0465.000
         SPACE                                                          0466.000
C.CMD    LA        R7,C.CRECOM     GET ADDRESS OF COMMAND PROCESSOR     0467.000
         STW       R7,COMDADDR     SAVE FOR DISPATCHER                  0468.000
         TRSW      R0              RETURN TO PARSER                     0469.000
         SPACE                                                          0470.000
         BOUND     1W              ALIGN                                0471.000
         SPACE                                                          0472.000
*++                                                                     0473.000
* S.CRECOM - STATE TABLES FOR THE CREATE COMMON COMMAND                 0474.000
*                                                                       0475.000
* COMMAND SYNTAX:                                                       0476.000
*                                                                       0477.000
* CREATE COMMON                                                         0478.000
*                                                                       0479.000
* OPTIONS:                                                              0480.000
*                                                                       0481.000
*--                                                                     0482.000
         SPACE                                                          0483.000
S.CRECOM STATE                     STATE TABLE FOR CREATE COMMON        0484.000
           TRAN    NOBLNK,A.GLOBAL      POSITION OPTION BLOCK FOR       0485.000
*                                       GLOBAL OPTIONS                  0486.000
C.10     STATE                                                          0487.000
           TRAN    EOS,,PERR006         ERROR -- MUST HAVE AT LEAST ONE 0488.000
*                                       PATHNAME                        0489.000
           TRAN    TSTEXP,,C.20,SS.KWSYN    IS IT A KEYWORD ???         0490.000
           TRAN    NOBLNK,,C.30              NOT A KEYWORD -- MUST BE AN0491.000
*                                            ACTUAL PATHNAME            0492.000
C.20     STATE                                                          0493.000
           TRAN    SUBEXP,,C.30,SS.INP,NOB.M      IS IT "PATH=" KEYWORD 0494.000
           TRAN    SUBEXP,,C.10,CC.OPT,NOB.M      CHECK FOR LEGAL OPTION0495.000
*                                                 KEYWORDS              0496.000
           ERRVAL  INVKEY                         INVALID KEYWORD       0497.000
C.30     STATE                                                          0498.000
           TRAN    EOS,,PERR006              ERROR -- MUST HAVE AT LEAST0499.000
*                                            ONE PATHNAME               0500.000
           TRAN    NOBLNK,A.LOCAL            POSITION TO 1ST LOCAL      0501.000
*                                            OPTION BLOCK               0502.000
         STATE                                                          0503.000
           TRAN    SUBEXP,A.LOCAL,C.40,CC.LIST   GET PATHNAME & LOCAL OP0504.000
C.40       TRAN    EOS,C.CMD,EXIT            EXIT PARSE -- SUCCESSFUL   0505.000
*                                            ALSO PLUG ENTRY ADDRESS    0506.000
*                                            SYNTAX VIOLATION           0507.000
         STATE                                                          0508.000
         SPACE     3                                                    0509.000
CC.LIST  STATE                               INPUT FILE LIST            0510.000
           TRAN    SUBEXP,,,SS.PATNM,NOB.M                     V.13     0511.000
         STATE                                                          0512.000
           TRAN    TSTEXP,,,SS.KWSYN         IS IT A KEYWORD ?          0513.000
           TRAN    LAMBDA,AS.PROT,CC.SL02    NO, MUST BE NUMBER         0514.000
         STATE                                                          0515.000
           TRAN    SUBEXP,,CC.SL05,CC.PROT,NOB.M  IS IT "PROT="         0516.000
           TRAN    SUBEXP,,CC.SL04,CC.FIRS,NOB.M  IS IT "FIRS="         0517.000
           ERRVAL  INVKEY                         INVALID KEYWORD       0518.000
CC.SL02  STATE                                                          0519.000
           TRAN    SUBEXP,,CC.SL05,SS.NUMB,NOB.M   PARSE NUMBER         0520.000
CC.SL04  STATE                                                          0521.000
           TRAN    TSTEXP,,,SS.KWSYN          KEYWORD?                  0522.000
           TRAN    LAMBDA,AS.PROT,CC.SL08     MUST BE A NUMBER          0523.000
         STATE                                                          0524.000
           TRAN    SUBEXP,,CC.SL10,CC.PROT,NOB.M                        0525.000
           ERRVAL  INVKEY                                               0526.000
CC.SL05  STATE                                                          0527.000
           TRAN    TSTEXP,,,SS.KWSYN         IS IT A KEYWORD ?          0528.000
           TRAN    LAMBDA,AS.FIRS,CC.SL08    NO, MUST BE A NUMBER       0529.000
         STATE                                                          0530.000
           TRAN    SUBEXP,,CC.SL10,CC.FIRS,NOB.M  IS IT "FIRST="        0531.000
           ERRVAL  INVKEY                         INVALID KEYWORD       0532.000
CC.SL08  STATE                                                          0533.000
           TRAN    SUBEXP,,,SS.NUMB,NOB.M    PARSE NUMBER               0534.000
CC.SL10  STATE                                                          0535.000
           TRAN    TSTEXP,,,SS.KWSYN         LOOK FOR AN OPTION KEYWORD 0536.000
           TRAN    LAMBDA,,CC.SL20           MUST NOT BE ANY            0537.000
         STATE                                                          0538.000
           TRAN    SUBEXP,,CC.SL10,CC.OPT,NOB.M  GET AN OPTION          0539.000
CC.SL20  STATE                                                          0540.000
           TRAN    COMMA,A.LOCAL,CC.SL30,,NOB.M   GET MORE IF IN LIST   0541.000
           TRAN    NOBLNK,,EXIT              EXIT THIS SUBEXPRESSION    0542.000
CC.SL30  STATE                                                          0543.000
           TRAN    SUBEXP,,CC.LIST,SS.INP,NOB.M+LMB.M   "PATH=" KEYWORD 0544.000
         STATE                                                          0545.000
         SPACE     3                                                    0546.000
CC.PROT  STATE                                                          0547.000
           TRAN    KEYWD,,,K.PROT,NOB.M      PROTOGRAN                  0548.000
         STATE                                                          0549.000
         SPACE                                                          0550.000
CC.FIRS  STATE                                                          0551.000
           TRAN    KEYWD,,,K.FIRS,NOB.M      FIRSTPAGE                  0552.000
         STATE                                                          0553.000
         SPACE                                                          0554.000
CC.OPT   STATE                     OPTIONS APPLICABLE FOR THIS COMMAND  0555.000
           TRAN    KEYWD,,,C.OPTS,NOB.M                                 0556.000
         STATE                                                          0557.000
         SPACE     4                                                    0558.000
C.OPTS   EQU       $                         CREATE DIRECTORY -- OPTIONS0559.000
         KEYWRD    ACCESS,,SS.ACCEF,3  ACCESS ATTRIBUTES !32B01  ECKW-340560.000
         KEYWRD    BRIEF,,SS.BRIE,3    BRIEF - BOOL OPTI !32B01  ECKW-340561.000
         KEYWRD    MEMCLASS,,SS.MEMC,3 MEMORY CLASS--E/H !32B01  ECKW-340562.000
         KEYWRD    OWNER,,SS.OWNE,3    OWNER NAME SPECI. !32B01  ECKW-340563.000
         KEYWRD    REPLACE,,SS.REPL,3  REPLAC - DEL.EXIST !32B01 ECKW-340564.000
         KEYWRD    SHARED,,SS.SHAR,3   SHARED ATTRIBUTE   !32B01 ECKW-340565.000
         KEYWRD    PROJECTGROUP,,SS.USER,4 PROJ.GRP. NAME SPEC.! 32B01  0566.000
         DATAW     0                         END OF LIST                0567.000
         SPACE                                                          0568.000
K.PROT   EQU       $                    PROTOGRAN PARSE                 0569.000
         KEYWRD    PROTGRAN,,SS.PROT,4  PROTGRAN               ! 32B01  0570.000
         DATAW     0                                                    0571.000
         SPACE                                                          0572.000
K.FIRS   EQU       $                    FIRSTPAGE PARSE                 0573.000
         KEYWRD    FIRSTPAGE,,SS.FIRS,3 FIRSTPAGE        !32B01 ECKW-34 0574.000
         DATAW     0                                                    0575.000
         SPACE     5                                                    0576.000
         TITLE     CREATE DIRECTORY ACTION ROUTINE(S) & STATE TABLES    0577.000
* D.CMD    - PARSE ACTION WHEN VALID SAVE COMMAND IS FOUND              0578.000
*                                                                       0579.000
         SPACE                                                          0580.000
D.CMD    LA        R7,C.CREDIR     GET ADDRESS OF COMMAND PROCESSOR     0581.000
         STW       R7,COMDADDR     SAVE FOR DISPATCHER                  0582.000
         TRSW      R0              RETURN TO PARSER                     0583.000
         SPACE                                                          0584.000
         BOUND     1W              ALIGN                                0585.000
         SPACE                                                          0586.000
*++                                                                     0587.000
* S.CREDIR - STATE TABLES FOR THE CREATE DIRECTORY COMMAND              0588.000
*                                                                       0589.000
* COMMAND SYNTAX:                                                       0590.000
*                                                                       0591.000
* CREATE DIRECTORY   PATHNAME        ! PARTIAL PATHNAME TO DIRECTORY    0592.000
*                                                                       0593.000
* OPTIONS:                                                              0594.000
*                                                                       0595.000
*--                                                                     0596.000
         SPACE                                                          0597.000
         BOUND     1W              ALIGN                                0598.000
S.CREDIR STATE                     STATE TABLE FOR CREATE DIRECTORY     0599.000
           TRAN    NOBLNK,A.GLOBAL      POSITION OPTION BLOCK FOR       0600.000
*                                       GLOBAL OPTIONS                  0601.000
D.10     STATE                                                          0602.000
           TRAN    EOS,,PERR006         ERROR -- MUST HAVE AT LEAST ONE 0603.000
*                                       PATHNAME                        0604.000
           TRAN    TSTEXP,,D.20,SS.KWSYN    IS IT A KEYWORD ???         0605.000
           TRAN    NOBLNK,,D.30              NOT A KEYWORD -- MUST BE AN0606.000
*                                            ACTUAL PATHNAME            0607.000
D.20     STATE                                                          0608.000
           TRAN    SUBEXP,,D.30,SS.INP,NOB.M      IS IT "PATH=" KEYWORD 0609.000
           TRAN    SUBEXP,,D.10,DD.OPT,NOB.M      CHECK FOR LEGAL OPTION0610.000
*                                                 KEYWORDS              0611.000
           ERRVAL  INVKEY                         INVALID KEYWORD       0612.000
D.30     STATE                                                          0613.000
           TRAN    EOS,,PERR006              ERROR -- MUST HAVE AT LEAST0614.000
*                                            ONE PATHNAME               0615.000
           TRAN    NOBLNK,A.LOCAL            POSITION TO 1ST LOCAL      0616.000
*                                            OPTION BLOCK               0617.000
         STATE                                                          0618.000
           TRAN    SUBEXP,A.LOCAL,D.40,DD.LIST   GET PATHNAME & LOCAL OP0619.000
D.40       TRAN    EOS,D.CMD,EXIT            EXIT PARSE -- SUCCESSFUL   0620.000
*                                            ALSO PLUG ENTRY ADDRESS    0621.000
*                                            SYNTAX VIOLATION           0622.000
         STATE                                                          0623.000
         SPACE     3                                                    0624.000
DD.LIST  STATE                               INPUT FILE LIST            0625.000
           TRAN    SUBEXP,,,SS.DPATH,NOB.M                              0626.000
DD.SL10  STATE                                                          0627.000
           TRAN    TSTEXP,,,SS.KWSYN                                    0628.000
           TRAN    LAMBDA,,DD.SL20                                      0629.000
         STATE                                                          0630.000
           TRAN    SUBEXP,,DD.SL10,DD.OPT,NOB.M  GET AN OPTION          0631.000
DD.SL20  STATE                                                          0632.000
           TRAN    COMMA,A.LOCAL,DD.SL30,,NOB.M   GET MORE IF IN LIST   0633.000
           TRAN    NOBLNK,,EXIT                                         0634.000
DD.SL30  STATE                                                          0635.000
           TRAN    SUBEXP,,DD.LIST,SS.INP,NOB.M+LMB.M    "PATH=" KEYWORD0636.000
         STATE                                                          0637.000
         SPACE     2                                                    0638.000
DD.OPT   STATE                     OPTIONS TO CREATE DIRECTORY COMMAND  0639.000
           TRAN    KEYWD,,,K.CREDIR,NOB.M                               0640.000
         STATE                                                          0641.000
         SPACE                                                          0642.000
K.CREDIR EQU       $                         CREATE DIRECTORY -- OPTIONS0643.000
         KEYWRD    ACCESS,,SS.ACCE,3   ACCESS ATTRIBUTES  !32B01 ECKW-340644.000
         KEYWRD    BRIEF,,SS.BRIE,3    BRIEF - BOOL OPTI  !32B01 ECKW-340645.000
         KEYWRD    ENTRIES,,SS.ENTR,3  # ENTRIES          !32B01 ECKW-340646.000
         KEYWRD    OWNER,,SS.OWNE,3    OWNER NAME SPECIF. !32B01 ECKW-340647.000
         KEYWRD    SHARED,,SS.SHAR,3   SHARED ATTRIBUTE   !32B01 ECKW-340648.000
         KEYWRD    START,,SS.STAR,3    STARTING BLOCK #   !32B01 ECKW-340649.000
         KEYWRD    PROJECTGROUP,,SS.USER,3 PROJ.GRP. NAME !32B01 ECKW-340650.000
         DATAW     0                         END OF LIST                0651.000
         TITLE     CREATE FILE COMMAND STATE TABLES & ACTION ROUTINES   0652.000
*                                                                       0653.000
* A.CMD    - ACTION WHEN VALID CREATE FILE(S) COMMAND IS PARSED         0654.000
*                                                                       0655.000
         SPACE                                                          0656.000
A.CMD    LA        R7,C.CREFIL     GET ADDRESS OF COMMAND PROCESSOR     0657.000
         STW       R7,COMDADDR     SAVE FOR DISPATCHER                  0658.000
         TRSW      R0              RETURN TO PARSER                     0659.000
         SPACE                                                          0660.000
         BOUND     1W              ALIGN                                0661.000
         SPACE                                                          0662.000
*++                                                                     0663.000
* S.CREFIL - STATE TABLES FOR THE CREATE FILE COMMAND                   0664.000
*                                                                       0665.000
* COMMAND SYNTAX:                                                       0666.000
*                                                                       0667.000
* CREATE [FILE] [GLOBAL OPTIONS] [PATH=] PATHNAME [LOCAL OPTIONS] [,...]0668.000
*                                                                       0669.000
* OPTIONS:                                                              0670.000
*                                                                       0671.000
*--                                                                     0672.000
         SPACE                                                          0673.000
S.CREFIL STATE                     STATE TABLE FOR CREATE FILE          0674.000
           TRAN    NOBLNK,A.GLOBAL      POSITION OPTION BLOCK FOR       0675.000
*                                       GLOBAL OPTIONS                  0676.000
S.10     STATE                                                          0677.000
           TRAN    EOS,,PERR006         ERROR -- MUST HAVE AT LEAST ONE 0678.000
*                                       PATHNAME                        0679.000
           TRAN    TSTEXP,,S.20,SS.KWSYN    IS IT A KEYWORD ???         0680.000
           TRAN    NOBLNK,,S.30              NOT A KEYWORD -- MUST BE AN0681.000
*                                            ACTUAL PATHNAME            0682.000
S.20     STATE                                                          0683.000
           TRAN    SUBEXP,,S.30,SS.INP,NOB.M      IS IT "PATH=" KEYWORD 0684.000
           TRAN    SUBEXP,,S.10,SS.OPT,NOB.M      CHECK FOR LEGAL OPTION0685.000
*                                                 KEYWORDS              0686.000
           ERRVAL  INVKEY                         INVALID KEYWORD       0687.000
S.30     STATE                                                          0688.000
           TRAN    EOS,,PERR006              ERROR -- MUST HAVE AT LEAST0689.000
*                                            ONE PATHNAME               0690.000
*          TRAN    NOBLNK,A.LOCAL            POSITION TO 1ST LO EVOM-33 0691.000
*                                            OPTION BLOCK               0692.000
           TRAN    NOBLNK,A.LOCAL1           ZERO SEGN & A.LOCA EVOM-33 0693.000
         STATE                                                          0694.000
           TRAN    SUBEXP,A.LOCAL,S.40,SS.LIST   GET PATHNAME & LOCAL OP0695.000
S.40       TRAN    EOS,A.CMD,EXIT            EXIT PARSE -- SUCCESSFUL   0696.000
*                                            ALSO PLUG ENTRY ADDRESS    0697.000
*                                            SYNTAX VIOLATION           0698.000
         STATE                                                          0699.000
         SPACE     3                                                    0700.000
SS.LIST  STATE                               INPUT FILE LIST            0701.000
           TRAN    SUBEXP,,,SS.CPTHN,NOB.M                              0702.000
SS.SL10  STATE                                                          0703.000
           TRAN    TSTEXP,,,SS.KWSYN         LOOK FOR AN OPTION KEYWORD 0704.000
           TRAN    LAMBDA,,SS.SL20           MUST NOT BE ANY            0705.000
         STATE                                                          0706.000
           TRAN    SUBEXP,,SS.SL10,SS.OPT,NOB.M  GET AN OPTION          0707.000
SS.SL20  STATE                                                          0708.000
           TRAN    COMMA,A.LOCAL,SS.SL30,,NOB.M   GET MORE IF IN LIST   0709.000
           TRAN    NOBLNK,,EXIT              EXIT THIS SUBEXPRESSION    0710.000
SS.SL30  STATE                                                          0711.000
           TRAN    SUBEXP,,SS.LIST,SS.INP,NOB.M+LMB.M   "PATH=" KEYWORD 0712.000
         STATE                                                          0713.000
         SPACE     3                                                    0714.000
SS.OPT   STATE                     OPTIONS APPLICABLE FOR THIS COMMAND  0715.000
           TRAN    KEYWD,,,K.OPTS,NOB.M                                 0716.000
         STATE                                                          0717.000
         SPACE     4                                                    0718.000
K.OPTS   EQU       $                         CREATE DIRECTORY -- OPTIONS0719.000
         KEYWRD    SIZE,,SS.ALLO,3     # BLOCKS TO ALLOCATE    ECKW-34  0720.000
         KEYWRD    ACCESS,,SS.ACCEF,3  ACCESS ATTRIBUTES  !32B01 ECKW-340721.000
         KEYWRD    AUTOEXT,,SS.AUTO,3  AUTOMATIC EXTEND   !32B01 ECKW-340722.000
         KEYWRD    BRIEF,,SS.BRIE,3    BRIEF LISTING      !32B01 ECKW-340723.000
         KEYWRD    FAST,,SS.FAST,3     FAST ID                 ECKW-34  0724.000
         KEYWRD    CONTIGUOUS,,SS.CONT,3 CONTIGUOUS=BOOL  !32B01 ECKW-340725.000
         KEYWRD    MAXINC,,SS.INCR,4   MAX. INCREMENT SIZE     ! 32B01  0726.000
         KEYWRD    MANEXT,,SS.MANE,3   MANUALLY EXTENDABL !32B01 ECKW-340727.000
         KEYWRD    MAXSIZE,,SS.MAXS,4  MAX SIZE - EXTEND. FILE ! 32B01  0728.000
         KEYWRD    MININC,,SS.MINI,3   MINIMUM INCR. SIZE !32B01 ECKW-340729.000
         KEYWRD    OWNER,,SS.OWNE,3    OWNER NAME SPECIFI !32B01 ECKW-340730.000
         KEYWRD    NOSAVE,,SS.NOSA,3   NOSAV ATTRIBUTE    !32B01 ECKW-340731.000
         KEYWRD    EOFM,,SS.RAND,3     RANDOM ATTRIBUTE   !32B01 ECKW-340732.000
         KEYWRD    REPLACE,,SS.REPL,3  REPLACE - DEL.EXIS !32B01 ECKW-340733.000
         KEYWRD    SHARED,,SS.SHAR,3   SHARED ATTRIBUTE   !32B01 ECKW-340734.000
         KEYWRD    START,,SS.STAR,3    START BLCK# SPEC  !32B01  ECKW-340735.000
         KEYWRD    PROJECTGROUP,,SS.USER,3 PROJ.GRP.NAME !32B01  ECKW-340736.000
         KEYWRD    ZERO,,SS.ZERO,3      ZERO=BOOL OPTION       ECKW-34  0737.000
         KEYWRD    SEGNUM,,SS.SEGN,3   MAX NUM OF SEGMNT EVOM-33 ECKW-340738.000
*  ZERO FILE SPACE                                                      0739.000
         DATAW     0                         END OF LIST                0740.000
         SPACE     2                                                    0741.000
END      END                                                            0742.000
